Как зациклить чтение строк из файла?

[plazma50]

Всем привет!
Как зациклить чтение строк из файла функции FileReadLine?
Везде примеры

If @error = -1 Then ExitLoop

т.е. дочитал до конца и все....
Мне нужно считывать адреса сайтов из текстового файла и поочередно их открывать, а когда список закончится то опять считывать начиная с первой строки и так бесконечно.
Если убираю выше означенную строку из кода, то по окончании списка браузер пытается открыть url http:///
Пока решил банальным закрытием файла после чтения последней строки, а потом через Do/Until опять открытием... но как мне кажется это не красиво...
Спасибо за любую подсказку!

 

[InnI]

Читайте сразу весь файл в массив и работайте с полученным массивом. Так проще.

FileReadToArray() ; в онлайн справке этой функции нет - см. справку AutoIt
; или
_FileReadToArray() ; в онлайн справке устаревшее описание - см. справку AutoIt

 

[joiner]

$fo = FileOpen('1.txt')
$line = 1
While 1
	$frl = FileReadLine($fo, $line)
	If @error = -1 Then
		$line = 1
		ContinueLoop
	Else
		$line += 1
	EndIf
	ConsoleWrite($frl & @LF)
WEnd

 

[madmasles]

Мой вариант.

Local $sFile = @ScriptDir & '\test.txt', $hFile, $sLine, $fExit

HotKeySet('{Esc}', '_Exit')
$hFile = FileOpen($sFile)
If $hFile = -1 Then Exit 1
Do
	$sLine = FileReadLine($hFile)
	If @error Then
		FileSetPos($hFile, 0, 0)
		ContinueLoop
	EndIf
	ConsoleWrite($sLine & @LF)
Until $fExit
FileClose($hFile)

Func _Exit()
	$fExit = True
EndFunc   ;==>_Exit

 

[plazma50]

Всем спасибо! Все варианты рабочие, но остановился на варианте от joiner как содержащем наименьшее количество If и Do, однако свой скрипт дополнил частью

HotKeySet('{Esc}', '_Exit')

от madmasles чтобы можно было скрипт прервать. От массива InnI отказался т.к. строк в текстовом файле всего-то 20 штук...

 

[plazma50]

решил не создавать новой темы, но задачу усложнить.

Возможно-ли чтение строк с разными промежутками времени, например после чтения первой строки подождать 1 мин, а после чтения 2 строки - 3 мин, а после 3 строки - 6 минут и т.д. в разнобой?

Пока сделал так (часть кода)

......
$frl = FileReadLine($fo, $line)
    If @error = -1 Then
        $line = 1
        ContinueLoop
    Else
        $line += 1
    EndIf
    _FFOpenURL($frl)
		_FFLoadWait()
	Sleep(2000)
.......

но это вариант с одинаковой задеркой в 2 сек, после загрузки строки с url сайта из файла
Спасибо!

 

[CrazyDoc]

но это вариант с одинаковой задеркой в 2 сек, после загрузки строки с url сайта из файла
Спасибо!

возможно

Sleep(Random ( [ Min = 0 [, Max = 1 [, Flag = 0 ]]] ))

?

 

[plazma50]

Спасибо CrazyDoc , но я наверно ввел вас в заблуждение. Мне нужно не случайное время ожидания между чтением строк, а строго определенное и величину этих таймаутов я должен иметь возможность задавать сам.

 

[edyapd]

Создайте массив задержек

$aline[0] = 2000
$aline[1] = 4000
$aline[2] = 6000
; И подставляйте вместо Sleep(2000)
Sleep($aline[$line-1])

Главное чтобы строк в массиве было столько же сколько и в файле. Либо проверки какие-то надо делать, скажем если число $line привысило Ubound($aline), то задержка такая-то.

 

[plazma50]

Спрасибо edyapd! Все вроде логично, но вставил в простой код

#Include <FF.au3>
#include <Array.au3>
_FFStart()
$fo = FileOpen('spisok.txt')
$line = 1

$aline[0] = 2000
$aline[1] = 4000
$aline[2] = 6000

While 1
    $frl = FileReadLine($fo, $line)
    If @error = -1 Then
        $line = 1
        ContinueLoop
    Else
        $line += 1
    EndIf
    _FFOpenURL($frl)
		_FFLoadWait()
		
Sleep($aline[$line-1])

WEnd

и выкидывает ошибку :( наверно руки кривые, Expected a "=" operator in assignment statement жалуется на $aline[0]

 

[InnI]

plazma50

жалуется на

А потому, что массив сперва нужно объявить

Global $aline[100]
$aline[0] = 2000
...

От массива InnI отказался

Очень даже зря. Смотрите, как упрощается код

#Include <FF.au3>

Global $aTime[] = [2000, 4000, 6000]

_FFStart()
While 1
  $aLines = FileReadToArray('spisok.txt')
  For $i = 0 To UBound($aLines) - 1
    _FFOpenURL($aLines[$i])
    _FFLoadWait()
    If $i < UBound($aTime) Then Sleep($aTime[$i])
  Next
WEnd

 

[plazma50]

:-[ Вынужден признать InnI что ваш вариант работает идеально. Да простит меня joiner, но ваш ответ в свете вновь открывшихся обстоятельств - лучший. Спасибо за помощь!

 

[madmasles]

InnI,
А зачем постоянно перечитывать файл в массив?

 

[InnI]

madmasles

зачем постоянно перечитывать

Если файл не меняется, тогда, в принципе, и не нужно.

 

[edyapd]

Я бы ещё добавил

else Sleep(2000)  ; Тут задержка по умолчанию, если не прописана в массиве