Значение у checkbox'ов

[royalfint]

Всем снова привет!
Как можно отметить checkbox? как проверить отмечен он или нет я уже нашел на форуме. А вот как отметить его не нашел :(
Всем заранее спс! :IL_AutoIt_1:

 

[madmasles]

royalfint,
Для своих:
1.

Спойлер

#include <GUIConstantsEx.au3>

GUICreate('Test', 200, 100)
$i_CheckBox = GUICtrlCreateCheckbox('Test Checkbox', 40, 10, 120, 20)
$i_Button = GUICtrlCreateButton('Click me', 40, 50, 120, 30)
GUISetState()
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $i_Button
			Switch BitAND(GUICtrlRead($i_CheckBox), $GUI_CHECKED)
				Case 0
					GUICtrlSetState($i_CheckBox, $GUI_CHECKED)
				Case Else
					GUICtrlSetState($i_CheckBox, $GUI_UNCHECKED)
			EndSwitch
	EndSwitch
WEnd

2.

Спойлер

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

GUICreate('Test', 200, 100)
$i_CheckBox = GUICtrlCreateCheckbox('Test Checkbox', 40, 10, 120, 20)
$i_Button = GUICtrlCreateButton('Click me', 40, 50, 120, 30)
GUISetState()
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $i_Button
			GUICtrlSendMsg($i_CheckBox, $BM_SETCHECK, Not GUICtrlSendMsg($i_CheckBox, $BM_GETCHECK, 0, 0), 0)
	EndSwitch
WEnd

Для чужих:

Спойлер

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>

GUICreate('Test', 200, 100)
GUICtrlCreateCheckbox('Test Checkbox', 40, 10, 120, 20)
$h_CheckBox = GUICtrlGetHandle(-1)
$i_Button = GUICtrlCreateButton('Click me', 40, 50, 120, 30)
GUISetState()
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $i_Button
			_GUICtrlButton_SetCheck($h_CheckBox, Not _GUICtrlButton_GetCheck($h_CheckBox))
	EndSwitch
WEnd

 

[royalfint]

Спс! :beer: