Выбор нескольких файлов

Parazit · 29 Дек 2016

Привет. Почему у меня не получается переместить/копировать несколько файлов?
Когда один файл выбран, то нормально, а когда выбрано более, то ни один не обрабатывается

Код:

$file=FileOpenDialog("Select Files", "", "All Files (*.*)", 4)
$dir=FileSelectFolder("Select Folder", "", 2)
FileCopy($file, $dir)

InnI · 29 Дек 2016

Parazit

Почему у меня не получается

В справке сказано:
[box]Возвращаемое значение
Успех: Возвращает полный путь и имена выбранных файлов. Результат для нескольких объектов: "Каталог|Файл1|Файл2|..."[/box]
Если вам сложно понять смысл написанного, то можно разобрать пример в той же справке. В противном случае результат работы функции при выборе нескольких файлов можно просто посмотреть

Код:

$file=FileOpenDialog("Select Files", "", "All Files (*.*)", 4)
MsgBox(0, "", $file)

joiner · 29 Дек 2016

чуть было не выложил готовый вариант :smile:

Parazit
ничего оскорбительного в словах InnI нет. всегда найдется что-то, что трудно понять. я сам много не понимаю. стараюсь экспериментировать с чужими примерами чтобы добиться нужного результата. но я признаю, что не понимаю. и не даун
у тебя не получается скопировать, потому что нужно формировать пути. ты этого не понял. вот тебя и подтолкнули к размышлению.
ты сейчас в роли спрашивающего, так будь благодарен за любой совет. иначе тебе больше никто здесь помогать не будет. это факт

Parazit · 29 Дек 2016

Извиняюсь, я погорячился

Garrett · 29 Дек 2016

OffTopic:
Parazit
Ещё одно оскорбление и я выпишу вам бан на недельку, чтобы вы подумали.

joiner · 29 Дек 2016

примерный пример :smile:

Код:

Local $title = "Удерживайте клавиши Ctrl или Shift, чтобы выбрать несколько файлов."
Local $var = FileOpenDialog($title, @ScriptDir, "Все файлы (*)", 1 + 4)
If @error Then
	MsgBox(4096, "", "Не выбрано ни одного файла")
Else
	Local $sPath
	Local $sDest = FileSelectFolder('Выбор папки назначения', @ScriptDir, 7)
	If @error Then Exit
	$var = StringSplit($var, "|")
	$sPath = $var[1] & '\'
	$sDest = $sDest & '\'
	For $i = 2 To $var[0]
		FileCopy($sPath & $var[$i], $sDest & $var[$i], 9)
	Next
EndIf

Parazit · 29 Дек 2016

Спасибо
Добавлено:
Сообщение автоматически объединено: 29 Дек 2016

joiner, а как мне проверять на наличие файлов в каталоге назначения, и в случае их присутствия,
добавлять к копируемым именам файлов счётчик?

Dessan · 29 Дек 2016

Parazit сказал(а):
Извиняюсь, я погорячился

Я потратил 2 часа времени, разбирая твой вопрос и комментарий от InnI. Перепробовал много вариантов, начитался справки, MsgBox выдаёт результат в виде: "Каталог|Файл1|Файл2|..." Но у меня также не копировалось несколько файлов, добавил функцию StringReplace , везде проставил "|", пробовал с @CRLF - файлы не копируются. Сижу сам тут как тот идиот и жду продолжения твоего диалога с InnI для дальнейших пояснений. А теперь, из-за тебя горячего, я не узнаю к какому пути решения тебя подталкивали.

Parazit · 29 Дек 2016

Dessan, вон же joiner уже дал рабочий скрипт. Осталось выяснить, как добавлять счётчик

joiner · 29 Дек 2016

Parazit
типа файл_копия_1, файл_копия_2 и так далее?
Добавлено:
Сообщение автоматически объединено: 29 Дек 2016

если я правильно понял, то можно так

Код:

Local $title = "Удерживайте клавиши Ctrl или Shift, чтобы выбрать несколько файлов."
Local $var = FileOpenDialog($title, @ScriptDir, "Все файлы (*)", 1 + 4)
If @error Then
	MsgBox(4096, "", "Не выбрано ни одного файла")
