Что нового

Как вернуть номер столбца ListView ??

uBaH

Новичок
Сообщения
19
Репутация
0
Подскажите пожалуйста как можно вернуть номер столбца в ListView при щелчке левой кнопкой мыши по ,например, второй строчке.
 

Yashied

Модератор
Команда форума
Глобальный модератор
Сообщения
5,379
Репутация
2,716
Код:
#Include <GUIConstantsEx.au3>
#Include <GUIListView.au3>
#Include <WindowsConstants.au3>

$hForm = GUICreate('MyGUI', 332, 400)
$LV = GUICtrlCreateListView('Column 1|Column 2|Column 3|Column 4', 10, 10, 312, 380)
For $i = 1 To 9
    GUICtrlCreateListViewItem('Item ' & $i & '|' & 'Sub ' & $i & '|' & 'Sub ' & $i & '|' & 'Sub ' & $i, $LV)
Next
GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
GUISetState()

Do
Until GUIGetMsg() = $GuI_EVENT_CLOSE

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	Switch $hWnd
		Case $hForm

			Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
			Local $CtrlID = DllStructGetData($tNMHDR, 'IDFrom')
			Local $Code = DllStructGetData($tNMHDR, 'Code')

			Switch $CtrlID
				Case $LV
					Switch $Code
						Case $NM_CLICK

							Local $tNMLISTVIEW = DllStructCreate('hwnd hWndFrom;uint_ptr IDFrom;uint_ptr Code;int Item;int SubItem;uint NewState;uint OldState;uint Changed;int X;int Y;lparam Param', $lParam)

							ConsoleWrite('Item: ' & DllStructGetData($tNMLISTVIEW, 'Item') & '   SubItem: ' & DllStructGetData($tNMLISTVIEW, 'SubItem') & @CR)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 
Верх