Повтор функций с интервалом

[Yoshiyuki]

Доброго времени суток, сделал вывод даного из веб страницы в гуй, но теперь появилась такая проблема, как сделать что бы каждый 2 минуты даные обновлялись?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <INet.au3>

$file = _INetGetSource('http://animeq.ru/')
$str=StringRegExp($file,'(?si)p style="color:#FFFFFF;margin: 0 0 10px;"><b>Слушатели: </b>(.*?)</p>',3)
$res=''
For $i=0 To UBound($str)-1
    $res&=$str[$i]&@CRLF
Next



#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 100, 100, 192, 124)
$Test = GuiCtrlCreateLabel("Слушателей: " & $res, 10, 10)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd

 

[CreatoR]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 100, 100)
$iLabel = GUICtrlCreateLabel("Слушателей: ", 10, 10, 90, 15)

GUISetState(@SW_SHOW)

_Update_Proc()
AdlibRegister('_Update_Proc', (1000 * 60) * 2)

While 1
    $nMsg = GUIGetMsg()
	
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _Update_Proc()
	$sRead = BinaryToString(InetRead('http://animeq.ru/'))
	$sStr = StringRegExpReplace($sRead, '(?si).*p style="color:#FFFFFF;margin: 0 0 10px;"><b>Слушатели: </b>(.*?)</p>.*', '\1')
	
	GUICtrlSetData($iLabel, "Слушателей: " & $sStr)
EndFunc

 

[Yoshiyuki]

Спасибо, пытался сделать также, но немного не так делал))