Else
	Local $sPath, $iC, $extn
	Local $sDest = FileSelectFolder('Выбор папки назначения', @ScriptDir, 7)
	If @error Then Exit
	$var = StringSplit($var, "|")
	$sPath = $var[1] & '\'
	$sDest = $sDest & '\'
	For $i = 2 To $var[0]
		If FileExists($sDest & $var[$i]) Then
			$extn = _div($var[$i])
			Do
				$iC += 1
			Until Not FileExists($sDest & $extn[0] & '(' & $iC & ')' & $extn[1])
			FileCopy($sPath & $var[$i], $sDest & $extn[0] & '(' & $iC & ')' & $extn[1])
			$iC = 0
		Else
			FileCopy($sPath & $var[$i], $sDest & $var[$i])
		EndIf
	Next
EndIf

Func _div($sString)
	Local $div[2]
	Local $ip = StringInStr($sString, '.', 0, -1)
	Local $name = StringLeft($sString, $ip - 1)
	Local $ext = StringTrimLeft($sString, $ip - 1)
	$div[0] = $name
	$div[1] = $ext
	Return $div
EndFunc   ;==>_div

Parazit · 30 Дек 2016

joiner, да, можно "файл_копия_1", а можно просто "name-1", "name-2", и т.д.
Ваш скрипт не совсем правильно работает.
Он работает, когда выбрано несколько файлов, но когда выбран только один, то файл не копируется

joiner · 30 Дек 2016

Тогда так

Код:

Local $title = "Удерживайте клавиши Ctrl или Shift, чтобы выбрать несколько файлов."
Local $var = FileOpenDialog($title, @ScriptDir, "Все файлы (*)", 1 + 4)
If @error Then
	MsgBox(4096, "", "Не выбрано ни одного файла")
Else
	Local $sPath, $iC, $extn
	Local $sDest = FileSelectFolder('Выбор папки назначения', @ScriptDir, 7)
	If @error Then Exit
	$sDest = $sDest & '\'
	$var = StringSplit($var, "|")
	If UBound($var) = 2 Then
		Local $gtn = StringRegExpReplace($var[1], '.*\\', '')
		If FileExists($sDest & $gtn) Then
			$extn = _div($gtn)
			Do
				$iC += 1
			Until Not FileExists($sDest & $extn[0] & '-' & $iC & $extn[1])
			FileCopy($var[1], $sDest & $extn[0] & '-' & $iC & $extn[1])
		Else
			FileCopy($var[1], $sDest & $gtn)
		EndIf
	Else
		$sPath = $var[1] & '\'
		For $i = 2 To $var[0]
			If FileExists($sDest & $var[$i]) Then
				$extn = _div($var[$i])
				Do
					$iC += 1
				Until Not FileExists($sDest & $extn[0] & '-' & $iC & $extn[1])
				FileCopy($sPath & $var[$i], $sDest & $extn[0] & '-' & $iC & $extn[1])
				$iC = 0
			Else
				FileCopy($sPath & $var[$i], $sDest & $var[$i])
			EndIf
		Next
	EndIf
EndIf

Func _div($sString)
	Local $div[2]
	Local $ip = StringInStr($sString, '.', 0, -1)
	Local $name = StringLeft($sString, $ip - 1)
	Local $ext = StringTrimLeft($sString, $ip - 1)
	$div[0] = $name
	$div[1] = $ext
	Return $div
EndFunc   ;==>_div

Parazit · 30 Дек 2016

joiner, гениально. Спасибо

joiner, задача чуть изменилась. Сам я это не осилю.
Я передаю выделенные в Total Commander файлы через параметр %P%S.
Т.е., мне не надо уже использовать FileOpenDialog. Как мне правильно это организовать?

Код:

$sDest = FileSelectFolder('Select Folder', '', 7)
For $i=1 To $CmdLine[0]
;If FileExists($sDest & $CmdLine[$i]) Then
        ;FileCopy($CmdLine[$i] + 'sss', $sDest)
;EndIf
;Next

;
;
;Local $title = "Удерживайте клавиши Ctrl или Shift, чтобы выбрать несколько файлов."
;Local $var = FileOpenDialog($title, @ScriptDir, "Все файлы (*)", 1 + 4)
;If @error Then
    ;MsgBox(4096, "", "Не выбрано ни одного файла")
;Else
    ;Local $sPath, $iC, $extn
;    
    ;$var = 
