Получить путь активного окна проводника

[antidog]

Например- открыта папка в проводнике, нужно получить её полный путь. Возможно такое?

 

[AlexTurist]

А как скрипт должен понимать о какой папке идет речь? Скажем открыто 2 папки.

 

[All2khoff]

в windows 10 такой вот костыль сработал.
запускать на ё, только при активном окне проводника.

#include <Array.au3>
HotKeySet ("`", "check")
HotKeySet ("ё", "check")

Func check()
   $title = WinGetTitle("[ACTIVE]")
   $text = WinGetText ($title)
   $lines = StringSplit($text, @LF, 1)
   if IsArray($lines) Then
;~       ConsoleWrite($lines[15])
       $adres = StringRegExpReplace($lines[15],"Адрес: ","")
      ConsoleWrite($adres&@CRLF)
   Else
   EndIf
EndFunc

While 1
    Sleep(100)
WEnd

 

[antidog]

А как скрипт должен понимать о какой папке идет речь? Скажем открыто 2 папки.

Та, что является активным окном в данный момент. Но, не принципиально, так как планирую работать с одной папкой в единицу времени.

Сообщение автоматически объединено: 4 Окт 2021

Сообщение автоматически объединено: 4 Окт 2021

в windows 10 такой вот костыль сработал.
запускать на ё, только при активном окне проводника.

На win7 ничего не выводит в консоль =(

 

[InnI]

Func check()
  $adres = StringRegExp(WinGetText("[ACTIVE]"), "Адрес: (.*)", 3)
  If IsArray($adres) Then ConsoleWrite($adres[0] & @CRLF)
EndFunc

 

[AlexTurist]

У меня на Windows 7 сработало так

Спойлер: Код

HotKeySet ("1", "check")

Func check()
   $title = WinGetTitle("[ACTIVE]")
   $text = WinGetText ($title)
   MsgBox (0,"",$text)
EndFunc

While 1
    Sleep(100)
WEnd

Это я так криво переделал код Glass4217))))

 

[joiner]

Делал так

[Файловая система] Создание папки в активной директории

AutoIt: 3.3.8.1 Категория: Автоматизация Описание: Программа создает папку в активном окне при нажатии горячих клавиш. Функция определения пути к открытой папке взята из сообщения http://autoit-script.ru/index.php/topic,5789.msg42085.html#msg42085 Код/Пример: Источник: autoit-script.ru...

autoit-script.ru

До сих пор пользуюсь. Система win 10 x64

 

[AZJIO]

Из моей программы SaveFolders.

$Tr7 = 0
$obj = "[CLASS:Edit; INSTANCE:1]"

Switch @OSVersion
    Case 'WIN_8',  'WIN_10'
        $obj = "[CLASS:ToolbarWindow32; INSTANCE:3]"
        $Tr7 = 1
    Case 'WIN_VISTA', 'WIN_7'
        $obj = "[CLASS:ToolbarWindow32; INSTANCE:2]"
        $Tr7 = 1
    Case Else
EndSwitch

$AllWindows = WinList()
For $i = 1 To $AllWindows[0][0]
    If _IsVisible($AllWindows[$i][1]) And $AllWindows[$i][0] <> "" And $AllWindows[$i][0] <> "Program Manager" And StringRight(_ProcessGetPath(WinGetProcess($AllWindows[$i][0])), 13) = '\explorer.exe' Then
        $tmp = ControlGetText($AllWindows[$i][0], '', $obj)
        If $Tr7 = 1 Then
            If $tmp = '' Then $tmp = $AllWindows[$i][0]
            $tmp = StringRegExpReplace($tmp, '(.*)(.:\\.*)', '\2')
            ; $tmp = StringRegExpReplace($tmp, '(?s)\A(?:.+?: )(.:\\.+?)\z', '\1')
            If Not FileExists($tmp) Then ContinueLoop
        EndIf
        MsgBox(0, 'Сообщение', $tmp)
    EndIf
Next

; Возвращает путь к EXE-файлу запущенного процесса зная его PID
Func _ProcessGetPath($PID)
    Local $hKernel32_dll, $hProcess, $Path, $ret
    If IsString($PID) Then $PID = ProcessExists($PID)
    $Path = DllStructCreate('char[1000]')
    $hKernel32_dll = DllOpen('Kernel32.dll')
    ; $PROCESS_QUERY_INFORMATION + $PROCESS_VM_READ
    $hProcess = DllCall($hKernel32_dll, 'int', 'OpenProcess', 'dword', 0x400 + 0x10, 'int', 0, 'dword', $PID)
    $ret = DllCall('Psapi.dll', 'long', 'GetModuleFileNameEx', 'long', $hProcess[0], 'int', 0, 'ptr', DllStructGetPtr($Path), 'long', DllStructGetSize($Path))
    $ret = DllCall($hKernel32_dll, 'int', 'CloseHandle', 'hwnd', $hProcess[0])
    DllClose($hKernel32_dll)
    Return DllStructGetData($Path, 1)
EndFunc   ;==>_ProcessGetPath

; Проверка, что окно является видимым. Возвращает True или False
Func _IsVisible($handle)
    Return BitAND(WinGetState($handle), 4) And BitAND(WinGetState($handle), 2)
EndFunc   ;==>_IsVisible