↑  ←  Описание функции

_GUICtrlComboBoxEx_Create

Создаёт элемент ComboBoxEx

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_Create($hWnd, $sText, $iX, $iY [, $iWidth = 100 [, $iHeight = 200 [, $iStyle = 0x00200002 [, $iExStyle = 0x00000000]]]])

Параметры

$hWnd Дескриптор родительского окна или окна владельца
$sText Разделённая строка для добавления в ComboBox
$iX Координата левого края
$iY Координата верхнего края
$iWidth [необязательный] Ширина элемента
$iHeight [необязательный] Высота элемента
$iStyle [необязательный] Стиль элемента:
    $CBS_DROPDOWN - Подобен $CBS_SIMPLE, но не отображается список, пока пользователь не нажмёт элемент справа от поля ввода для раскрытия списка.
    $CBS_DROPDOWNLIST - Подобен $CBS_DROPDOWN, но поле ввода недоступно для редактирования, и только отображает текущий выбор в списке.
    $CBS_SIMPLE - Список отображается всегда.
    По умолчанию: $CBS_DROPDOWN, $WS_VSCROLL     Принудительно : $WS_CHILD, $WS_TABSTOP, $WS_VISIBLE
$iExStyle [необязательный] Расширенный стиль элемента:
    $CBES_EX_CASESENSITIVE - Учитывает регистр при поиске
    $CBES_EX_NOEDITIMAGE - Поле ввода и раскрывающийся список не будут отображать изображения пунктов
    $CBES_EX_NOEDITIMAGEINDENT - Поле ввода и раскрывающийся список не будут отображать изображения пунктов (INDENT - отступы)
    $CBES_EX_NOSIZELIMIT - Позволяет элементу ComboBoxEx иметь вертикальный размер меньше, чем его содержимое.

Возвращаемое значение

Успех:Возвращает дескриптор элемента Listbox
Ошибка:Возвращает 0

См. также

_GUICtrlComboBoxEx_Destroy

Пример

#include <GuiComboBoxEx.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hCombo

_Main()