;    Local $sDest = FileSelectFolder('Выбор папки назначения', @ScriptDir, 7)
    ;If @error Then Exit
    $sDest = $sDest & '\'
    $CmdLine = StringSplit($CmdLine, "|")
    If UBound($CmdLine) = 2 Then
        Local $gtn = StringRegExpReplace($CmdLine[1], '.*\\', '')
        If FileExists($sDest & $gtn) Then
            $extn = _div($gtn)
            Do
                $iC += 1
            Until Not FileExists($sDest & $extn[0] & '-' & $iC & $extn[1])
            FileCopy($CmdLine[1], $sDest & $extn[0] & '-' & $iC & $extn[1])
        Else
            FileCopy($CmdLine[1], $sDest & $gtn)
        EndIf
    Else
        $sPath = $CmdLine[1] & '\'
        For $i = 2 To $CmdLine[0]
            If FileExists($sDest & $CmdLine[$i]) Then
                $extn = _div($CmdLine[$i])
                Do
                    $iC += 1
                Until Not FileExists($sDest & $extn[0] & '-' & $iC & $extn[1])
                FileCopy($sPath & $CmdLine[$i], $sDest & $extn[0] & '-' & $iC & $extn[1])
                $iC = 0
            Else
                FileCopy($sPath & $CmdLine[$i], $sDest & $CmdLine[$i])
            EndIf
        Next
    EndIf
        Next
;EndIf

Func _div($sString)
    Local $div[2]
    Local $ip = StringInStr($sString, '.', 0, -1)
    Local $name = StringLeft($sString, $ip - 1)
    Local $ext = StringTrimLeft($sString, $ip - 1)
    $div[0] = $name
    $div[1] = $ext
    Return $div
EndFunc

joiner · 30 Дек 2016

в каком виде передается строка в $CmdLine ?

Parazit · 30 Дек 2016

Выделенные файлы с полным путём.
Как обычные аргументы, переданные скрипту, начиная с нулевого.

joiner · 30 Дек 2016

Parazit
пример приведи. я не пользуюсь ТС

Parazit · 31 Дек 2016

Это то же самое, как ввести в окне cmd.exe.

"C:\FileCopy.au3" "C:\111.txt" "C:\222.txt"

joiner · 31 Дек 2016

собери нижеприведенный скрипт в экзешник и перетащи мышкой на него файлы

Код:

Local $iC, $extn, $gtn
Local $sDest = FileSelectFolder('Выбор папки назначения', @ScriptDir, 7)
If @error Then Exit
$sDest = $sDest & '\'
For $i = 1 To $cmdline[0]
	$gtn = StringRegExpReplace($cmdline[$i], '.*\\', '')
	If FileExists($sDest & $gtn) Then
		$extn = _div($gtn)
		Do
			$iC += 1
		Until Not FileExists($sDest & $extn[0] & '-' & $iC & $extn[1])
		FileCopy($cmdline[$i], $sDest & $extn[0] & '-' & $iC & $extn[1])
		$iC = 0
	Else
		FileCopy($cmdline[$i], $sDest & $gtn)
	EndIf
Next

Func _div($sString)
	Local $div[2]
	Local $ip = StringInStr($sString, '.', 0, -1)
	Local $name = StringLeft($sString, $ip - 1)
	Local $ext = StringTrimLeft($sString, $ip - 1)
	$div[0] = $name
	$div[1] = $ext
	Return $div
EndFunc   ;==>_div

Parazit · 31 Дек 2016

Спасибо, это то, что доктор прописал.

Автор темы	Похожие темы	Форум	Ответы	Дата
J	Выбор пункта ControlTreeView по части имени пункта	Общие вопросы по AutoIt	1	20 Ноя 2023
	FileOpenDialog и FileSelectFolder не справляются. Мультивыбор файлов и/или папок	Общие вопросы по AutoIt	11	23 Апр 2023
D	Выбор нескольких вариантов из выпадающего списка	Общие вопросы по AutoIt	4	25 Дек 2021
	GUISelButton - Выбор нескольких вариантов из выпадающего списка	UDF - Пользовательские функции	7	22 Янв 2017
D	_IELinkGetCollection - выбор нескольких ссылок и нажимание на них подряд	Автоматизация IE и Web-интерфейса	10	19 Ноя 2014

Поиск

Поиск

Выбор нескольких файлов

Parazit

InnI

AutoIT Гуру

joiner

Модератор

Parazit

Garrett

Модератор

joiner

Модератор

Parazit

Dessan

Parazit

joiner

Модератор

Parazit

joiner

Модератор

Parazit

joiner

Модератор

Parazit

joiner

Модератор

Parazit

joiner

Модератор

Parazit