Как взять ссылки из определенного <table></table> ?

[RavdonikaS]

В частности вот тут ==> http://otvet.mail.ru/open/
Интересуют ссылки как _IELinkGetCollection но только из центрального табла (<table class="Questions">) там где вопросы пользователей
Как получить список список этих ссылок?

 

[madmasles]

Re: [Автоматизация] Как взять ссылки из определенного <table></table> ?

RavdonikaS,
Попробуйте примерно так.

#include <IE.au3>
#include <Array.au3>

_IEErrorHandlerRegister()

Global $sUrl = 'http://otvet.mail.ru/open/', $aLink[1][2]

$oIE = _IECreate($sUrl)
$oTables = _IETagNameGetCollection($oIE, 'table')
For $oTable In $oTables
	If $oTable.classname == 'Questions' Then
		$oLinks = _IETagNameGetCollection($oTable, 'a')
		ReDim $aLink[@extended + 1][2]
		For $oLink In $oLinks
			If StringInStr($oLink.href, 'question') Then
				ConsoleWrite($oLink.href & @TAB & $oLink.innertext & @LF)
				$aLink[0][0] += 1
				$aLink[$aLink[0][0]][0] = $oLink.href
				$aLink[$aLink[0][0]][1] = $oLink.innertext
			EndIf
		Next
		ExitLoop
	EndIf
Next
;_IEQuit($oIE)
If $aLink[0][0] Then
	ReDim $aLink[$aLink[0][0] + 1][2]
	_ArrayDisplay($aLink)
Else
	MsgBox(16, 'Error', 'No')
EndIf