_GUICtrlListView_DeleteItem
Удаляет пункт из ListView
#include <GuiListView.au3>
_GUICtrlListView_DeleteItem($hWnd, $iIndex)
Параметры
| $hWnd | Идентификатор или дескриптор ListView |
| $iIndex |
Индекс удаляемого пункта |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlListView_DeleteAllItems, _GUICtrlListView_DeleteItemsSelectedПример
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Example1()
Example_UDF_Created()
Func Example1()
Local $hListView
GUICreate("ListView - Удаление пункта", 400, 300)
$hListView = GUICtrlCreateListView("Кол1|Кол2|Кол3", 2, 2, 394, 268)
GUISetState()
; 3 колонки добавлены
For $iI = 0 To 9
GUICtrlCreateListViewItem("Пункт " & $iI & "|Пункт " & $iI & "-1|Пункт " & $iI & "-2", $hListView)
Next
MsgBox(4160, "Информация", "Удаление пункта")
; Пункты созданы с помощью встроенной в AutoIt функции, передаётся идентификатор
MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteItem($hListView, 1))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example1
Func Example_UDF_Created()
Local $GUI, $aItems[10][3], $hListView
$GUI = GUICreate("(UDF) ListView Удаление пункта", 400, 300)
$hListView = _GUICtrlListView_Create($GUI, "Кол1|Кол2|Кол3", 2, 2, 394, 268)
GUISetState()
; 3 колонки добавлены
For $iI = 0 To UBound($aItems) - 1
$aItems[$iI][0] = "Пункт " & $iI
$aItems[$iI][1] = "Пункт " & $iI & "-1"
$aItems[$iI][2] = "Пункт " & $iI & "-2"
Next
_GUICtrlListView_AddArray($hListView, $aItems)
MsgBox(4160, "Информация", "Удаление пункта")
; Здесь уже передаётся дескриптор
MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteItem($hListView, 1))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example_UDF_Created