Что нового

[Сеть, интернет] Сокращение ссылок на vk.cc [POST зпрос]

Duff1993

Новичок
Сообщения
29
Репутация
0
Добрый день. Подскажите пожалуйста, как реализовать сокращение ссылок в окне через сервис vk.cc

Вот как получилось для сервиса bit.ly

Насколько я понял, в вк.сс нету апи, поэтому надо использовать пост запрос. Но как это реализовать? :stars:

Код:
$sLong_Url = InputBox('Get Shorten Link', 'Enter long url to get shorten version:', 'http://www.google.com') ;$CmdLine[2]
If @error Then Exit

$sUser_Name = 'autoit3user'
$sAPI_Key = 'R_f4f7554a3e8648d85980a489bbc7fce8'

$sShort_Url = InetRead('http://api.bit.ly/v3/shorten?login=' & $sUser_Name & '&apiKey=' & $sAPI_Key & '&longUrl=' & _EncodeURI($sLong_Url) & '&format=txt')
$sShort_Url = StringStripWS(BinaryToString($sShort_Url), 3)

InputBox('Get Shorten Link', 'Shorten version, copy to clipboard?', $sShort_Url)
If Not @error Then ClipPut($sShort_Url)

Func _EncodeURI($sURLString)
    Local $aURLStrSplit = StringSplit($sURLString, "")
    Local $sRetString = ""

    For $i = 1 To UBound($aURLStrSplit) - 1
        If Not StringRegExp($aURLStrSplit[$i], '(?i)[a-z]|\.|-|_') Then $aURLStrSplit[$i] = "%" & Hex(Asc($aURLStrSplit[$i]), 2)
        $sRetString &= $aURLStrSplit[$i]
    Next

    Return $sRetString
EndFunc
 

gloss

Ленивое кодило
Сообщения
155
Репутация
5
Re: [Сеть, интернет] Сокращение ссылок на vk.cc

OffTopic:
Получилось? Стырено же отсюда
 
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
Re: [Сеть, интернет] Сокращение ссылок на vk.cc

gloss сказал(а):
OffTopic:
Получилось? Стырено же отсюда

Да, именно оттуда взял битл.

Насколько я понял, надо создать пост запрос с параметром "act=shorten&link=google.com". Однако вопрос, как это привязать к GUI Autoit?
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Duff1993
Я делал когда-то эту штуку, только не на autoit, а на PHP, но не суть.
Для того, чтобы сделать ссылку, надо авторизоваться в ВК, причём не как приложение, а с логином и паролем, как это делает обычный браузер, хотя может и ошибаюсь. И уже потом отправить запрос.

Duff1993 [?]
вопрос, как это привязать к GUI Autoit?
GUI здесь не причём. POST запросы делаются обычно через WinHttpRequest.


Добавлено:
Сообщение автоматически объединено:

Запрос:
Код:
POST https://vk.com/cc HTTP/1.1
Host: vk.com
User-Agent: Mozilla/5.0...
Content-Type: application/x-www-form-urlencoded; charset=UTF-8
X-Requested-With: XMLHttpRequest
Referer: https://vk.com/cc
Content-Length: 86
Cookie: remix...
Connection: keep-alive
Pragma: no-cache
Cache-Control: no-cache

act=shorten&al=1&link=http%3A%2F%2Fautoit-script.ru%2Findex.php%2Ftopic%2C20411.0.html

и ответ:
Код:
HTTP/1.1 200 OK
Server: Apache
Date: Wed, 22 Jul 2015 04:40:07 GMT
Content-Type: text/plain; charset=windows-1251
Content-Length: 84
Connection: keep-alive
X-Powered-By: PHP/3.15977
Pragma: no-cache
Cache-control: no-store

18028<!>profile.css,page.css,profile.js,page.js<!>0<!>6659<!>0<!>http://vk.cc/411GNd

Соответственно можно сделать
Код:
$aStringSplit=StringSplit($response, "<!>", 1)
$sLink=$aStringSplit[$aStringSplit[0]]
как-нибудь так... Ну или множество вариантов с регулярными выражениями.
 
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
Спасибо!