Func _Main()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("Создаёт ComboBoxEx", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "Это тест|Строка 2", 2, 2, 394, 268)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    _GUICtrlComboBoxEx_AddString ($hCombo, "Еще текст")
    _GUICtrlComboBoxEx_InsertString ($hCombo, "Вставленный текст", 1)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hCombo
            Switch $iCode
                Case $CBEN_BEGINEDIT ; Высылается, когда пользователь активирует выпадающий список или кликает в поле ввода.
                    _DebugPrint("$CBEN_BEGINEDIT" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    Return 0
                Case $CBEN_DELETEITEM
                    _DebugPrint("$CBEN_DELETEITEM" & _GetComboBoxEx($ilParam))
                    Return 0
                Case $CBEN_DRAGBEGINA, $CBEN_DRAGBEGINW
                    $tInfo = DllStructCreate($tagNMCBEDRAGBEGIN, $ilParam)
                    If DllStructGetData($tInfo, "ItemID") Then _DebugPrint("$CBEN_DRAGBEGIN" & _GetComboBoxEx($ilParam))
                    _DebugPrint("$CBEN_DRAGBEGIN" & @lf & "--> hwndfrom:" & @tab & DllStructGetData($tInfo, "hWndFrom") & @LF & _
                            "-->IDFrom:" & @tab & DllStructGetData($tInfo, "IDFrom") & @LF & _
                            "-->Code:" & @tab & DllStructGetData($tInfo, "Code") & @LF & _
                            "-->ItemID:" & @tab & DllStructGetData($tInfo, "ItemID") & @LF & _
                            "-->Text:" & @tab & DllStructGetData($tInfo, "Text"))
                    ; return is ignored
                Case $CBEN_ENDEDITA, $CBEN_ENDEDITW ; Высылается, когда пользователь завершил операцию в поле ввода или выбрал пункт из выпадающего списка.
                    $tInfo = DllStructCreate($tagNMCBEENDEDIT, $ilParam)
                    _DebugPrint("$CBEN_ENDEDIT" & @lf & "--> hwndfrom:" & @tab & DllStructGetData($tInfo, "hWndFrom") & @LF & _
                            "-->IDFrom:" & @tab & DllStructGetData($tInfo, "IDFrom") & @LF & _
                            "-->Code:" & @tab & DllStructGetData($tInfo, "Code") & @LF & _
                            "-->fChanged:" & @tab & DllStructGetData($tInfo, "fChanged") & @LF & _
                            "-->NewSelection:" & @tab & DllStructGetData($tInfo, "NewSelection") & @LF & _
                            "-->Text:" & @tab & DllStructGetData($tInfo, "Text") & @LF & _
                            "-->Why:" & @tab & DllStructGetData($tInfo, "Why"))
                    Return False ; accept the notification and allow the control to display the selected item
;~                  Return True  ; otherwise
                Case $CBEN_GETDISPINFOA, $CBEN_GETDISPINFOW ; Sent to retrieve display information about a callback item
                    _DebugPrint("$CBEN_GETDISPINFO" & _GetComboBoxEx($ilParam))
                    Return 0
                Case $CBEN_INSERTITEM
                    $tInfo = DllStructCreate($tagNMCOMBOBOXEX, $ilParam)
                    Local $tBuffer = DllStructCreate("wchar Text[" & DllStructGetData($tInfo, "TextMax") & "]", DllStructGetData($tInfo, "Text"))
                    _DebugPrint("$CBEN_INSERTITEM" & @lf & "--> hwndfrom:" & @tab & DllStructGetData($tInfo, "hWndFrom") & @LF & _
                            "-->IDFrom:" & @tab & DllStructGetData($tInfo, "IDFrom") & @LF & _
                            "-->Code:" & @tab & DllStructGetData($tInfo, "Code") & @LF & _
                            "-->Mask:" & @tab & DllStructGetData($tInfo, "Mask") & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->Text:" & @tab & DllStructGetData($tBuffer, "Text") & @LF & _
                            "-->TextMax:" & @tab & DllStructGetData($tInfo, "TextMax") & @LF & _
                            "-->Indent:" & @tab & DllStructGetData($tInfo, "Indent") & @LF & _
                            "-->Image:" & @tab & DllStructGetData($tInfo, "Image") & @LF & _
                            "-->SelectedImage:" & @tab & DllStructGetData($tInfo, "SelectedImage") & @LF & _
                            "-->OverlayImage:" & @tab & DllStructGetData($tInfo, "OverlayImage") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    Return 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _GetComboBoxEx($ilParam)
    $tInfo = DllStructCreate($tagNMCOMBOBOXEX, $ilParam)
    Local $aItem = _GUICtrlComboBoxEx_GetItem ($hCombo, DllStructGetData($tInfo, "Item"))
    Return @lf & "--> hwndfrom:" & @tab & DllStructGetData($tInfo, "hWndFrom") & @LF & _
            "-->IDFrom:" & @tab & DllStructGetData($tInfo, "IDFrom") & @LF & _
            "-->Code:" & @tab & DllStructGetData($tInfo, "Code") & @LF & _
            "-->Mask:" & @tab & DllStructGetData($tInfo, "Mask") & @LF & _
            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
            "-->Text:" & @TAB & $aItem[0] & @LF & _
            "-->TextMax:" & @TAB & $aItem[1] & @LF & _
            "-->Indent:" & @TAB & $aItem[2] & @LF & _
            "-->Image:" & @TAB & $aItem[3] & @LF & _
            "-->SelectedImage:" & @TAB & $aItem[4] & @LF & _
            "-->OverlayImage:" & @TAB & $aItem[5] & @LF & _
            "-->Param:" & @TAB & $aItem[5]
EndFunc   ;==>_GetComboBoxEx

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint