Обновление значения только в первой вкладе из трёх

[Scampy]

Доброго времени суток!
Есть код:

#include <GUIConstantsEx.au3>

$GUI = GUICreate('Тест', 535, 390)
GUICtrlCreateTab(5, 5, 525, 355)
GUICtrlCreateTabItem("Tab 1")
$Label = GUICtrlCreateLabel("", 310, 50, 80, 17)
$Button1 = GUICtrlCreateButton("Обновить", 20, 50, 100)

DateRefresh()
Func DateRefresh()
   $Size1 = Round(DirGetSize(@TempDir) / 1048576, 2)
   $Label1 = GUICtrlCreateLabel("" & $Size1 & " Мб", 150, 50, 70, 12)
EndFunc

GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("Tab 3")

GUICtrlSetState(0, $GUI_SHOW)
GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW)

While 1
$msg = GUIGetMsg()
   Select
	  Case $msg = $GUI_EVENT_CLOSE
		 ExitLoop
	  Case $msg = $Button1
	  DateRefresh()
	  GUISetState(@SW_SHOW)
	EndSelect
 WEnd

Как сделать чтобы при нажатии кнопки "Обновить" нужное значение отображалось только в первой вкладке, а не во всех трёх?
Спасибо

 

[Yashied]

#include <GUIConstantsEx.au3>

$GUI = GUICreate('Тест', 535, 390)
GUICtrlCreateTab(5, 5, 525, 355)
GUICtrlCreateTabItem("Tab 1")
$Label = GUICtrlCreateLabel("", 310, 50, 80, 17)
$Button1 = GUICtrlCreateButton("Обновить", 20, 50, 100)
$Label1 = GUICtrlCreateLabel("", 150, 50, 70, 12)
GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("Tab 3")
GUICtrlCreateTabItem("")
DateRefresh()
GUISetState(@SW_SHOW)

While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			DateRefresh()
	EndSwitch
WEnd

Func DateRefresh()
	GUICtrlSetData($Label1, Round(DirGetSize(@TempDir) / 1048576, 2) & " МБ")
EndFunc   ;==>DateRefresh