ControlShow
Отображает ранее скрытый элемент.
ControlShow ( "title", "text", controlID )
Параметры
| title | Заголовок/дескриптор/класс окна. См. заголовки и текст окон (расширенные). |
| text |
Текст окна. |
| controlID |
Идентификатор элемента управления. Смотрите Элементы управления. |
Возвращаемое значение
| Успех: | Возвращает 1. |
| Ошибка: | Возвращает 0, если окно/элемент не найден. |
См. также
ControlHide, ControlEnable, ControlCommandПример
; Запуск калькулятора
Run('calc.exe')
; Класс окна в зависимости от версии OS
Switch @OSVersion
Case 'WIN_7', 'WIN_8'
$sClassWnd = 'CalcFrame'
$sClassEdit = 'Static'
Case Else
$sClassWnd = 'SciCalc'
$sClassEdit = 'Edit'
EndSwitch
; Ожидание 5 секунд до появление окна калькулятора
$hWnd = WinWait('[CLASS:' & $sClassWnd & ']', '', 5)
If Not $hWnd Then
MsgBox(4096, 'Сообщение', 'Окно не найдено, завершаем работу скрипта')
Exit
EndIf
ControlHide($hWnd, '', '[CLASS:' & $sClassEdit & '; INSTANCE:1]')
For $i = 1 To 27
ControlHide($hWnd, '', '[CLASS:Button; INSTANCE:' & $i & ']')
Sleep(50)
Next
MsgBox(4096, 'Сообщение', 'Кнопки стали скрыты')
ControlShow($hWnd, '', '[CLASS:' & $sClassEdit & '; INSTANCE:1]') ; отображает скрытый элемент
For $i = 1 To 27
ControlShow($hWnd, '', '[CLASS:Button; INSTANCE:' & $i & ']')
Sleep(50)
Next
MsgBox(4096, 'Сообщение', 'Кнопки стали видны')
; Закрывает калькулятор.
WinClose($hWnd)