Установка курсора в поле формы Через InternetExplorer <IE.au3>

[RavdonikaS]

Подскажите как тут ==> https://ru.4game.com/lineage2/play/?popupWidget=AuthPopupWidget
перевести курсор в поля "Почта или логин" и "Пароль"?
Или как сразу ввести туда данные?

2 дня уже мучаюсь ничего внятного не выходит

 

[madmasles]

RavdonikaS,
Попробуйте так, у меня работает.

#include <IE.au3>
; IE8 Win 7x32

RunWait(@SystemDir & '\RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 4351')
AdlibRegister('_Yes')
$oIE = _IECreate('https://ru.4game.com/lineage2/play/?popupWidget=AuthPopupWidget')
If @error Then Exit 13

Do
	$oLog = _IEGetObjById($oIE, 'AuthFormLogin')
	If @error Then ExitLoop
	_IEFormElementSetValue($oLog, 'MyLogin')
	If @error Then ExitLoop
	$oPass = _IEGetObjById($oIE, 'AuthFormPassword')
	If @error Then ExitLoop
	_IEFormElementSetValue($oPass, 'MyPassword')
	If @error Then ExitLoop
	$oChb = _IEGetObjById($oIE, 'jsLoginPopupWidget__RememberMe')
	If @error Then ExitLoop
	_IEAction($oChb, 'click')
	If @error Then ExitLoop
	_IELoadWait($oIE)
	If @error Then ExitLoop
	$oBtn = _IEGetObjById($oIE, 'jsLoginPopupWidget__SignIn')
	If @error Then ExitLoop
	_IEAction($oBtn, 'click')
	If @error Then ExitLoop
	_IELoadWait($oIE)
	If @error Then ExitLoop
Until 1
If @error Then Exit 14
AdlibUnRegister('_Yes')
MsgBox(64, 'Info', 'OK')

Func _Yes()
	Local $h_Win = WinGetHandle('[Title:Предупреждение о безопасности; Class:#32770]')
	If Not $h_Win Then Return
	ControlClick($h_Win, '', '[CLASS:Button; INSTANCE:1]')
EndFunc   ;==>_Yes

 

[RavdonikaS]

Класс работает!!!
Зачем вначале историю очищать?
И для чего функция _Yes()?

Вопросы задал преждевременно
Немного покрутил (ручками попробовал) - разобрался

Это если вход уже выполнен что бы оно все равно заполняло по новой поля - Удобно если аккаунтов несколько

RunWait(@SystemDir & '\RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 4351')

Убирает назойливую табличку выскакивает постоянно на IntertnetExplorer и не дает дальше ничего делать

Func _Yes()
    Local $h_Win = WinGetHandle('[Title:Предупреждение о безопасности; Class:#32770]')
    If Not $h_Win Then Return
    ControlClick($h_Win, '', '[CLASS:Button; INSTANCE:1]')
EndFunc   ;==>_Yes

ТЕМА РЕШЕНА!
Огромное спасибо

 

[madmasles]

RavdonikaS,
[info border=#0000ff float=left]На форуме принято помечать тему решенной после получения ответа на свой вопрос!
Вверху или внизу темы нажмите на ссылку такого вида:

Тема не решена[/info]