Запрет переименования файлов по клику в проводнике

[CreatoR]

Нужен надёжный метод запрета переименования файлов по клику в проводнике.
Речь идёт о появлений поля Input при клике на выделенном файле в Explorer'е.

Всякие MouseClick/Move/Up/ESC прошу не предлагать.

 

[firex]

CreatoR
Только написание DLL, и никак иначе. Этот аспект создан и контролируется исключительно Explorer'ом, что само по себе логично.

 

[InnI]

#include <WinAPI.au3>

Opt("WinWaitDelay", 0)

While Sleep(10)
  $sCtrl = ControlGetFocus("")
  If StringInStr($sCtrl, "Edit") Then
    $hWnd = ControlGetHandle("", "", $sCtrl)
    If _WinAPI_GetClassName(_WinAPI_GetParent($hWnd)) = "CtrlNotifySink" Then WinClose($hWnd)
  EndIf
WEnd

 

[CreatoR]

InnI
Вот так наверно будет правильнее (для рабочего стола тоже):

#include <WinAPI.au3>
#include <APIConstants.au3>

Opt("WinWaitDelay", 0)

While Sleep(10)
	$sCtrl = ControlGetFocus("")
	
	If StringInStr($sCtrl, "Edit") Then
		$hWnd = ControlGetHandle("", "", $sCtrl)
		$sClass = _WinAPI_GetClassName(_WinAPI_GetAncestor($hWnd, $GA_ROOT))
		
		If StringRegExp($sClass, "^(CabinetWClass|Progman|WorkerW)$") Then
			WinClose($hWnd)
		EndIf
	EndIf
WEnd

Но это не совсем то, нужно более надёжно это делать.

 

[InnI]

CreatoR

так наверно будет правильнее

В данном случае невозможно ввести путь в строке адреса, т.к. при клике там тоже появляется Edit.

нужно более надёжно

Я ещё не встречал пользователя, способного вручную переименовать файл в проводнике за 10 мс

 

[CreatoR]

InnI [?]

Я ещё не встречал пользователя, способного вручную переименовать файл в проводнике за 10 мс

Я про отлов элементов и окон.
И к тому же, меня не волнует возможность юзера переименовать файл, мне нужно на время отключить данное действие, т.к мой скрипт выполняет некие действия при длительном нажатий на файле, и если нажать на выделенном файле, то после отжатия кнопки мышки начинается редактирование имени файла.

Вот так тогда уж:

#NoTrayIcon
#include <WinAPI.au3>
#include <APIConstants.au3>

Global Const $sEditParentClass = "^(SysListView32|CtrlNotifySink)$"
Global Const $sEditAncestorClass = "^((Cabinet|Explore)WClass|Progman|WorkerW)$"

Opt("WinWaitDelay", 0)
HotKeySet('{ESC}', '_Exit')

While Sleep(10)
	$sCtrl = ControlGetFocus("[ACTIVE]")
	
	If StringLeft($sCtrl, 4) = "Edit" Then
		$hWnd = ControlGetHandle("[ACTIVE]", "", $sCtrl)
		$sAncestorClass = _WinAPI_GetClassName(_WinAPI_GetAncestor($hWnd, $GA_ROOTOWNER))
		$sParentClass = _WinAPI_GetClassName(_WinAPI_GetParent($hWnd))
		
		If StringRegExp($sAncestorClass, $sEditAncestorClass) And StringRegExp($sParentClass, $sEditParentClass) Then
			;ControlSend($hWnd, '', '', '{ESC}')
			WinClose($hWnd)
		EndIf
	EndIf
WEnd

Func _Exit()
	Exit
EndFunc

 

[joiner]

CreatoR [?]

Вот так тогда уж:

этот код не дает открыть ни одну папку на рабочем столе. только через правый клик

 

[CreatoR]

joiner [?]

этот код не дает открыть ни одну папку на рабочем столе

Всему виной ControlGetFocus в цикле:

HotKeySet('{ESC}', '_Exit')

While Sleep(10)
	ControlGetFocus("[ACTIVE]")
WEnd

Func _Exit()
	Exit
EndFunc

баг?

 

[madmasles]

CreatoR [?]

баг?

Похоже, что да.

 

[InnI]

CreatoR

после отжатия кнопки мышки начинается редактирование имени файла

Это зависит от настройки. При включении "Открывать одним щелчком, выделять указателем" файлы запускаются.

 

[CreatoR]

InnI [?]

Это зависит от настройки. При включении "Открывать одним щелчком, выделять указателем" файлы запускаются

Мне оно нужно когда эта опция не включена :laugh:.
Интересно где эта опция в реестре проверяется...

 

[InnI]

CreatoR

в реестре проверяется

На Win7 изменения происходят здесь:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer, ShellState (REG_BINARY)

 

[CreatoR]

joiner [?]

этот код не дает открыть ни одну папку на рабочем столе

Обход проблемы:

#NoTrayIcon
#include <APIConstants.au3>
#include <WinAPI.au3>

Global Const $sEditParentClass = '^(SysListView32|CtrlNotifySink)$'
Global Const $sEditAncestorClass = '^((Cabinet|Explore)WClass|Progman|WorkerW)$'

Opt('WinWaitDelay', 0)
HotKeySet('{ESC}', '_Exit')

While Sleep(10)
	$sCtrl = _ControlGetFocusEx('[ACTIVE]')
	
	If StringLeft($sCtrl, 4) = 'Edit' Then
		$hWnd = ControlGetHandle('[ACTIVE]', '', $sCtrl)
		$sAncestorClass = _WinAPI_GetClassName(_WinAPI_GetAncestor($hWnd, $GA_ROOTOWNER))
		$sParentClass = _WinAPI_GetClassName(_WinAPI_GetParent($hWnd))
		
		If StringRegExp($sAncestorClass, $sEditAncestorClass) And StringRegExp($sParentClass, $sEditParentClass) Then
			WinClose($hWnd)
		EndIf
	EndIf
WEnd

Func _ControlGetFocusEx($sTitle)
	Local $aRet
	
	While 1
		$aRet = DllCall('user32.dll', 'short', 'GetAsyncKeyState', 'int', '0x01')
		
		If Not @error And BitAND($aRet[0], 0x8000) <> 0 Then
			Sleep(RegRead('HKCU\Control Panel\Mouse', 'DoubleClickSpeed') + 50)
		Else
			Return ControlGetFocus($sTitle)
		EndIf
	Wend
EndFunc

Func _Exit()
	Exit
EndFunc

По мотивам тикета...

madmasles [?]

Похоже, что да.

Хотел создать тикет, но оказывается (см. выше) такой уже создан, причём 7 лет назад.
Не стали исправлять т.к баг системный (при получении фокуса сбрасывается состояние поля ввода).

 

[InnI]

Ещё вариант для Win7 и выше

#include <WinAPI.au3>
#include "UIAutomate.au3"

$UIA_ConsoleWriteError = 0

While Sleep(10)
  $oCtrl = _UIA_GetFocusedElement()
  $hWnd = HWnd(_UIA_ElementGetPropertyValue($oCtrl, "NativeWindowHandle"))
  $sClass = _UIA_ElementGetPropertyValue($oCtrl, "ClassName")
  $sRootClass = _WinAPI_GetClassName(_WinAPI_GetAncestor($hWnd, 2))
  If $sClass = "UIRenameTextElement" Or ($sClass = "Edit" And ($sRootClass = "Progman" Or $sRootClass = "WorkerW")) Then ControlSend("", "", $hWnd, "{ESC}")
WEnd