Что нового

Как создать меню выбора шрифта?

agikon

Знающий
Сообщения
789
Репутация
16
подскажите пожалуйста.
искал и нигде не нахожу.
 
Автор
A

agikon

Знающий
Сообщения
789
Репутация
16
а нету хоть какогото примера? а то по всему форуиу на ChooseFont только моя тема выскакивает.
 

Zaramot

I ♥ AutoIt
Сообщения
1,160
Репутация
660
а нету хоть какогото примера
Код:
#include <Misc.au3>

GUICreate("Test", 306, 135)
$Label1 = GUICtrlCreateLabel("Hello world !!!", 32, 24, 259, 42)
$Button1 = GUICtrlCreateButton("Шрифт", 112, 88, 75, 25)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $Button1
            $Font = _ChooseFont()
			If @error Then ContinueLoop
            GUICtrlSetFont($Label1, $Font[3], $Font[4], $Font[1], $Font[2])
			GUICtrlSetColor($Label1, $Font[7])
    EndSwitch
WEnd
 
Автор
A

agikon

Знающий
Сообщения
789
Репутация
16
та ненашел я там по шрифты воообще ничего.

Zaramot
спасибо то что надо.
 

kaster

Мой Аватар, он лучший самый
Команда форума
Глобальный модератор
Сообщения
4,020
Репутация
622
agikon [?]
та ненашел я там по шрифты воообще ничего.
ты или тролль, или я даже боюсь озвучивать... уже в который раз жалуешь что не можешь найти какие-то элементарные вещи в справке, когда тебе указывают явное название. на крайний случай, если ты все еще этого не понял, то каждая задекларированная функция из стандартной поставки AutoIt на форуме имеет ссылку. поэтому смело кликай, если видишь такую фунцию. они обычно имеют свойство подчеркиваться при наведении мышкой.
Код:
_ChooseFont
 
Автор
A

agikon

Знающий
Сообщения
789
Репутация
16
Zaramot
спасибо.
а можете сделать чтобы сохранялось это всё в ini-файл?
как я не шаманил не хочет он у меня записываься в ini-файл.

Kaster
ну нуб я чего тут не ясного.
 

Zaramot

I ♥ AutoIt
Сообщения
1,160
Репутация
660
а можете сделать чтобы сохранялось это всё в ini-файл?
Код:
#include <Misc.au3>

Global $INI = @ScriptDir & '\Settings.ini'

If FileExists($INI) Then
	$Size = IniRead($INI, 'Font', 'Size', '')
	$Width = IniRead($INI, 'Font', 'Width', '')
	$Attribute = IniRead($INI, 'Font', 'Atributte', '')
	$Name = IniRead($INI, 'Font', 'Name', '')
	$Color = IniRead($INI, 'Font', 'Color', '')
EndIf

GUICreate("Test", 306, 135)
$Label1 = GUICtrlCreateLabel("Hello world !!!", 32, 24, 259, 42)
If FileExists($INI) Then
	GUICtrlSetFont(-1, $Size, $Width, $Attribute, $Name)
	GUICtrlSetColor(-1, $Color)
EndIf
$Button1 = GUICtrlCreateButton("Шрифт", 112, 88, 75, 25)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $Button1
            $Font = _ChooseFont()
            If @error Then ContinueLoop
            GUICtrlSetFont($Label1, $Font[3], $Font[4], $Font[1], $Font[2])
            GUICtrlSetColor($Label1, $Font[7])
			IniWrite($INI, 'Font', 'Size', $Font[3])
			IniWrite($INI, 'Font', 'Width', $Font[4])
			IniWrite($INI, 'Font', 'Atributte', $Font[1])
			IniWrite($INI, 'Font', 'Name', $Font[2])
			IniWrite($INI, 'Font', 'Color', $Font[7])
    EndSwitch
WEnd
 
Автор
A

agikon

Знающий
Сообщения
789
Репутация
16
Zaramot
слов нет..
спасибо большое.
я совсем не так делал, не удивительно что у меня ничего не получалось.
 

Zaramot

I ♥ AutoIt
Сообщения
1,160
Репутация
660
AZJIO,
Код:
#include <Misc.au3>

Global $INI = @ScriptDir & '\Settings.ini'
Global $Italic = False, $Underline = False, $Strikethru = False

If FileExists($INI) Then
	$ColorREF = IniRead($INI, 'Font', 'ColorREF', '')
	$Size = IniRead($INI, 'Font', 'Size', '')
	$Weight = IniRead($INI, 'Font', 'Width', '')
	$Attribute = IniRead($INI, 'Font', 'Atributte', '')
	$Name = IniRead($INI, 'Font', 'Name', '')
	$Color = IniRead($INI, 'Font', 'Color', '')
EndIf

$GUI = GUICreate("Test", 306, 135)
$Label1 = GUICtrlCreateLabel("Hello world !!!", 32, 24, 259, 42)
If FileExists($INI) Then
	GUICtrlSetFont(-1, $Size, $Weight, $Attribute, $Name)
	GUICtrlSetColor(-1, $Color)
EndIf
$Button1 = GUICtrlCreateButton("Шрифт", 112, 88, 75, 25)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $Button1
			Switch $Attribute
				Case 2
					$Italic = True
				Case 10
					$Italic = True
					$Strikethru = True
				Case 8
					$Strikethru = True
				case 4
					$Underline = True
				Case 6
					$Italic = True
					$Underline = True
				Case 12
					$Underline = True
					$Strikethru = True
				Case 14
					$Italic = True
					$Underline = True
					$Strikethru = True
			EndSwitch
            $Font = _ChooseFont($Name, $Size, $ColorREF, $Weight, $Italic, $Underline, $Strikethru, $GUI)
            If @error Then ContinueLoop
            GUICtrlSetFont($Label1, $Font[3], $Font[4], $Font[1], $Font[2])
            GUICtrlSetColor($Label1, $Font[7])
			IniWrite($INI, 'Font', 'Size', $Font[3])
			IniWrite($INI, 'Font', 'Width', $Font[4])
			IniWrite($INI, 'Font', 'Atributte', $Font[1])
			IniWrite($INI, 'Font', 'Name', $Font[2])
			IniWrite($INI, 'Font', 'Color', $Font[7])
			IniWrite($INI, 'Font', 'ColorREF', $Font[5])
    EndSwitch
WEnd
 
Верх