Элементы GUI Как определить наличие фокуса на элементе

pvnn · 9 Окт 2022

Всем привет!
Есть элемент, созданный при помощи Autoit, например Input1, т.е. я знаю ID элемента, его хэндл, а как узнать в фокусе ли элемент? Вроде не сложная задача, но как-то не решается...
В ниже приведенном примере, зная ClassNameNN, я могу определить фокус элемента, но это как-то не универсально, т.к. ClassNameNN может быть любой, в зависимости от последовательности создания элементов на форме.
Можно ли определить наличие фокуса зная только ID элемента/хэндл или как мне программно узнать ClassNameNN элемента?

Код:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

HotKeySet("{F1}", "GetFocus")

$Form1 = GUICreate("Form1", 251, 142, 349, 207)
$Input1 = GUICtrlCreateInput("Input1", 8, 16, 121, 21)
$hInput1=GUICtrlGetHandle($Input1)
$Input2 = GUICtrlCreateInput("Input2", 8, 56, 121, 21)
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func GetFocus()
    If ControlGetFocus($Form1)='Edit1' Then
        MsgBox(0,'','$Input1 - в фокусе')
    Else
        MsgBox(0,'','$Input1 - не в фокусе')
    EndIf
EndFunc

Oki · 9 Окт 2022

А если так?

Код:

Func GetFocus()
   If ControlGetHandle("", "", ControlGetFocus($Form1)) = $hInput1 Then
      MsgBox(0, "", "in focus")
   Else
      MsgBox(0, "", "not in focus")
   EndIf
EndFunc

InnI · 9 Окт 2022

pvnn сказал(а):
в зависимости от последовательности создания элементов на форме

Последовательность создания элементов определяете вы сами. В вашем примере Input1 всегда будет Input1, потому что создаётся первым относительно остальных Input.

pvnn сказал(а):
как мне программно узнать ClassNameNN элемента

Узнать ClassnameNN посредством скрипта

Добрый день! Возникла необходимость посредством скомпилированого скрипта (не при помощи стандартной утилиты) узнать класс элемента, который находится под курсором. Есть ли такая возможность? И еще вопрос, дабы не плодить темы: возможно ли следить за мышью и делать определенные действия во время...

autoit-script.ru

Oki · 9 Окт 2022

InnI сказал(а):
Последовательность создания элементов определяете вы сами. В вашем примере Input1 всегда будет Input1, потому что создаётся первым относительно остальных Input.

Разве автор кода не может использовать мнемонику иного стиля в именовании дескрипторов? Суть же вопроса была в обращении именно по дескриптору.

InnI сказал(а):
Узнать ClassnameNN посредством скрипта

Добрый день! Возникла необходимость посредством скомпилированого скрипта (не при помощи стандартной утилиты) узнать класс элемента, который находится под курсором. Есть ли такая возможность? И еще вопрос, дабы не плодить темы: возможно ли следить за мышью и делать определенные действия во время...

autoit-script.ru

Не очень понятно, как использовать получение имени класса окна, когда речь об одном конкретном элементе управления. Но это касается лишь побочного вопроса, возникшего у топикстартера, предложившего один из путей решения изначально сформулированного вопроса. Можно ли попросту обойтись функцией ControlGetHandle(), если отбросить побочный вопрос?

Norm · 9 Окт 2022

Я для этого у себя такую функцию сделал:

Код:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

HotKeySet("{F1}", "GetFocus")

$Form1 = GUICreate("Form1", 251, 142, 349, 207)
$Input1 = GUICtrlCreateInput("Input1", 8, 16, 121, 21)
$hInput1=GUICtrlGetHandle($Input1)
$Input2 = GUICtrlCreateInput("Input2", 8, 56, 121, 21)
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func GetFocus()
    Local $aInfo = _ControlGetFocusEx($Form1, 3)
    If $aInfo <> -1 Then
        MsgBox(0, "В фокусе", _
        "ID = "& $aInfo[0] & @CRLF & _
        "Handle = "& $aInfo[1] & @CRLF & _
        "CLASSNN = "& $aInfo[2])
    EndIf
EndFunc

