Привязка к железу через DriveGetSerial, легко обойти! Есть ли аналоги?

Centurion · 26 Июн 2011

Привязал программу к железу по SN через DriveGetSerial. Но это все легко обходиться через создание и копирование образа.. Есть ли какие нибудь альтернативные способы привязки?
Добавлено:
Сообщение автоматически объединено: 26 Июн 2011

Привязка происходит к съемным флешь накопителям

edward_freedom · 26 Июн 2011

OffTopic:
Любую защиту можно убрать с помощью декомплиятора, который свободно лежит в интернете

Centurion · 26 Июн 2011

Это понятно, но меня интересует именно привязка к железу.

edward_freedom · 26 Июн 2011

http://autoit-script.ru/index.php?topic=2474.0

VladUs · 26 Июн 2011

http://autoit-script.ru/index.php?topic=1919.0

Centurion · 26 Июн 2011

Эти темы я видел, там рассматривается когда программа привязывается к конкретному ПК, а мне надо именно к съемному накопителю, что бы она запускалась только с него.

CreatoR · 26 Июн 2011

VladUs
Зачем повторять тему которую уже запостил edward_freedom? :smile:

VladUs · 26 Июн 2011

CreatoR [?]

Зачем повторять тему которую уже запостил edward_freedom?

Исправил

Centurion · 26 Июн 2011

Видимо мне нужно получить SN самого устройства а не тома т.к. SN устройства не копируется через образ (насколько я понял). А как узнать этот SN

Yashied · 26 Июн 2011

Попробуйте поиграться с этим:

Код:

$oService = ObjGet('winmgmts:\\.\root\cimv2')
$oItem = $oService.ExecQuery('SELECT InterfaceType,PnPDeviceID FROM Win32_DiskDrive')
For $Property In $oItem
	If $Property.InterfaceType = 'USB' Then
		ConsoleWrite($Property.PnPDeviceID & @CR)
	EndIf
Next

После выполнения этого кода вы получите примерно следующую строку:

USBSTOR\DISK&VEN_JETFLASH&PROD_TS4GJFV30&REV_8.07\7QAIJQ2O&0

То, что выделено красным, не должно меняться от порта к порту и одинаково для флешек одной модели. Серийного номера, как такового, обычные фешки не имеют (?), только жесткие диски.

Если помножить эту информацию на серийный номер тома и взять не очень популярную флешку, то вы получите достаточно уникальный ID для привязки программы к флешке.

Garrett · 26 Июн 2011

Yashied, а сигнатура не подойдёт в качестве уникального номера?
После форматирования сигнатура остаётся неизменной.

Код:

;...
ConsoleWrite($Property.Signature & @CR)
;...

Centurion · 26 Июн 2011

Garrett - а при копировании через образ?

Yashied - Если помножить эту информацию на серийный номер тома - можно пример если не затруднит

Yashied · 26 Июн 2011

Garrett

Сигнатуру генерирует Windows при первом подключении...

Centurion

Код:

#Include  <Crypt.au3>

ConsoleWrite(_UniqueUSBFlashID('E:') & @CR)

