↑  ←  Описание функции

_GUICtrlListView_SetGroupInfo

Устанавливает параметры группы

#include <GuiListView.au3>
_GUICtrlListView_SetGroupInfo($hWnd, $iGroupID, $sHeader [, $iAlign = 0 [, $iState = $LVGS_NORMAL]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iGroupID Идентификатор группы (ID)
$sHeader Текст заголовка
$iAlign [необязательный] Выравнивание текста заголовка группы:
    0 - Влево
    1 - По центру
    2 - Вправо
$iState [необязательный] Vista и выше, могут иметь одно из следующих значений:
    $LVGS_NORMAL - Группы раскрыты, имена групп отображаются, и все пункты в группах отображаются.
    $LVGS_COLLAPSED - Группы свёрнуты.
    $LVGS_HIDDEN - Группы скрыты.
    $LVGS_NOHEADER - Группы не отображают заголовок.
    $LVGS_COLLAPSIBLE - Группы могут быть свернуты.
    $LVGS_FOCUSED - The group has keyboard focus.
    $LVGS_SELECTED - Группа выбрана.
    $LVGS_SUBSETED - The group displays only a portion of its items.
    $LVGS_SUBSETLINKFOCUSED - The subset link of the group has keyboard focus

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Минимальная ОС - Windows XP.

См. также

_GUICtrlListView_GetGroupInfo, _GUICtrlListView_GetGroupInfoByIndex

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aInfo, $hImage, $hListView

    GUICreate("Устанавливает информацию о группе", 400, 300)

    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Создание групп
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1", 1)
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

    ; Изменяет информацию о группе
    $aInfo = _GUICtrlListView_GetGroupInfo($hListView, 1)
    MsgBox(4160, "Информация", "Текст первой группы: " & $aInfo[0])
    _GUICtrlListView_SetGroupInfo($hListView, 1, "Новая группа 1")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main