Как отправить ControlSend в нужное окно?

[Spyhunter]

Доброго времени суток,
всплыл недавно вопрос:
Есть несколько окон игры, с абсолютно одинаковым названием.
И

ControlSend()

отправляет символ сразу во все окна игры.
Как отправить символ в одно, определённое окно?

 

[madmasles]

Spyhunter,
Используйте Handle окна вместо заголовка.

 

[Spyhunter]

Я снова упёрся в ту же проблему, как определить handle, если заголовки одинаковы?

 

[madmasles]

Spyhunter [?]

Я снова упёрся в ту же проблему, как определить handle, если заголовки одинаковы?

Попробуйте примерно так.

Dim $aInf[6][2] = [[5]], $sFileRun = @WindowsDir & '\notepad.exe'

For $i = 1 To $aInf[0][0]
	$aInf[$i][0] = Run($sFileRun)
	Sleep(250)
Next

$aList = WinList('[Class:Notepad]')

For $i = 1 To $aInf[0][0]
	For $j = 1 To $aList[0][0]
		If Not BitAND(WinGetState($aList[$j][1]), 2) Then ContinueLoop
		$iTemp = WinGetProcess($aList[$j][1])
		If $iTemp = $aInf[$i][0] Then
			$aInf[$i][1] = $aList[$j][1]
			ExitLoop
		EndIf
	Next
Next
$iTemp = 0

For $i = 1 To $aInf[0][0]
	WinSetTitle($aInf[$i][1], '', 'Window number ' & $i);можно эту строку убрать
	ControlSend($aInf[$i][1], '', '[CLASS:Edit; INSTANCE:1]', 'Window number ' & $i & @CRLF & 'Handle: ' & _
			$aInf[$i][1] & @CRLF & 'PID: ' & $aInf[$i][0] & @CRLF & 'Title: ' & WinGetTitle($aInf[$i][1]))
Next

 

[Spyhunter]

Пока не совсем разобрался в примере... А можно ли узнать handle по PID'y?

 

[madmasles]

Spyhunter [?]

А можно ли узнать handle по PID'y?

_WinAPI_EnumProcessWindows() из WinAPIEx.au3.

 

[Spyhunter]

Похоже, то что надо :laugh:
Спасибо.