Что нового

Использование маски в имени файла вложения _INetSmtpMailCom

pas86

Новичок
Сообщения
2
Репутация
0
Всем добрый день. Столкнулся с тем, что необходимо во вложение письма вставлять файл, конец названия которого меняется каждый месяц(пишется месяц и год).
Использую отдельный файл config.ini, в котором описаны все переменные.
Код:
[Config]
SMTP=
FromName=
FromAddress=
ToAddress=
FilePath=D:\temp\primer June 2020.xlsm
Subject=


Файл в папке с таким названием всегда один. Как указать верно имя с маской, чтобы _INetSmtpMailCom верно воспринял его.
Пробовал FilePath=D:\temp\primer*.xlsm -не работает.

ps сильно не пинайте, только начал разбираться с AutoIt
Сообщение автоматически объединено:

Код _INetSmtpMailCom
Код:
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
       If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
     $objEmail=""
  EndFunc   ;==>_INetSmtpMailCom
 
Последнее редактирование:

xXx

Меценат
Меценат
Сообщения
200
Репутация
70
... Как указать верно имя с маской...
Функция не принимает пути с маской. Соответственно ей нужно припадать путь к конкретному существующему файлу. А для этого файл еще надо найти. А что у нас может искать по маске? Правильно... Вот пример:
Код:
$FilePath='D:\temp\primer*.xlsm'

$hSearch = FileFindFirstFile($FilePath)
If $hSearch = -1 Then Exit MsgBox(4096, "Ошибка", "Ни один из файлов или каталогов не соответствует маске поиска")
$sFile = FileFindNextFile($hSearch)
FileClose($hSearch)
If $sFile Then MsgBox(262144, Default, '[' & $sFile & ']') ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<< П Р О В Е Р К А >>>>>>>>>>>>>>>>>>>>>>>>
 
Автор
P

pas86

Новичок
Сообщения
2
Репутация
0
Спасибо большое, буду пробовать!
Сообщение автоматически объединено:

Спасибо большое, еще раз. Все работает!
Сообщение автоматически объединено:

Подскажите еще, FileFindFirstFile не воспринимает путь с папками, написанными русскими буквами, как быть?
 
Последнее редактирование:
Верх