Установка текста в элемент

[Rinfes]

С помощью программы отловлен элемент, который показывает время: [CLASS:SysDateTimePick32; INSTANCE:1]
Значение этого элемента выводится в формате ЧЧ:ММ:СС
Пытаюсь поставить нужное для себя время. Команды не помогают. Что делать?

ControlSetText("Окно №1", "", "[CLASS:SysDateTimePick32; INSTANCE:1]", "20:00:00")
ControlSend("Окно №1", "", "[CLASS:SysDateTimePick32; INSTANCE:1]", "20:00:00")

Исходный код этой программы:

Спойлер

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>


Example1()
Func Example1()
    Local $n, $msg

    GUICreate("Время", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState()

    ; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(4096, "Время", GUICtrlRead($n))
    GUIDelete()
EndFunc

 

[edyapd]

Да вроди можно заменить

Спойлер

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>

HotKeySet('{F1}', '_EditTime')

Example1()
Func Example1()
    Local $n, $msg

    GUICreate("Время", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState()

    ; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(4096, "Время", GUICtrlRead($n))
    GUIDelete()
EndFunc

Func _EditTime()
	ControlSend("Время", "", "[CLASS:SysDateTimePick32; INSTANCE:1]", "20:00:00")
EndFunc

Только оно не тикает

 

[Rinfes]

Ну вот если программа скомпилирована и запускается как exe файл, то не работает. Кстати, ваш вариант не полностью рабочий. число "20" устанавливается в ту ячейку времени, которая выбрана.

Установить время получается, если добавить в начало

ControlFocus("Окно №1", "", "[CLASS:SysDateTimePick32; INSTANCE:1]")

Но если скрипт запустить еще раз, то "20 часов" он поставить в минуты

 

[edyapd]

Сейчас почитал справку. Я так понимаю, что в поле дата можно устанавливать с помощью команды

$Err = GUICtrlSetData($n, '00:00:00')
ConsoleWrite($Err & @LF)

Только не пойму, почему возращает 0, то есть ошибка. При этом время не устанавливается.
Может кто-то сможет подсказать, как это правильно делать.

 

[Cornet]

GUICtrlSetData($n, "2015/06/08 19:20:51")

 

[edyapd]

Да, теперь это точно работает.

Спойлер

#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>

HotKeySet('{F1}', '_EditTime')
Global $n
Example1()
Func Example1()
    Local $msg

    GUICreate("Время", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState()

    ; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(4096, "Время", GUICtrlRead($n))
    GUIDelete()
EndFunc

Func _EditTime()
	$sTime = InputBox('Ввод времени', 'Введите время:', GUICtrlRead($n))
	If StringRegExp($sTime, '^([01]?[0-9]|2[0-3])(:[0-5][0-9]){2}', 0) Then
		$sTime = '2015/01/01 ' & $sTime
		GUICtrlSetData($n, $sTime)
		ConsoleWrite($sTime & @LF)
	Else
		MsgBox(0, 'Ошибка', 'Не корректное время', 5)
	EndIf
EndFunc