Картинка на форме, после события

[k790]

Здравствуйте.
Можно но ли, командой

$Pic1 = GUICtrlCreatePic("путь до картинки", 16, 70, 22, 22)

, сделать, чтобы после определённой части кода выскакивала эта картинка?
Я попытался сделать, но у меня не получилось. Вообще надо после УСПЕШНОГО копирования показать одну картинку, а в противном случаю другую. Я в справке нашёл, что 1-выполнено, а 0-не выполнено, но у меня почему-то при успешном копировании 0.
Это надо впихнуть в часть кода

If GUICtrlRead($Checkbox7) = $GUI_CHECKED Then
                GUICtrlSetData($Progress1, $iProgress)
                $iProgress += $iPrgrs_Step
                Sleep(3000)
                FileCopy($Opera_Dir & "\profile\typed_history.xml", $Backup_Dir & "\profile\")
            EndIf

 

[`p r o x y]

Re: Ксртинка на форме, после события

Пример 1

#include <GUIConstantsEx.au3>

Opt('GUIOnEventMode', 		1)
Opt('MustDeclareVars', 		1)

Global	$hMainWin, $hPic1, $hPic2

$hMainWin = GUICreate('Пример смены изображения')
	GUISetOnEvent($GUI_EVENT_CLOSE, '_ProExit')


$hPic1 = GUICtrlCreatePic(StringRegExpReplace(@AutoItExe, '(.+)\\.+', '\1') & '\Examples\GUI\logo4.gif',  10, 10, 169, 68)
	GUICtrlSetState(-1, $GUI_HIDE)

$hPic2 = GUICtrlCreatePic(StringRegExpReplace(@AutoItExe, '(.+)\\.+', '\1') & '\Examples\GUI\mslogo.jpg', 10, 10, 255, 40)
	GUICtrlSetState(-1, $GUI_HIDE)

GUICtrlCreateButton('Изменить изображение', 10, 80)
	GUICtrlSetOnEvent(-1, '_SwitchPic')

GUISetState()

While 1
	Sleep(10)
WEnd

Func _ProExit()
	Exit
EndFunc

Func _SwitchPic()
	Local $iStatePic1, $iStatePic2

	$iStatePic1 = GUICtrlGetState($hPic1)
	$iStatePic2 = GUICtrlGetState($hPic2)
	
	If (BitAnd($iStatePic1, 32) AND BitAnd($iStatePic2, 32)) OR BitAnd($iStatePic1, 32) Then
		GUICtrlSetState($hPic1, $GUI_SHOW)
		GUICtrlSetState($hPic2, $GUI_HIDE)
	Else
		GUICtrlSetState($hPic2, $GUI_SHOW)
		GUICtrlSetState($hPic1, $GUI_HIDE)
	EndIf
EndFunc

Пример 2

#include <GUIConstantsEx.au3>

Opt('GUIOnEventMode', 		1)
Opt('MustDeclareVars', 		1)

Global	$hMainWin, $hPic, $fPicSwitch

$hMainWin = GUICreate('Пример смены изображения')
	GUISetOnEvent($GUI_EVENT_CLOSE, '_ProExit')


$hPic = GUICtrlCreatePic('', 10, 10, 1, 1)

GUICtrlCreateButton('Изменить изображение', 10, 80)
	GUICtrlSetOnEvent(-1, '_SwitchPic')

GUISetState()

While 1
	Sleep(10)
WEnd

Func _ProExit()
	Exit
EndFunc

Func _SwitchPic()
	If $fPicSwitch == '' Or Not $fPicSwitch Then
		GUICtrlSetPos($hPic, 10, 10, 169, 68)
		GUICtrlSetImage($hPic, StringRegExpReplace(@AutoItExe, '(.+)\\.+', '\1') & '\Examples\GUI\logo4.gif')
		$fPicSwitch = 1
	Else
		GUICtrlSetPos($hPic, 10, 10, 255, 40)
		GUICtrlSetImage($hPic, StringRegExpReplace(@AutoItExe, '(.+)\\.+', '\1') & '\Examples\GUI\mslogo.jpg')
		$fPicSwitch = 0
	EndIf
EndFunc

 

[k790]

А мне это точно подходит?
У меня картинки зависят от скопированного(папки, файлы), то есть если скопировалось, то одна картинка, а если нет, то другая.
По описанию, если скопировалось, то это равно 1, а если нет, 0.
Но у меня во всех случаях равно 0.
А картинка напрямую зависит от копирования