Подсчет чекнутых checkbox и работа с ними.

le1to · 22 Сен 2014

Добрый вечер!
искал на форуме ответы на мои вопросы, находил что-то подобное, но отсутствие опыта и неделя практики в autoit помешали получить ответы.
Вопрос такой:
существует например $List с чекбоксами в GUI.
1. Как посчитать количество отмеченных чекбоксов?
2. Как вставить это количество в существующий $Label? (думаю, после ответа на первый пункт пойму, но все же)
3. Как сделать , чтобы чекнутые строки добавлялись сразу же в пустой $List2?
4. Возможна ли сортировка чекбоксов по алфавиту, хотя бы на $List2?

madmasles · 22 Сен 2014

le1to [?]

1. Как посчитать количество отмеченных чекбоксов?

Код:

_GUICtrlListView_GetItemCount()
_GUICtrlListView_GetItemChecked()

2. Как вставить это количество в существующий $Label?

Код:

GUICtrlSetData()

3. Как сделать , чтобы чекнутые строки добавлялись сразу же в пустой $List2?

Код:

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

4. Возможна ли сортировка чекбоксов по алфавиту, хотя бы на $List2?

Код:

_GUICtrlListView_RegisterSortCallBack()
_GUICtrlListView_SortItems()

le1to · 22 Сен 2014

а можно на примере первые 2 пункта, пожалуйста?

AZJIO · 22 Сен 2014

le1to
Вы можете кликнуть на увиденные функции и откроется пример их использования.

В этом примере много чего есть, и сортировка и количество пунктов.

Код:

GUICtrlCreateListViewItem

le1to · 22 Сен 2014

Спасибо, но, наверное, пока я не могу быстро самостоятельно сопоставлять скрипты, кажется, что в первом пункте первая команда считает чекбоксы, а вторая обращается к определенному чекбоксу .

AZJIO · 22 Сен 2014

le1to
Скачайте Коллекция скриптов, извлеките архив, активируйте поиск файла "чекбокс" и там точно будет пример с работой чекбоксов (ListView с чекбосами.au3, с ошибкой в имени :smile:

). Там главное запрос отмеченности, а подсчёт делается в цикле опрашивая каждый пункт на предмет отмеченности.

Код:

_GUICtrlListView_GetItemChecked

le1to · 22 Сен 2014

AZJIO сказал(а):
le1to
Скачайте Коллекция скриптов, извлеките архив, активируйте поиск файла "чекбокс" и там точно будет пример с работой чекбоксов. Там главное запрос омесенности, а подсчёт делается в цикле опрашивая кжадый пункт на предмет отмеченности.

Пришел к мысли, что можно проверять опрашивая каждый пункт, но думал есть вариант проще, но сойдет и такое.

madmasles · 22 Сен 2014

le1to [?]

а можно на примере первые 2 пункта

Пример.

Код:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

_Main()

Func _Main()
	Local $iTimer, $hListView, $iBtn, $iBtnRand, $iLbl, $iCountCheck, $aItems[Random(50, 100, 1)][1]

	GUICreate('ListView', 400, 400)
	$hListView = GUICtrlCreateListView('', 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
	$iBtn = GUICtrlCreateButton('Get Checked Count', 20, 310, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 350, 110, 30)
	_GUICtrlListView_AddColumn($hListView, 'Пункты', 90)
	_GUICtrlListView_SetItemCount($hListView, 5000)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = 'Пункт ' & $i
	Next
	_GUICtrlListView_AddArray($hListView, $aItems)
	GUISetState()
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				$iCountCheck = 0
				For $i = 0 To _GUICtrlListView_GetItemCount($hListView) - 1
					If _GUICtrlListView_GetItemChecked($hListView, $i) Then $iCountCheck += 1
				Next
				GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($hListView) - 1
					If Random(0, 1, 1) Then  _GUICtrlListView_SetItemChecked($hListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

И еще пример.

Код:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $iListView, $iCountCheck = 0, $iLbl

_Main()

Func _Main()
	Local $iTimer, $iBtn, $iBtnRand, $aItems[Random(50, 100, 1)][1]

	GUICreate('ListView', 400, 400)
	$iListView = GUICtrlCreateListView('', 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($iListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
	$iBtn = GUICtrlCreateButton('UnChecked All', 20, 350, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 310, 110, 30)
	_GUICtrlListView_AddColumn($iListView, 'Пункты', 90)
	_GUICtrlListView_SetItemCount($iListView, 5000)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = Random(1, 1000, 1) & ' Пункт'
	Next
	_GUICtrlListView_AddArray($iListView, $aItems)
	GUISetState()
	GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				_GUICtrlListView_SetItemChecked($iListView, -1, 0)
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($iListView) - 1
					If Random(0, 1, 1) Then _GUICtrlListView_SetItemChecked($iListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
	Local $tInfo
	$tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
	Switch DllStructGetData($tInfo, 'IDFrom')
		Case $iListView
			Switch DllStructGetData($tInfo, 'Code')
				Case $LVN_ITEMCHANGED
					Switch DllStructGetData($tInfo, 'NewState')
						Case $LVM_FIRST
							$iCountCheck -= 1
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
						Case $LVM_FIRST * 2
							$iCountCheck += 1
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

И еще один пример.

Код:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $iListView, $iListViewCheck, $hListViewCheck, $iCountCheck = 0, $iLbl

_Main()

Func _Main()
	Local $iTimer, $iBtn, $iBtnRand, $aItems[Random(50, 100, 1)][2]

	GUICreate('ListView', 400, 400)
	$iListView = GUICtrlCreateListView('', 2, 2, 197, 268)
	$iListViewCheck = GUICtrlCreateListView('', 201, 2, 197, 268)
	$hListViewCheck = GUICtrlGetHandle($iListViewCheck)
	_GUICtrlListView_SetExtendedListViewStyle($iListViewCheck, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES))
	_GUICtrlListView_SetExtendedListViewStyle($iListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES, $LVS_EX_GRIDLINES))
	$iBtn = GUICtrlCreateButton('UnChecked All', 20, 350, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 310, 110, 30)
	_GUICtrlListView_AddColumn($iListView, 'Пункты', 90)
	_GUICtrlListView_AddColumn($iListView, '1', 90)
	_GUICtrlListView_AddColumn($iListViewCheck, 'Checked', 90)
	_GUICtrlListView_AddColumn($iListViewCheck, '1', 90)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = Random(1, 1000, 1) & ' Пункт'
		$aItems[$i][1] = Random(1, 1000, 1) & ' Пункт'
	Next
	_GUICtrlListView_AddArray($iListView, $aItems)
	GUISetState()
	GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				GUIRegisterMsg($WM_NOTIFY, '')
				_GUICtrlListView_SetItemChecked($iListView, -1, 0)
				_GUICtrlListView_DeleteAllItems($hListViewCheck)
				$iCountCheck = 0
				GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
				GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($iListView) - 1
					If Random(0, 1, 1) Then _GUICtrlListView_SetItemChecked($iListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
	Local $tInfo, $iIndex, $iIndexCh
	$tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
	Switch DllStructGetData($tInfo, 'IDFrom')
		Case $iListView
			Switch DllStructGetData($tInfo, 'Code')
				Case $LVN_ITEMCHANGED
					Switch DllStructGetData($tInfo, 'NewState')
						Case $LVM_FIRST
							$iCountCheck -= 1
							$iIndex = DllStructGetData($tInfo, 'Index')
							$iIndex = _GUICtrlListView_FindInText($hListViewCheck, _GUICtrlListView_GetItemText($iListView, $iIndex))
							If $iIndex >= 0 Then _GUICtrlListView_DeleteItem($hListViewCheck, $iIndex)
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
						Case $LVM_FIRST * 2
							$iCountCheck += 1
							$iIndex = DllStructGetData($tInfo, 'Index')
							_GUICtrlListView_AddItem($iListViewCheck, _GUICtrlListView_GetItemText($iListView, $iIndex))
							$iIndexCh = _GUICtrlListView_GetItemCount($iListViewCheck) - 1
							For $i = 1 To _GUICtrlListView_GetColumnCount($iListView) - 1
								_GUICtrlListView_AddSubItem($iListViewCheck, $iIndexCh, _GUICtrlListView_GetItemText($iListView, $iIndex, $i), $i)
							Next
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

А сортировку мне уже лень прикручивать. :smile:

le1to · 23 Сен 2014

madmasles сказал(а):

le1to [?]

а можно на примере первые 2 пункта

Пример.

Код:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

_Main()

Func _Main()
	Local $iTimer, $hListView, $iBtn, $iBtnRand, $iLbl, $iCountCheck, $aItems[Random(50, 100, 1)][1]

	GUICreate('ListView', 400, 400)
	$hListView = GUICtrlCreateListView('', 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
	$iBtn = GUICtrlCreateButton('Get Checked Count', 20, 310, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 350, 110, 30)
	_GUICtrlListView_AddColumn($hListView, 'Пункты', 90)
	_GUICtrlListView_SetItemCount($hListView, 5000)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = 'Пункт ' & $i
	Next
	_GUICtrlListView_AddArray($hListView, $aItems)
	GUISetState()
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				$iCountCheck = 0
				For $i = 0 To _GUICtrlListView_GetItemCount($hListView) - 1
					If _GUICtrlListView_GetItemChecked($hListView, $i) Then $iCountCheck += 1
				Next
				GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($hListView) - 1
					If Random(0, 1, 1) Then  _GUICtrlListView_SetItemChecked($hListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

И еще пример.

Код:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $iListView, $iCountCheck = 0, $iLbl

_Main()

Func _Main()
	Local $iTimer, $iBtn, $iBtnRand, $aItems[Random(50, 100, 1)][1]

	GUICreate('ListView', 400, 400)
	$iListView = GUICtrlCreateListView('', 2, 2, 394, 268)
	_GUICtrlListView_SetExtendedListViewStyle($iListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
	$iBtn = GUICtrlCreateButton('UnChecked All', 20, 350, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 310, 110, 30)
	_GUICtrlListView_AddColumn($iListView, 'Пункты', 90)
	_GUICtrlListView_SetItemCount($iListView, 5000)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = Random(1, 1000, 1) & ' Пункт'
	Next
	_GUICtrlListView_AddArray($iListView, $aItems)
	GUISetState()
	GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				_GUICtrlListView_SetItemChecked($iListView, -1, 0)
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($iListView) - 1
					If Random(0, 1, 1) Then _GUICtrlListView_SetItemChecked($iListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
	Local $tInfo
	$tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
	Switch DllStructGetData($tInfo, 'IDFrom')
		Case $iListView
			Switch DllStructGetData($tInfo, 'Code')
				Case $LVN_ITEMCHANGED
					Switch DllStructGetData($tInfo, 'NewState')
						Case $LVM_FIRST
							$iCountCheck -= 1
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
						Case $LVM_FIRST * 2
							$iCountCheck += 1
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

И еще один пример.

Код:

Global $iListView, $iListViewCheck, $hListViewCheck, $iCountCheck = 0, $iLbl

_Main()

Func _Main()
	Local $iTimer, $iBtn, $iBtnRand, $aItems[Random(50, 100, 1)][2]

	GUICreate('ListView', 400, 400)
	$iListView = GUICtrlCreateListView('', 2, 2, 197, 268)
	$iListViewCheck = GUICtrlCreateListView('', 201, 2, 197, 268)
	$hListViewCheck = GUICtrlGetHandle($iListViewCheck)
	_GUICtrlListView_SetExtendedListViewStyle($iListViewCheck, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES))
	_GUICtrlListView_SetExtendedListViewStyle($iListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES, $LVS_EX_GRIDLINES))
	$iBtn = GUICtrlCreateButton('UnChecked All', 20, 350, 110, 30)
	$iLbl = GUICtrlCreateLabel('Checked: 0', 150, 310, 100, 20)
	$iBtnRand = GUICtrlCreateButton('Checked Random', 20, 310, 110, 30)
	_GUICtrlListView_AddColumn($iListView, 'Пункты', 90)
	_GUICtrlListView_AddColumn($iListView, '1', 90)
	_GUICtrlListView_AddColumn($iListViewCheck, 'Checked', 90)
	_GUICtrlListView_AddColumn($iListViewCheck, '1', 90)
	For $i = 0 To UBound($aItems) - 1
		$aItems[$i][0] = Random(1, 1000, 1) & ' Пункт'
		$aItems[$i][1] = Random(1, 1000, 1) & ' Пункт'
	Next
	_GUICtrlListView_AddArray($iListView, $aItems)
	GUISetState()
	GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $iBtn
				GUIRegisterMsg($WM_NOTIFY, '')
				_GUICtrlListView_SetItemChecked($iListView, -1, 0)
				_GUICtrlListView_DeleteAllItems($hListViewCheck)
				$iCountCheck = 0
				GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
				GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
			Case $iBtnRand
				For $i = 0 To _GUICtrlListView_GetItemCount($iListView) - 1
					If Random(0, 1, 1) Then _GUICtrlListView_SetItemChecked($iListView, $i)
				Next
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
	Local $tInfo, $iIndex, $iIndexCh
	$tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
	Switch DllStructGetData($tInfo, 'IDFrom')
		Case $iListView
			Switch DllStructGetData($tInfo, 'Code')
				Case $LVN_ITEMCHANGED
					Switch DllStructGetData($tInfo, 'NewState')
						Case $LVM_FIRST
							$iCountCheck -= 1
							$iIndex = DllStructGetData($tInfo, 'Index')
							$iIndex = _GUICtrlListView_FindInText($hListViewCheck, _GUICtrlListView_GetItemText($iListView, $iIndex))
							If $iIndex >= 0 Then _GUICtrlListView_DeleteItem($hListViewCheck, $iIndex)
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
						Case $LVM_FIRST * 2
							$iCountCheck += 1
							$iIndex = DllStructGetData($tInfo, 'Index')
							_GUICtrlListView_AddItem($iListViewCheck, _GUICtrlListView_GetItemText($iListView, $iIndex))
							$iIndexCh = _GUICtrlListView_GetItemCount($iListViewCheck) - 1
							For $i = 1 To _GUICtrlListView_GetColumnCount($iListView) - 1
								_GUICtrlListView_AddSubItem($iListViewCheck, $iIndexCh, _GUICtrlListView_GetItemText($iListView, $iIndex, $i), $i)
							Next
							GUICtrlSetData($iLbl, 'Checked: ' & $iCountCheck)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

А сортировку мне уже лень прикручивать. :smile:

Это очень круто для меня=)
3й пример что то не работает, не могли бы помочь, сделать в скрипте такую же функцию, как в примере 2, что бы считалось количество отмеченных чекбоксов сразу, без нажатия кнопок и отображалось в $iLbl, и процитировать сбоку каждую добавленную строку для анализа?

Код:

#include <AVIConstants.au3>
#include <GuiConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GuiListView.au3>

; GUI
GUICreate("Coordinate", 400, 400)

; TAB
GUICtrlCreateTab(0, 0, 401, 400)
GUICtrlCreateTabItem("Сотрудники") ;Первая вкладка
Local $Persons = GUICtrlCreateGroup("Пришли на работу", 5, 25, 150, 340)
GUICtrlSetState(-1, $GUI_SHOW)
Local $hTree = GUICtrlCreateTreeView(10, 40, 140, 320, BitOR($TVS_CHECKBOXES, $TVS_DISABLEDRAGDROP), $WS_EX_CLIENTEDGE)
GUICtrlSetState(-1, $GUI_SHOW)
GUICtrlSetBkColor($hTree, 0xD0F0F0)
Local $Count = GUICtrlCreateGroup("Всего на работе", 170, 25, 100, 100)
GUICtrlSetState(-1, $GUI_SHOW)
;~ GUICtrlCreateList ("", 175, 40, 90, 80, BitOR($TVS_CHECKBOXES, $TVS_DISABLEDRAGDROP), $WS_EX_CLIENTEDGE)
Local $iLbl = GUICtrlCreateLabel ( "0", 170, 40, 0, 0, $SS_CENTER)
GUICtrlSetFont (-1,50, 800)
;Список сотрудников
GUICtrlCreateTreeViewItem("Иванов", $hTree)
GUICtrlCreateTreeViewItem("Петров", $hTree)
GUICtrlCreateTreeViewItem("Сидоров", $hTree)
;Вторая вкладка
GUICtrlCreateTabItem("Распределение по линиям")
;Третяя вкладка
GUICtrlCreateTabItem("Three")
GUICtrlCreateTabItem("")



; GUI MESSAGE LOOP
GUISetState(@SW_SHOW)
While 1
	Switch GUIGetMsg()
	Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd

madmasles · 23 Сен 2014

le1to,

Предупреждение За нарушение общих правил (пункт В.2):

Старайтесь избегать “Over quoting” (преувеличенное цитирование) - цитируйте только необходимую часть сообщения, которая наилучшим образом подчеркнёт суть цитируемого.

С уважением, ваш Глобальный модератор.

[info border=#0000ff float=left]С такой постановкой вопроса Вам надо в Стол заказов.Переоформите тему в соответствии с Правилами обязательного оформления тем в разделе "Стол заказов" и я ее туда перенесу.[/info]
Добавлено:
Сообщение автоматически объединено: 23 Сен 2014

le1to [?]

3й пример что то не работает

Поправил.

Автор темы	Похожие темы	Форум	Ответы	Дата
D	Подсчет файлов .xlsx в активной папке	Общие вопросы по AutoIt	7	21 Апр 2022
D	Поиск и подсчет повторяющихся (уникальных) строк в массиве	Общие вопросы по AutoIt	1	29 Сен 2021
D	Копирование папки, отображение процесса загрузки буфера и подсчет времени потраченного на процесс (секундомер)	Стол заказов	46	23 Июн 2020
H	Подсчет меток в 2Гис	Стол заказов	0	9 Мар 2020
	Перенесено: Подсчет чекнутых checkbox и работа с ними.	Общие вопросы по AutoIt	0	22 Сен 2014

Поиск

Поиск

Подсчет чекнутых checkbox и работа с ними.

le1to

Новичок

madmasles

Модератор

le1to

Новичок

AZJIO

Меценат

le1to

Новичок

AZJIO

Меценат

le1to

Новичок

madmasles

Модератор

le1to

Новичок

Вложения

madmasles

Модератор