Func _UniqueUSBFlashID($sDrive)

	Local $oService, $oItems, $Hash, $Text = ''

	$oService = ObjGet('winmgmts:\\.\root\cimv2')
	If Not IsObj($oService) Then
		Return SetError(1, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_LogicalDiskToPartition')
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If StringInStr($Property.Dependent, '"' & $sDrive & '"') Then
			$Text = StringTrimLeft($Property.Antecedent, StringInStr($Property.Antecedent, '='))
			ExitLoop
		EndIf
	Next
	If Not $Text Then
		Return SetError(3, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_DiskDriveToDiskPartition')
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If StringInStr($Property.Dependent, $Text) Then
			$Text = StringTrimLeft($Property.Antecedent, StringInStr($Property.Antecedent, '='))
			ExitLoop
		EndIf
	Next
	If Not $Text Then
		Return SetError(3, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_DiskDrive WHERE DeviceID = ' & $Text)
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If $Property.InterfaceType = 'USB' Then
			$Text = StringTrimLeft($Property.PnPDeviceID, StringInStr($Property.PnPDeviceID, '&VEN_'))
			$Text = StringStripWS(StringLeft($Text, StringInStr($Text, '\', 0, -1) - 1), 8)
			$Text &= DriveGetFileSystem($sDrive) & DriveGetSerial($sDrive)
			$Text &= $Property.TotalCylinders
			$Text &= $Property.TotalHeads
			$Text &= $Property.TotalSectors
			$Text &= $Property.TotalTracks
			ExitLoop
		EndIf
	Next
	If Not $Text Then
		Return SetError(3, 0, '')
	EndIf
	$Hash = StringTrimLeft(_Crypt_HashData($Text, $CALG_MD5), 2)
	If Not $Hash Then
		Return SetError(4, 0, '')
	EndIf
	Return '{' & StringMid($Hash, 1, 8) & '-' & StringMid($Hash, 9, 4) & '-' & StringMid($Hash, 13, 4) & '-' & StringMid($Hash, 17, 4) & '-' & StringMid($Hash, 21, 12) & '}'
EndFunc   ;==>_UniqueUSBFlashID

Garrett · 26 Июн 2011

Yashied [?]

Сигнатуру генерирует Windows при первом подключении...

То есть в момент самого первого подключения? Я правильно понял?
Потому как я неоднократно менял флешки пока экспериментировал, и сигнатуры у них оставались неизменными. :scratch:

Centurion · 27 Июн 2011

Yashiled
Я написал так _UniqueUSBFlashID(StringLeft(@ScriptDir, 2))) и он работает и на обычном HDD

Yashied · 27 Июн 2011

Centurion сказал(а):
Я написал так _UniqueUSBFlashID(StringLeft(@ScriptDir, 2))) и он работает и на обычном HDD

Я там немного ошибся...

Код:

#Include  <Crypt.au3>

ConsoleWrite(_UniqueUSBFlashID('E:') & @CR)

Func _UniqueUSBFlashID($sDrive)

	Local $oService, $oItems, $Hash, $Disk = '', $Part = '', $Text = ''

	$oService = ObjGet('winmgmts:\\.\root\cimv2')
	If Not IsObj($oService) Then
		Return SetError(1, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_LogicalDiskToPartition')
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If StringInStr($Property.Dependent, '"' & $sDrive & '"') Then
			$Part = StringTrimLeft($Property.Antecedent, StringInStr($Property.Antecedent, '='))
			ExitLoop
		EndIf
	Next
	If Not $Part Then
		Return SetError(3, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_DiskDriveToDiskPartition')
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If StringInStr($Property.Dependent, $Part) Then
			$Disk = StringTrimLeft($Property.Antecedent, StringInStr($Property.Antecedent, '='))
			ExitLoop
		EndIf
	Next
	If Not $Disk Then
		Return SetError(3, 0, '')
	EndIf
	$oItems = $oService.ExecQuery('SELECT * FROM Win32_DiskDrive WHERE DeviceID = ' & $Disk)
	If Not IsObj($oItems) Then
		Return SetError(2, 0, '')
	EndIf
	For $Property In $oItems
		If $Property.InterfaceType = 'USB' Then
			$Text = StringTrimLeft($Property.PnPDeviceID, StringInStr($Property.PnPDeviceID, '&VEN_'))
			$Text = StringStripWS(StringLeft($Text, StringInStr($Text, '\', 0, -1) - 1), 8)
			$Text &= DriveGetFileSystem($sDrive) & DriveGetSerial($sDrive)
			$Text &= $Property.TotalCylinders
			$Text &= $Property.TotalHeads
			$Text &= $Property.TotalSectors
			$Text &= $Property.TotalTracks
			ExitLoop
		EndIf
	Next
	If Not $Text Then
		Return SetError(3, 0, '')
	EndIf
	$Hash = StringTrimLeft(_Crypt_HashData($Text, $CALG_MD5), 2)
	If Not $Hash Then
		Return SetError(4, 0, '')
	EndIf
	Return '{' & StringMid($Hash, 1, 8) & '-' & StringMid($Hash, 9, 4) & '-' & StringMid($Hash, 13, 4) & '-' & StringMid($Hash, 17, 4) & '-' & StringMid($Hash, 21, 12) & '}'
EndFunc   ;==>_UniqueUSBFlashID

Centurion · 27 Июн 2011

Он работает с обычными HDD?
Добавлено:
Сообщение автоматически объединено: 27 Июн 2011

Все, понял. первый вариант для HDD и Flash второй только для Flash

Yashied · 27 Июн 2011

Первый вариант неправильный! Не используй его!

Centurion · 27 Июн 2011

Но второй не работает на обычных HDD

Yashied · 27 Июн 2011

Centurion сказал(а):
Привязка происходит к съемным флешь накопителям

Автор темы	Похожие темы	Форум	Ответы	Дата
T	Привязка к Железу	Общие вопросы по AutoIt	4	5 Мар 2023
T	Привязка программы к железу	Общие вопросы по AutoIt	8	5 Мар 2023
	Privat (Привязка по железу)	Общие вопросы по AutoIt	5	17 Июл 2015
N	Система защиты и привязка к железу	Общие вопросы по AutoIt	12	10 Май 2013
S	(Привязка скрипта к одному компьютеру (железу)) помогите в переделке скрипта.	Общие вопросы по AutoIt	7	14 Окт 2012

Привязка к железу через DriveGetSerial, легко обойти! Есть ли аналоги?

Новичок

Осваивающий

Новичок

Осваивающий

Скриптер

Новичок

Must AutoIt!

Скриптер

Новичок

Модератор

Модератор

Новичок

Модератор

Модератор

Новичок

Модератор

Новичок

Модератор

Новичок

Модератор