; Возвращает дескриптор, класс и Control-ID элемента имеющего фокус
Func _ControlGetFocusEx($hWnd = 0, _ ; Дескрипток окна
    $iRet = 0) ; Return: 0 => ID элемента; 1 дескриптор элемента; 2 класс элемента; 3 => массив со всей информацией
    If $hWnd = 0 Then
        $hWnd = WinGetHandle("[ACTIVE]")
    EndIf
    If Not $hWnd Then
        Return -1
    EndIf
    Local $aRetArr[3]
    $aRetArr[2] = ControlGetFocus($hWnd) ; Klass
    $aRetArr[1] = ControlGetHandle($hWnd,"",$aRetArr[2]) ; Handle
    $aRetArr[0] = _WinAPI_GetDlgCtrlID($aRetArr[1]) ; GUI-ID
    Switch $iRet
        Case 3
            Return $aRetArr
        Case Else
            Return $aRetArr[$iRet]
    EndSwitch
EndFunc

Oki · 9 Окт 2022

Norm сказал(а):
Код:

While 1 $nMsg = GUIGetMsg() Switch $nMsg Case $GUI_EVENT_CLOSE Exit EndSwitch WEnd

Всегда поражает, когда вижу эту конструкцию. Ведь можно не мудрить.

Код:

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Но в целом за готовое решение, конечно, лайк. Не в курсе, годится ли для частной цели основного вопроса топика моё, которое выше? Ведь топикстартеру, похоже, не требуется большего.

pvnn · 9 Окт 2022

Oki, Norm

Спасибо! Для Edit все идеально получилось. но я так понимаю, что с ComboBox подобная конструкция работать не будет.
Потому что GUICtrlGetHandle($Combo1) вернет указатель на ComboBox, а ControlGetHandle("", "", ControlGetFocus($Form1)) указатель на Edit1

Код:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

HotKeySet("{F1}", "GetFocus")

$Form1 = GUICreate("Form1", 251, 142, 349, 207)
$Combo1 = GUICtrlCreateCombo("Combo1", 8, 16, 121, 21)
$hCombo1=GUICtrlGetHandle($Combo1)

$Input2 = GUICtrlCreateInput("Input2", 8, 56, 121, 21)
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func GetFocus()
    MsgBox(0,'',ControlGetFocus($Form1)&@CRLF& $hCombo1 &' - '&ControlGetHandle("", "", ControlGetFocus($Form1)))
    If ControlGetHandle("", "", ControlGetFocus($Form1))=$hCombo1 Then
        MsgBox(0,'','$Combo1- в фокусе')
    Else
        MsgBox(0,'','$Combo1 - не в фокусе')
    EndIf
EndFunc

П.С. Я же не выхожу за рамки темы, "Как определить наличие фокуса на элементе" Combo ведь тоже элемент формы. В примере указал только Input, потому что думал, что решение будет работать и для комбо, ведь они оба возвращают ClassNameNN='Edit1'

InnI · 9 Окт 2022

pvnn сказал(а):
с ComboBox подобная конструкция работать не будет

Код:

If _WinAPI_GetAncestor(ControlGetHandle("", "", ControlGetFocus($Form1))) = $hCombo1 Then

Norm · 10 Окт 2022

Спасибо InnI за окончательное решения вопроса.
Теперь определяются все элементы.

Код:

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>

HotKeySet("{F1}", "GetFocus")

Local $iFileMenu, $iFileItem, $hGui
Local $iHelpMenu, $iInfoItem, $iExit, $iRecentFilesMenu
Local $iViewMenu, $iStyleitem, $iBtnOK

$hGui = GUICreate("Элемент меню в GUI", 300, 500)

$iFileMenu = GUICtrlCreateMenu("&Файл")
$iFileItem = GUICtrlCreateMenuItem("Открыть", $iFileMenu)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$iHelpMenu = GUICtrlCreateMenu(GUICtrlGetHandle($iFileMenu))
GUICtrlCreateMenuItem("Сохранить", $iFileMenu)
GUICtrlSetState(-1, $GUI_DISABLE)
$iInfoItem = GUICtrlCreateMenuItem("Информация", $iHelpMenu)
$iExit = GUICtrlCreateMenuItem("Выход", $iFileMenu)
$iRecentFilesMenu = GUICtrlCreateMenu("Последние файлы", $iFileMenu, 1)
$iStyleitem = GUICtrlCreateMenuItem("Стиль GUI POPUP", $iViewMenu)
GUICtrlCreateMenuItem("", $iViewMenu)
$iRadioitem4 = GUICtrlCreateMenuItem("Радио4", $iViewMenu, -1, 1)

