↑  ←  Описание функции

_GUICtrlMenu_GetMenu

Возвращает дескриптор меню назначенного указанному окну

#include <GuiMenu.au3>
_GUICtrlMenu_GetMenu($hWnd)

Параметры

$hWnd Дескриптор окна, дескриптор меню которого необходимо получить

Возвращаемое значение

Успех:Возвращает дескриптор меню
Ошибка:Возвращает 0

Примечания

_GUICtrlMenu_GetMenu не работает с floating menu bars. Floating menu bars являются пользовательскими элементами, которые имитируют стандартное меню, но не являются таковыми.

См. также

_GUICtrlMenu_SetMenu, _GUICtrlMenu_FindParent

См. также

Искать GetMenu в библиотеке MSDN

Пример

#include <GuiMenu.au3>

_Main()

Func _Main()
    Local $hWnd, $hMain, $hItem1, $hItem2

    ; Запуск блокнота
    Run("notepad.exe")
    $hWnd = WinWaitActive("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Создаёт вложенные пункты меню
    $hItem1 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem1, 0, "Подпункт &1", 0x1000)
    _GUICtrlMenu_InsertMenuItem($hItem1, 1, "Подпункт &2", 0x1001)

    ; Создаёт меню
    $hItem2 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem2, 0, "Пункт &1", 0x2000, $hItem1)
    _GUICtrlMenu_InsertMenuItem($hItem2, 1, "Пункт &2", 0x2001)
    _GUICtrlMenu_InsertMenuItem($hItem2, 2, "", 0)
    _GUICtrlMenu_InsertMenuItem($hItem2, 3, "Пункт &3", 0x2002)
    _GUICtrlMenu_InsertMenuItem($hItem2, 4, "Пункт &4", 0x2003)

    ; Вставляет новое меню в Блокнот
    _GUICtrlMenu_InsertMenuItem($hMain, 6, 'Меню+', 0, $hItem2)
    _GUICtrlMenu_DrawMenuBar($hWnd)

EndFunc   ;==>_Main