Смена картинки в диалоге по значению в ComboBox

[prokazzza]

Подскажите простой способ смены картинки в диалоге при выборе значений в ComboBox. К примеру при выборе key1 показывалась картинка 1.jpg, при выборе key2 картинка 2.jpg и т.д.

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>

$Form1 = GUICreate("", 228, 78)
$Pic1 = GUICtrlCreatePic(@ScriptDir & '\1.jpg', 8, 16, 89, 49)
$Combo1 = GUICtrlCreateCombo("", 138, 28, 73, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Key1|Key2", "Key1")
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd

 

[CreatoR]

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>

$Form1 = GUICreate("", 228, 78)
$Pic1 = GUICtrlCreatePic(@ScriptDir & '\1.jpg', 8, 16, 89, 49)
$Combo1 = GUICtrlCreateCombo("", 138, 28, 73, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Key1|Key2", "Key1")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
	
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
		Case $Combo1
			Switch GUICtrlRead($Combo1)
				Case "Key1"
					GUICtrlSetImage($Pic1, @ScriptDir & '\1.jpg')
				Case "Key2"
					GUICtrlSetImage($Pic1, @ScriptDir & '\2.jpg')
			EndSwitch
    EndSwitch
WEnd

или так:

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>

$Form1 = GUICreate("", 228, 78)
$Pic1 = GUICtrlCreatePic(@ScriptDir & '\1.jpg', 8, 16, 89, 49)
$Combo1 = GUICtrlCreateCombo("", 138, 28, 73, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Key1|Key2", "Key1")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
	
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
		Case $Combo1
			$iKey = StringRight(GUICtrlRead($Combo1), 1)
			GUICtrlSetImage($Pic1, @ScriptDir & '\' & $iKey & '.jpg')
    EndSwitch
WEnd

 

[prokazzza]

CreatoR благодарю !!!