$iBtnOK = GUICtrlCreateButton("", 10, 20, 140, 25)
GUICtrlSetData(-1, "Button = "& GUICtrlGetHandle($iBtnOK))
GUICtrlSetState(-1, $GUI_FOCUS)

$Updown = GUICtrlCreateInput("", 180, 20, 100, 24)
GUICtrlCreateUpdown(-1)
GUICtrlCreateLabel(GUICtrlGetHandle($Updown), 190, 5, 100, 14)

$nCh1 = GUICtrlCreateCheckbox("", 10, 60, 120, 20)
GUICtrlSetData(-1, "ChBx = "& GUICtrlGetHandle($nCh1))

$Combo = GUICtrlCreateCombo("", 150, 60, 100, 23)
$hCombo = GUICtrlGetHandle($Combo)
GUICtrlSetData(-1, $hCombo &"|элемент2|элемент3|элемент4", $hCombo)
$date = GUICtrlCreateDate("1953/04/25", 10, 90, 185, 20)
GUICtrlCreateLabel(GUICtrlGetHandle($date), 200, 92, 185, 20)

$iEdit = GUICtrlCreateEdit("", 10, 120, 200, 40)
GUICtrlSetData(-1, "Edit = "& GUICtrlGetHandle($iEdit))

$Input1 = GUICtrlCreateInput("", 10, 170, 200, 20)
GUICtrlSetData(-1, "Input = "& GUICtrlGetHandle($Input1))

$iRadio1 = GUICtrlCreateRadio("", 10, 200, 130, 20)
GUICtrlSetData(-1, "Radio1 = "& GUICtrlGetHandle($iRadio1))
$iRadio2 = GUICtrlCreateRadio("", 10, 220, 130, 20)
GUICtrlSetData(-1, "Radio1 = "& GUICtrlGetHandle($iRadio2))

$treeview = GUICtrlCreateTreeView(150, 200, 100, 90)
$tree1 = GUICtrlCreateTreeViewItem("Тексты", $treeview)
GUICtrlSetData($tree1, GUICtrlGetHandle($treeview))
GUICtrlCreateTreeViewItem("текст1", $tree1)
GUICtrlCreateTreeViewItem("текст2", $tree1)
GUICtrlCreateTreeViewItem("текст3", $tree1)

$tab = GUICtrlCreateTab(10, 280, 200, 60)
$hInf = GUICtrlGetHandle($tab)
GUICtrlCreateTabItem("Путь")
GUICtrlSetImage(-1, "shell32.dll", -222, 0) ; иконка вкладки
GUICtrlCreateLabel($hInf, 20, 310, 185, 20)
GUICtrlCreateTabItem("Test")
GUICtrlCreateLabel($hInf, 20, 310, 185, 20)
GUICtrlCreateTabItem("")

$ListView = GUICtrlCreateListView("ListView Handle|кол2|кол3  ", 10, 350, 220, 120);,$LVS_SORTDESCENDING)
$hInf = GUICtrlGetHandle($ListView)
GUICtrlSetBkColor(-1, 0xFFFEEE) ; устанавливает цвет фона ListView
GUICtrlCreateListViewItem($hInf &"|кол22|кол23", $ListView)
GUICtrlCreateListViewItem($hInf &"|кол12|кол13", $ListView)

GUISetState()
MsgBox(0,Default,"Установите фокус на элемент и нажмите F1")
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func GetFocus()
    Local $tInfo, $aInfo = _ControlGetFocusEx($hGui, 3)
   If Not @error Then
        MsgBox(0, GUICtrlGetHandle($aInfo[0]), _
        "ID = "& $aInfo[0] & @CRLF & _
        "Handle = "& $aInfo[1] & @CRLF & _
        "CLASSNN = "& $aInfo[2])
    EndIf

EndFunc

; Возвращает дескриптор, класс и Control-ID элемента имеющего фокус
Func _ControlGetFocusEx($hWnd = 0, _ ; Дескрипток окна
    $iRet = 0) ; Return: 0 => ID элемента; 1 дескриптор элемента; 2 класс элемента; 3 => массив со всей информацие
    If $hWnd = 0 Then
        $hWnd = WinGetHandle("[ACTIVE]")
    EndIf
    If Not $hWnd Then
        Return SetError(-1,0,0)
    EndIf
   Local $aRetArr[4] = [0,0,0], $hAncstr
    $aRetArr[2] = ControlGetFocus($hWnd) ; Klass
    $aRetArr[1] = ControlGetHandle($hWnd,"",$aRetArr[2]) ; Handle
    $hAncstr = _WinAPI_GetAncestor($aRetArr[1]) ; Handle Ancestor
    $aRetArr[0] = _WinAPI_GetDlgCtrlID(($hAncstr <> $hWnd) ? $hAncstr : $aRetArr[1]) ; GUI-ID
    If $aRetArr[1] = $hWnd Then
	  Return SetError(-2,0,0) ; No Focus
    EndIf
    Switch $iRet
        Case 3
            Return $aRetArr
        Case Else
            Return $aRetArr[$iRet]
    EndSwitch