Подскажите пожалуйста, как это реализовать через скрипты AutoIT. Пол ночи читал справки, искал примеры но так и не получилось :(.
Буду очень, очень признателен!
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Duff1993 сказал(а):
Спасибо!

Подскажите пожалуйста, как это реализовать через скрипты AutoIT. Пол ночи читал справки, искал примеры но так и не получилось :(.
Буду очень, очень признателен!

Вот, написал.
Несколько раз проверил, всё отлично работает! Ура!
Пробуйте.
Код:
Global $url = _VKShortURL("7***48***1*", "*********", "http://google.ru/")
MsgBox(0, "url", $url)


Func _VKShortURL($sLogin, $sPassword, $sURL)
	Local $oReq, $sSendStr, $Cookie, $sAction, $sURLCC
	Local $sResponse, $aStringSplit, $sLink
	$sURLCC = "https://vk.com/cc"
	$sUserAgent = 'Mozilla/5.0 (Windows NT 6.1; rv:27.0) Gecko/20100101 Firefox/27.0'
	$oReq = ObjCreate('WinHttp.WinHttpRequest.5.1')
	If Not IsObj($oReq) Then Return SetError(1, 0, 0)
	$oReq.Open('GET', "http://m.vk.com/", False)
	$oReq.SetRequestHeader('User-Agent', $sUserAgent)
	$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
	If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
	$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
	$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
	$oReq.SetRequestHeader('Connection', 'keep-alive')
	$oReq.Send($sSendStr)
	$Cookie = __SetCookieParse($oReq.GetAllResponseHeaders())
	$sResponse = $oReq.responseText
	If StringInStr($sResponse, '://login.vk.com/?act=login') Then
		$sAction = StringRegExpReplace($sResponse, "(?si).*?\<form.*?action\=['""](.*?)['""].*?\>.*", "$1")
		$oReq.Open('POST', $sAction, False)
		$oReq.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded; charset=UTF-8')
		$oReq.SetRequestHeader('User-Agent', $sUserAgent)
		$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
		If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
		$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
		$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
		$oReq.SetRequestHeader('Connection', 'keep-alive')
		$oReq.SetRequestHeader('Referer', 'http://m.vk.com/')
		$sSendStr = 'email=' & __encodeURIComponent($sLogin) & '&pass=' & __encodeURIComponent($sPassword) & ''
		$oReq.Send($sSendStr)
	EndIf
	$oReq.Open('POST', $sURLCC, False)
	$oReq.SetRequestHeader('X-Requested-With', 'XMLHttpRequest')
	$oReq.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded; charset=UTF-8')
	$oReq.SetRequestHeader('User-Agent', $sUserAgent)
	$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
	If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
	$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
	$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
	$oReq.SetRequestHeader('Connection', 'keep-alive')
	$oReq.SetRequestHeader('Referer', $sURLCC)
	$sSendStr = 'act=shorten&al=1&link=' & __encodeURIComponent($sURL)
	$oReq.Send($sSendStr)
	$sResponse = $oReq.responseText
	ConsoleWrite("POST_REQUEST: " & $sSendStr & @CRLF)
	ConsoleWrite("RESPONSE: " & $sResponse & @CRLF)
	$aStringSplit = StringSplit($sResponse, "<!>", 1)
	If @error Then Return SetError(@error, @extended, 0)
	$sLink = $aStringSplit[$aStringSplit[0]]
	Return $sLink
EndFunc   ;==>_VKShortURL

Func __SetCookieParse($AllResponseHeaders)
	$sCOOKIES = ""
	$aResponseHeaders = StringSplit($AllResponseHeaders, @CRLF)
	For $i = 1 To $aResponseHeaders[0]
		If StringLeft($aResponseHeaders[$i], 10) = 'Set-Cookie' Then
			$iPozSim = StringInStr($aResponseHeaders[$i], ';')
			$sCOOKIES &= StringMid($aResponseHeaders[$i], 13, $iPozSim - 13) & '; '
		EndIf
	Next
	$sCOOKIES = StringMid($sCOOKIES, 1, StringLen($sCOOKIES) - 2)
	Return $sCOOKIES
EndFunc   ;==>__SetCookieParse

Func __encodeURIComponent($sTxt)
	$sTxt = StringReplace($sTxt, @CRLF, '\r\n')
	$sTxt = StringReplace($sTxt, @CR, '\r')
	$sTxt = StringReplace($sTxt, @LF, '\n')
	$sTxt = StringReplace($sTxt, "'", "\'")
	$oSC = ObjCreate("ScriptControl")
	If Not IsObj($oSC) Then Return SetError(1)
	$oSC.Language = "JavaScript"
	Return $oSC.Eval('encodeURIComponent("' & $sTxt & '");')
EndFunc   ;==>__encodeURIComponent
Func __decodeURIComponent($sTxt)
	$sTxt = StringReplace($sTxt, @CRLF, '\r\n')
	$sTxt = StringReplace($sTxt, @CR, '\r')
	$sTxt = StringReplace($sTxt, @LF, '\n')
	$sTxt = StringReplace($sTxt, "'", "\'")
	$oSC = ObjCreate("ScriptControl")
	If Not IsObj($oSC) Then Return SetError(1)
	Return $oSC.Eval('decodeURIComponent("' & $sTxt & '");')
EndFunc   ;==>__decodeURIComponent
Функции я думаю лучше вынести в отдельный файл (UDF) и подключать его через #include, так будет удобнее. Например так:
Код:
#include "VK_short_URL.au3"
$url = _VKShortURL("79004321678", "qwERTy123", "http://example.com/pg789.html")
MsgBox(0, "example url", $url)
 

gloss

Ленивое кодило
Сообщения
155
Репутация
5
OffTopic:
Только таким макаром можно сильно спалиться.
Лучше использовать левую учетку.
Pjkzke6.png
 

inververs

AutoIT Гуру
Сообщения
2,135
Репутация
465
OffTopic:
gloss
что за програмка такая?
 

inververs

AutoIT Гуру
Сообщения
2,135
Репутация
465
OffTopic:
она что умеет показывать HTTPS трафик для autoit? а для Flash тоже может?
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
Странно, но у меня не работает.

Получаю вот такое сообщение: http://clip2net.com/s/3lnQFN6
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Я протестировал, обычно такое бывает, если ввести неправильные логин и пароль от ВК. У меня всё работает, сократил сегодня перед написанием этого сообщения 39 ссылок, всё норм. Потом сделал GUI небольшое, там input для логина, пароля и URL, сокращал несколько ссылок через него, тоже всё нормально.
 
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
alex33 сказал(а):
Я протестировал, обычно такое бывает, если ввести неправильные логин и пароль от ВК. У меня всё работает, сократил сегодня перед написанием этого сообщения 39 ссылок, всё норм. Потом сделал GUI небольшое, там input для логина, пароля и URL, сокращал несколько ссылок через него, тоже всё нормально.

А можешь поделится GUI, предварительно выделив места, где надо вбить аккаунт ВК?
Извини, что по пустякам дергаю из за своей безрукости. Спасибо!
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Duff1993 [?]
А можешь поделится GUI
Код:
#include <GUIConstants.au3>
#include <EditConstants.au3>
Global $url, $gui, $input1, $input2, $input3, $input4, $btn1
Opt("GUICloseOnESC", 0)
$gui = GUICreate("ВК Сокращалка ссылок", 400, 300)
GUICtrlCreateLabel("Логин", 10, 10, 90, 30)
$input1 = GUICtrlCreateInput("", 110, 10, 190, 30)
GUICtrlSetLimit($input1, 70)
GUICtrlCreateLabel("Пароль", 10, 50, 90, 30)
$input2 = GUICtrlCreateInput("", 110, 50, 190, 30, $ES_PASSWORD)
GUICtrlSetLimit($input2, 25)
GUICtrlCreateLabel("URL", 10, 160, 90, 30)
$input3 = GUICtrlCreateInput("", 110, 160, 190, 30)
$btn1 = GUICtrlCreateButton("Получить короткую ссылку", 50, 200, 170, 30)
GUICtrlSetState($btn1, $GUI_DEFBUTTON)
GUICtrlCreateLabel("Короткая ссылка", 10, 250, 140, 30)
$input4 = GUICtrlCreateInput("", 160, 250, 160, 30, $ES_READONLY)
GUISetState(@SW_SHOW, $gui)
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			ExitLoop
		Case $btn1
			If StringLen(GUICtrlRead($input1)) > 5 And StringLen(GUICtrlRead($input2)) > 5 And StringLen(GUICtrlRead($input3)) > 5 Then
				$url = _VKShortURL(GUICtrlRead($input1), GUICtrlRead($input2), GUICtrlRead($input3))
				If Not @error Then
					GUICtrlSetData($input4, $url)
					GUICtrlSetState($input4, $GUI_FOCUS)
				Else
					MsgBox(16, "error" & @error, "error code: " & @error, 10, $gui)
				EndIf
			Else
				MsgBox(16, "error", "error", 2, $gui)
			EndIf
	EndSwitch
WEnd
GUIDelete($gui)


Func _VKShortURL($sLogin, $sPassword, $sURL)
	Local $oReq, $sSendStr, $Cookie, $sAction, $sURLCC
	Local $sResponse, $aStringSplit, $sLink
	$sURLCC = "https://vk.com/cc"
	$sUserAgent = 'Mozilla/5.0 (Windows NT 6.1; rv:27.0) Gecko/20100101 Firefox/27.0'
	$oReq = ObjCreate('WinHttp.WinHttpRequest.5.1')
	If Not IsObj($oReq) Then Return SetError(1, 0, 0)
	$oReq.Open('GET', "http://m.vk.com/", False)
	$oReq.SetRequestHeader('User-Agent', $sUserAgent)
	$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
	If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
	$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
	$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
	$oReq.SetRequestHeader('Connection', 'keep-alive')
	$oReq.Send($sSendStr)
	$Cookie = __SetCookieParse($oReq.GetAllResponseHeaders())
	$sResponse = $oReq.responseText
	If StringInStr($sResponse, '://login.vk.com/?act=login') Then
		$sAction = StringRegExpReplace($sResponse, "(?si).*?\<form.*?action\=['""](.*?)['""].*?\>.*", "$1")
		$oReq.Open('POST', $sAction, False)
		$oReq.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded; charset=UTF-8')
		$oReq.SetRequestHeader('User-Agent', $sUserAgent)
		$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
		If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
		$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
		$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
		$oReq.SetRequestHeader('Connection', 'keep-alive')
		$oReq.SetRequestHeader('Referer', 'http://m.vk.com/')
		$sSendStr = 'email=' & __encodeURIComponent($sLogin) & '&pass=' & __encodeURIComponent($sPassword) & ''
		$oReq.Send($sSendStr)
	EndIf
	$oReq.Open('POST', $sURLCC, False)
	$oReq.SetRequestHeader('X-Requested-With', 'XMLHttpRequest')
	$oReq.SetRequestHeader('Content-Type', 'application/x-www-form-urlencoded; charset=UTF-8')
	$oReq.SetRequestHeader('User-Agent', $sUserAgent)
	$oReq.SetRequestHeader('Cache-Controle', 'no-cach')
	If $Cookie <> "" Then $oReq.SetRequestHeader('Cookie', $Cookie)
	$oReq.SetRequestHeader('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8')
	$oReq.SetRequestHeader('Accept-Language', 'ru-RU,ru;q=0.8,en-US;q=0.5,en;q=0.3')
	$oReq.SetRequestHeader('Connection', 'keep-alive')
	$oReq.SetRequestHeader('Referer', $sURLCC)
	$sSendStr = 'act=shorten&al=1&link=' & __encodeURIComponent($sURL)
	$oReq.Send($sSendStr)
	$sResponse = $oReq.responseText
	ConsoleWrite("POST_REQUEST: " & $sSendStr & @CRLF)
	ConsoleWrite("RESPONSE: " & $sResponse & @CRLF)
	$aStringSplit = StringSplit($sResponse, "<!>", 1)
	If @error Then Return SetError(@error, @extended, 0)
	$sLink = $aStringSplit[$aStringSplit[0]]
	Return $sLink
EndFunc   ;==>_VKShortURL

Func __SetCookieParse($AllResponseHeaders)
	$sCOOKIES = ""
	$aResponseHeaders = StringSplit($AllResponseHeaders, @CRLF)
	For $i = 1 To $aResponseHeaders[0]
		If StringLeft($aResponseHeaders[$i], 10) = 'Set-Cookie' Then
			$iPozSim = StringInStr($aResponseHeaders[$i], ';')
			$sCOOKIES &= StringMid($aResponseHeaders[$i], 13, $iPozSim - 13) & '; '
		EndIf
	Next
	$sCOOKIES = StringMid($sCOOKIES, 1, StringLen($sCOOKIES) - 2)
	Return $sCOOKIES
EndFunc   ;==>__SetCookieParse

Func __encodeURIComponent($sTxt)
	$sTxt = StringReplace($sTxt, @CRLF, '\r\n')
	$sTxt = StringReplace($sTxt, @CR, '\r')
	$sTxt = StringReplace($sTxt, @LF, '\n')
	$sTxt = StringReplace($sTxt, "'", "\'")
	$oSC = ObjCreate("ScriptControl")
	If Not IsObj($oSC) Then Return SetError(1)
	$oSC.Language = "JavaScript"
	Return $oSC.Eval('encodeURIComponent("' & $sTxt & '");')
EndFunc   ;==>__encodeURIComponent
Func __decodeURIComponent($sTxt)
	$sTxt = StringReplace($sTxt, @CRLF, '\r\n')
	$sTxt = StringReplace($sTxt, @CR, '\r')
	$sTxt = StringReplace($sTxt, @LF, '\n')
	$sTxt = StringReplace($sTxt, "'", "\'")
	$oSC = ObjCreate("ScriptControl")
	If Not IsObj($oSC) Then Return SetError(1)
	Return $oSC.Eval('decodeURIComponent("' & $sTxt & '");')
EndFunc   ;==>__decodeURIComponent


Добавлено:
Сообщение автоматически объединено:

Покажи, что пишется в консоль после сокращения, если не заработает.



Добавлено:
Сообщение автоматически объединено:

Я понял. Только щас сделал ещё одну страничку, без привязки к почте и телефону. Т.е. аккаунт вообще без всяких превязок.
При сокращении ссылки (вообще при любом действии: лайк, сообщение, комментарий и т.д) он просит ввести и подтвердить номер телефона, иначе пропустить и ввести код с картинки.


Добавлено:
Сообщение автоматически объединено:

А скрипт тем временем ошибку выдаёт.
 
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
alex33 сказал(а):
А скрипт тем временем ошибку выдаёт.

Странно, у меня ошибку не выдает, но получаю вот такой результат: http://clip2net.com/clip/m47828/63681-clip-19kb.png?nocache=1

Использую нормальную страницу, без двойной аутентификации, привязанной к телефону и имейлу.
 

alex33

Скриптер
Сообщения
1,457
Репутация
184
Duff1993 [?]
Странно, у меня ошибку не выдает
Да, извиняюсь, у меня тоже ошибки нет,
а под ошибкой на самом деле я это и имел ввиду.
Это возвращается хеш, который нужно передать вторым запросом, вместе с кодом капчи. Вот как выглядит это всё:
Запрос:
Код:
POST http://vk.com/cc HTTP/1.1
Host: vk.com
User-Agent: Mozilla...
Content-Type: application/x-www-form-urlencoded; charset=UTF-8
X-Requested-With: XMLHttpRequest
Referer: http://vk.com/cc
Content-Length: 47
Cookie: r...
Connection: keep-alive
Pragma: no-cache
Cache-Control: no-cache

act=shorten&al=1&link=http%3A%2F%2Fyandex.ru%2F
Ответ:
Код:
HTTP/1.1 200 OK
Server: Apache
Date: Wed, 29 Jul 2015 12:33:04 GMT
Content-Type: text/plain; charset=windows-1251
Content-Length: 84
Connection: keep-alive
X-Powered-By: PHP/3.16140
Pragma: no-cache
Cache-control: no-store

18042<!>profile.css,page.css,profile.js,page.js<!>0<!>6661<!>11<!>27b7882d9f11d96071

Далее появляется форма (запрос ниже), в ней предлагается ввести номер телефона и код из СМС,
либо пропустить ввод номера и ввести код с картинки, что я и сделал.
И так, запрос:
Код:
POST http://vk.com/activation.php HTTP/1.1
Host: vk.com
User-Agent: Mozilla...
Content-Type: application/x-www-form-urlencoded; charset=UTF-8
X-Requested-With: XMLHttpRequest
Referer: http://vk.com/cc
Content-Length: 66
Cookie: remix...
Connection: keep-alive
Pragma: no-cache
Cache-Control: no-cache

act=validate_box&al=1&captcha=1&hash=27b7882d9f11d96071&skip_push=
Ну и ответ:
Код:
HTTP/1.1 200 OK
Server: Apache
Date: Wed, 29 Jul 2015 12:33:04 GMT
Content-Type: text/plain; charset=windows-1251
Content-Length: 11727
Connection: keep-alive
X-Powered-By: PHP/3.16140
Pragma: no-cache
Cache-control: no-store

18042<!>uncommon.css<!>0<!>6661<!>0<!><!bool><!><div id="validation_box" class="">
Там идёт очень много CSS + HTML + Javascript кода, который я небуду вставлять в это сообщение, т.к. код очень большой...

И вот. После ввода капчи, нажимаем "Отправить", и происходит последний запрос.
Код:
POST http://vk.com/cc HTTP/1.1
Host: vk.com
User-Agent: Mozilla...
Content-Type: application/x-www-form-urlencoded; charset=UTF-8
X-Requested-With: XMLHttpRequest
Referer: http://vk.com/cc
Content-Length: 90
Cookie: remix...
Connection: keep-alive
Pragma: no-cache
Cache-Control: no-cache

act=shorten&al=1&captcha_key=z8q7s&captcha_sid=508998318351&link=http%3A%2F%2Fyandex.ru%2F
И конечно же ответ (который включает в себя нашу сокращённую ссылку):
Код:
HTTP/1.1 200 OK
Server: Apache
Date: Wed, 29 Jul 2015 12:36:36 GMT
Content-Type: text/plain; charset=windows-1251
Content-Length: 83
Connection: keep-alive
X-Powered-By: PHP/3.16140
Pragma: no-cache
Cache-control: no-store

18042<!>profile.css,page.css,profile.js,page.js<!>0<!>6661<!>0<!>http://vk.cc/hfOwt
Вот кажется и всё.


Добавлено:
Сообщение автоматически объединено:

Но повторяю, у меня на трёх страницах с привязкой всё работает как надо, а именно так, как я показал в посте#3,
URL возвращается как обычно, ввиде: http://vk.cc/411GNd
Код:
$link = "http://vk.cc/411GNd"



Добавлено:
Сообщение автоматически объединено:

Duff1993
А вы когда через браузер сокращаете, у вас капча или что-нибудь такое выскакивает? Или сразу сокращает после нажатия "Получить короткий вариант ссылки"?
 
Автор
D

Duff1993

Новичок
Сообщения
29
Репутация
0
alex33 сказал(а):
А вы когда через браузер сокращаете, у вас капча или что-нибудь такое выскакивает? Или сразу сокращает после нажатия "Получить короткий вариант ссылки"?

Когда через браузер - капч, или других окон не выскакивает.
 
Верх