↑  ←  Описание функции

GUICtrlCreateUpdown

Создаёт UpDown в GUI.

GUICtrlCreateUpdown ( inputcontrolID [, style = -1 ] )

Параметры

inputcontrolID Идентификатор (controlID) элемента input, для которого будет создан элемент UpDown.
style [необязательный] Стиль элемента. Смотрите Стили элементов GUI в приложении.
-1 - по умолчанию : $UDS_ALIGNRIGHT.
принудительный стиль : $UDS_SETBUDDYINT и $UDS_ALIGNRIGHT если не определено иное выравнивание.

Возвращаемое значение

Успех:Возвращает идентификатор (controlID) нового элемента.
Ошибка:Возвращает 0.

Примечания


Чтобы использовать параметры, указанные выше, вы должны включить в ваш скрипт #include <UpDownConstants.au3>.

Максимальное и минимальное значение может быть установлено с помощью GUICtrlSetLimit.
По умолчанию Windows увеличивает значение при нажатии на верхнюю кнопку со стрелкой.

По умолчанию высота изменяется в соответствии с одним из связанных элементов input.

См. также

GUICtrlCreateInput, GUICtrlSetData, GUICtrlSetLimit

Пример

#include <UpdownConstants.au3>

GUICreate('Updown и стили', 260, 260)

$1 = GUICtrlCreateInput(998, 10, 10, 80, 20)
GUICtrlCreateUpdown(-1) ; с разделителем в 1 000
GUICtrlSetLimit(-1, 32767, 1)
GUICtrlCreateLabel('по умолчанию, ' & @CRLF & 'с разделителем в 1 000', 100, 6, 160, 34)

GUICtrlCreateInput(999, 10, 40, 80, 20)
GUICtrlCreateUpdown(-1, $UDS_NOTHOUSANDS) ; без разделителя в 1000
GUICtrlSetLimit(-1, 32767, 1)
GUICtrlCreateLabel('без разделителя в 1000', 100, 43, 160, 17)

GUICtrlCreateInput(3, 10, 70, 80, 30)
GUICtrlCreateUpdown(-1, $UDS_ALIGNLEFT) ; слева
GUICtrlSetLimit(-1, 9, 1)
GUICtrlCreateLabel('слева', 100, 76, 160, 17)

GUICtrlCreateInput('4', 10, 110, 80, 20)
GUICtrlCreateUpdown(-1, $UDS_ALIGNRIGHT) ; справа
GUICtrlSetLimit(-1, 9, 1)
GUICtrlCreateLabel('справа', 100, 112, 160, 17)

GUICtrlCreateInput(5, 10, 140, 80, 50)
GUICtrlSetFont(-1, 30)
GUICtrlCreateUpdown(-1, $UDS_ARROWKEYS) ; управление клавишами
GUICtrlSetLimit(-1, 9, 1)
GUICtrlCreateLabel('управление клавишами' & @CRLF & 'стрелка вверх' & @CRLF & 'стрелка вниз', 100, 144, 160, 51)

GUICtrlCreateInput(6, 10, 200, 80, 20)
GUICtrlCreateUpdown(-1, $UDS_HORZ) ; горизонтально
GUICtrlSetLimit(-1, 9, 1)
GUICtrlCreateLabel('горизонтально', 100, 203, 160, 17)

GUICtrlCreateInput(7, 10, 230, 80, 20)
GUICtrlCreateUpdown(-1, $UDS_WRAP) ; счёт по кругу
GUICtrlSetLimit(-1, 9, 1)
GUICtrlCreateLabel('счёт по кругу', 100, 232, 160, 17)
GUISetState()

Do
Until GUIGetMsg() = -3

MsgBox(4096, 'Сообщение', GUICtrlRead($1))