EndFunc

pvnn · 10 Окт 2022

InnI
Спасибо! То что надо.
Тема решена.

Norm · 8 Окт 2025

Улучшенная версия функции

Код:

; Возвращает информацию о GUI-элементе, который в данный момент находится в фокусе.
; Параметры:
;   $hWnd   – (необязательно) дескриптор окна, в котором нужно проверить фокус.
;             Если не указан или недействителен, используется активное окно.
;   $iRet   – тип возвращаемого значения:
;             0 = ID элемента
;             1 = дескриптор элемента
;             2 = имя класса элемента
;             3 = массив со всеми данными: [ID, дескриптор, класс, дескриптор родителя]
;
; Принцип работы:
;   - Получает дескриптор фокуса через GetFocus().
;   - При необходимости определяет родительское окно через GetParent().
;   - Сравнивает фокус с окном и при необходимости использует Ancestor.
;   - Возвращает запрошенную информацию.
;
; Примечание:
;   Функция особенно полезна для сложных элементов, таких как ComboBox,
;   где фокус может быть установлен на внутренний компонент.
Func _ControlGetFocusEx($hWnd = 0, $iRet = 0)
    Local $aHCtrl = DllCall("user32.dll", "hwnd", "GetFocus")
    If Not IsHWnd($hWnd) Then
        $hWnd = DllCall("user32.dll", "hwnd", "GetParent", "hwnd", $aHCtrl[0])[0]
        If $hWnd = 0 Then $hWnd = WinGetHandle("[ACTIVE]")
    EndIf

    Local $iCtrlID = _WinAPI_GetDlgCtrlID($aHCtrl[0])
    Local $hAncestor = _WinAPI_GetAncestor($aHCtrl[0])
    If ($hAncestor <> $hWnd) Then
        $iCtrlID = _WinAPI_GetDlgCtrlID($hAncestor)
        $aHCtrl[0] = $hAncestor
    EndIf
    Local $aRetArr[4] = [$iCtrlID, $aHCtrl[0], ControlGetFocus($hWnd), $hAncestor]
    Switch $iRet
        Case 3
            Return $aRetArr
        Case Else
            Return $aRetArr[$iRet]
    EndSwitch
EndFunc   ;==>_ControlGetFocusEx

Автор темы	Похожие темы	Форум	Ответы	Дата
A	Автоматизация Определить разрешение экрана и кликнуть в координаты пикселя	Общие вопросы по AutoIt	4	20 Июл 2023
W	Определить окно на переднем плане.	Общие вопросы по AutoIt	3	14 Апр 2023
A	[Сеть, интернет] Определить наличие определенного текста на странице	Общие вопросы по AutoIt	1	14 Окт 2012
G	Как определить наличие цифровой подписи в exe файле?	Общие вопросы по AutoIt	13	16 Июн 2012
K	Определить наличие цвета на иконке курсора	Общие вопросы по AutoIt	0	19 Янв 2012

Поиск

Поиск

Элементы GUI Как определить наличие фокуса на элементе

pvnn

Осваивающий

Oki

Продвинутый

InnI

AutoIT Гуру

Узнать ClassnameNN посредством скрипта

Oki

Продвинутый

Узнать ClassnameNN посредством скрипта

Norm

Продвинутый

Oki

Продвинутый

pvnn

Осваивающий

Oki, Norm

InnI

AutoIT Гуру

Norm

Продвинутый

pvnn

Осваивающий

Norm

Продвинутый

Элементы GUI Как определить наличие фокуса на элементе

Осваивающий

Продвинутый

AutoIT Гуру

Продвинутый

Продвинутый

Продвинутый

Осваивающий

Oki, Norm​

AutoIT Гуру

Продвинутый

Осваивающий

Продвинутый

Oki, Norm