Найти кнопки в AdGuard

[RedShade7]

Версия AutoIt: 3.3.12.0
Описание:
Всем привет! Хотел автоматизировать установку AdGuard, но столкнулся с проблемой - AutoIt Window Info не видит элемент кнопки, да и вообще не видит элементы в окне установщика AdGuard, как быть?
Заранее спасибо!
Ссылка на AdGuard http://adguard.com/ru/download.html

 

[kaster]

Re: AdGuard

Предупреждение

За нарушение правил форума (пункт Б.5):

Имя темы должно нести смысловую нагрузку (отражать суть вопроса/проблемы)
Правильно сформулированное название темы привлекает больше внимания, и шансы получить конкретный ответ увеличиваются.

Данные правила могут пополняться локальными правилами раздела.
Как правильно называть темы

"AdGuard" - это неприемлемое название темы, переименуйте тему иначе она будет закрыта, а вам возможно будет выдан бан на несколько дней.

С уважением, ваш Глобальный модератор.

Добавлено:

Сообщение автоматически объединено: 3 Авг 2014

Правила обязательного оформления тем в разделе "Стол заказов"

 

[InnI]

RedShade7 [?]

как быть

Использовать UIAutomate

#RequireAdmin
#include <UIAutomate.au3>

; запуск
Run("adguardInstaller.exe")
$hWnd = WinWait("[TITLE:Установщик Adguard;REGEXPCLASS:HwndWrapper]")
$oWnd = _UIA_GetElementFromHandle($hWnd)

; страница 1
_UIA_WaitControlTypeElement($oWnd, "UIA_TextControlTypeId", "ЛИЦЕНЗИОННОЕ СОГЛАШЕНИЕ")
$oBtn = _UIA_GetControlTypeElement($oWnd, "UIA_ButtonControlTypeId", "Я принимаю условия")
_UIA_ElementDoDefaulAction($oBtn)

; страница 2
_UIA_WaitControlTypeElement($oWnd, "UIA_TextControlTypeId", "ВЫБОР ПАПКИ УСТАНОВКИ")
#cs отключение создания ярлыка
$oCheck = _UIA_GetControlTypeElement($oWnd, "UIA_CheckBoxControlTypeId", "Создать ярлык на рабочем столе")
_UIA_ElementDoDefaulAction($oCheck)
#ce
; далее
$oBtn = _UIA_GetControlTypeElement($oWnd, "UIA_ButtonControlTypeId", "Далее")
_UIA_ElementDoDefaulAction($oBtn)

; страница 3
_UIA_WaitControlTypeElement($oWnd, "UIA_TextControlTypeId", "РЕГИСТРАЦИЯ")
; далее
$oBtn = _UIA_GetControlTypeElement($oWnd, "UIA_ButtonControlTypeId", "Далее")
_UIA_ElementDoDefaulAction($oBtn)

; страница 4
_UIA_WaitControlTypeElement($oWnd, "UIA_TextControlTypeId", "Adguard рекомендует продукты")
; отключение продуктов Яндекса
$oChecks = _UIA_FindAllElements($oWnd, "ControlType", $UIA_CheckBoxControlTypeId)
For $i = 1 To $oChecks[0]
  _UIA_ElementDoDefaulAction($oChecks[$i])
Next
; далее
$oBtn = _UIA_GetControlTypeElement($oWnd, "UIA_ButtonControlTypeId", "Далее")
_UIA_ElementDoDefaulAction($oBtn)

; закрытие окна настроек
$hWnd = WinWait("[TITLE:Adguard;REGEXPCLASS:HwndWrapper]", "", 30)
If Not $hWnd Then Exit
$oWnd = _UIA_GetElementFromHandle($hWnd)
$UIA_DefaultWaitTime = 30
_UIA_WaitControlTypeElement($oWnd, "UIA_TextControlTypeId", "Select your language")
WinClose($hWnd)