Выполнение команд из текстового файла

[MockeR]

Как сделать чтобы AutoIt выполнял команды, которые записаны в текстовом файле?

 

[madmasles]

MockeR
Например, так

$aText = StringSplit(StringStripCR(FileRead('test.txt')), @LF)

If $aText[0] Then
	For $i = 1 To $aText[0]
		If StringInStr($aText[$i], 'пожалуйста') Then
			If StringInStr($aText[$i], 'сообщение') Then
				$aMessage = StringRegExp($aText[$i], '"(.*?)"', 3)
				If IsArray($aMessage) Then
					MsgBox(64, 'Строка ' & $i, $aMessage[0])
				EndIf
			EndIf
		Else
			MsgBox(16, 'Строка ' & $i, 'А где волшебное слово?')
		EndIf
	Next
EndIf

В файле test.txt

Покажи сообщение с текстом "Пробный текст-1"
Покажи, пожалуйста, сообщение с текстом "Пробный текст-1"

 

[MockeR]

спасибо, работает
а если файл test.txt содержит

MsgBox(0, "Test", "Hello World:)")

Как эту команду выполнить?

 

[madmasles]

MockeR

$aText = StringSplit(StringStripCR(FileRead('test.txt')), @LF)

If $aText[0] Then
	For $i = 1 To $aText[0]
		Execute($aText[$i])
		If @error Then
			MsgBox(16, 'Error', 'Ошибка в строке ' & $i)
		EndIf
	Next
EndIf

В файле test.txt

MsgBox(0, "Test", "Hello World:)")

Или так:

;$aText = StringSplit(StringStripCR(FileRead('test.txt')), @LF)

For $i = 1 To 10
	$iIndex = Random(1, 5, 1)
	;MsgBox(64, $i, $aText[$iIndex])
	MsgBox(64, $i, FileReadLine('test.txt', $iIndex), 1)
Next

В файле test.txt

Один
Два
Три
Четыре
Пять

 

[MockeR]

А если в файле есть разные команды, то как заставить AutoIt их выполнить? :wall_brake:

 

[MockeR]

помогите!!! :'(

 

[CreatoR]

MockeR [?]

А если в файле есть разные команды, то как заставить AutoIt их выполнить?

Тебе же показали как:

$aFuncs = StringSplit(StringStripCR(FileRead('test.txt')), @LF)

For $i = 1 To UBound($aFuncs)-1
    Execute($aFuncs[$i])
Next

 

[MockeR]

MockeR [?]

А если в файле есть разные команды, то как заставить AutoIt их выполнить?

Тебе же показали как:

$aFuncs = StringSplit(StringStripCR(FileRead('test.txt')), @LF)

For $i = 1 To UBound($aFuncs)-1
    Execute($aFuncs[$i])
Next

Это конечно работает, но только для команд которые содержатся только на одной строке.
А если там будет, например,

Спойлер

test.txt

MsgBox(0, "2", "msg1")
MsgBox(0, "2", "msg2")
For $q = 1 to 5
	MsgBox(0, "Test", $q)
Next

то сдесь выполняются только 2 первых мессагбокса :(

 

[aleratorio]

Run(@AutoItExe & ' test.txt', @ScriptDir)

 

[madmasles]

MockeR [?]

Это конечно работает, но только для команд которые содержатся только на одной строке.
А если там будет, например,...

А зачем это?

 

[MockeR]

MockeR [?]

Это конечно работает, но только для команд которые содержатся только на одной строке.
А если там будет, например,...

А зачем это?

просто нужно сделать программу которая будет выполнять все команд из заданого файла!!!


Добавлено:

Сообщение автоматически объединено: 29 Дек 2010

Run(@AutoItExe & ' test.txt', @ScriptDir)

не работает :(

 

[aleratorio]

Не знаю, у меня работает. test.txt находится в каталоге со скриптом.

 

[madmasles]

MockeR [?]

просто нужно сделать программу которая будет выполнять все команд из заданого файла!!!

Тогда Вам надо четко определиться в каком виде эти команды будут в файле.

 

[MockeR]

MockeR [?]

просто нужно сделать программу которая будет выполнять все команд из заданого файла!!!

Тогда Вам надо четко определиться в каком виде эти команды будут в файле.

команды могут быть разные!!! начиная от ClipGet() и заканчивая _WordQuit()


Добавлено:

Сообщение автоматически объединено: 29 Дек 2010

Не знаю, у меня работает. test.txt находится в каталоге со скриптом.

это работает только со скриптом!!!
с скомпилированной программой @AutoItExe возвращает не путь AutoIt'a, а путь этой же программы(((

 

[aleratorio]

Run(@AutoItExe & ' /AutoIt3ExecuteScript test.txt', @ScriptDir)

работает и со скриптом и с exe-шником

 

[MockeR]

ops: вот так действительно работает!!! :thumbs_up:
Спасибо!!! :smoking:

С меня +1 :beer:

 

[CreatoR]

Я когда то делал так:

#include <File.au3>

$sReadIncl = _
	'#NoTrayIcon' & @CRLF & _
	'ConsoleWrite("Return from Line #" & @ScriptLineNumber & ": " & TestFunc("Test"))' & @CRLF & _
	'ConsoleWrite("Return from Line #" & @ScriptLineNumber & ": " & MsgBox(36, "", "Are you sure?"))' & @CRLF & _
	'Func TestFunc($sParam)' & @CRLF & _
	'	Return $sParam' & @CRLF & _
	'EndFunc'

$sRet = _AutoIt3ExecuteCode($sReadIncl)

ConsoleWrite($sRet)

Func _AutoIt3ExecuteCode($sCode)
	Local $sTmpFile = _TempFile(@TempDir, "~AutoIt3ExecuteCode_")
	FileWrite($sTmpFile, $sCode)
	
	Local $iPID = Run(@AutoItExe & ' /ErrorStdOut /AutoIt3ExecuteScript "' & $sTmpFile & '"', @WorkingDir, 0, 2)
	Local $sStdOut_Read = "", $sStdOut_Ret = ""
	
	While 1
		$sStdOut_Read = StdoutRead($iPID)
		
		If @error <> 0 Then
			ExitLoop
		EndIf
		
		If $sStdOut_Read <> "" Then
			$sStdOut_Ret &= $sStdOut_Read & @CRLF
		EndIf
		
		Sleep(10)
	WEnd
	
	FileDelete($sTmpFile)
	Return $sStdOut_Ret
EndFunc

Тут естественно вместо содержимого $sReadIncl нужно подставить FileRead("MyFuncs.txt").

 

[aleratorio]

Да не за что... Просто если бы вопрос (или название темы) были сформулированы как: "Запуск txt-файла, как au3-скрипта из другого скрипта" - думаю ответили бы сразу...

 

[MockeR]

Creator, Спасибо, это тоже отлично работает!!!
+1


Добавлено:

Сообщение автоматически объединено: 30 Дек 2010

Да не за что... Просто если бы вопрос (или название темы) были сформулированы как: "Запуск txt-файла, как au3-скрипта из другого скрипта" - думаю ответили бы сразу...

Ничего)) главное что проблема решена!!! ;D

 

[CreatoR]

MockeR
Не нужно цитировать всё сообщение (тем более включая код), достаточно только тот текст, на который отвечаешь.