Как быстро поменять раскладку (RU/ENG) на заданную?

[Suppir]

Вариант послания Alt+Shift отпадает, потому что у разных пользователей стоят различные комбинации клавиш. Манипуляции в трее также отпадают, так как у некоторых пользователей есть меню в трее, у других - нет, а у третьих стоит PuntoSwitcher и подобные штуки.
Существует ли функция, которая меняет раскладку на заданную напрямую? Спасибо

 

[vovsla]

поменять раскладку можно только в определённом окне, $WorkWindowName - название окна

$WinID=WinGetHandle($WorkWindowName)
$ret=DllCall("user32.dll", "long", "LoadKeyboardLayout", "str", "00000409", "int", 0)
DllCall("user32.dll", "ptr", "SendMessage", "hwnd", $WinID, "int", "0x50", "int", 1, "int", $ret[0])

00000409 - Eng
00000419 - Rus

 

[Suppir]

Спасибо!

 

[Suppir]

Осталось только узнать, как получить этот $WorkWindowName. У меня в программе название окна (верхняя синяя полоска программы) меняется в зависимости от того, какой документ открыт.
Как получить название активного окна?

 

[SyDr]

"" - вот название активного окна

 

[Suppir]

Ясно, спасибо

 

[vovsla]

можно использовать [CLASS:класс окна] и\или текст в окне
так WinGetHandle("[CLASS:TTOTAL_CMD]") или так WinGetHandle("", "а тут какой-нить текст из окна")

 

[Suppir]

Еще вопросик. У меня в буфере обмена есть текст. Я хочу вставить его в форму. Активный курсор мигает внутри формы, раскладка английская. Я посылаю

Send ("^v")

(вставить), однако вставка текста работает в 1 случае из 10. В чем тут может быть дело?

 

[vovsla]

лучше использовать ControlSend ( а тут можно указать хендел, "text", controlID, "string" [, flag] )
или можно ControlSetText ( "title", "text", controlID, "new text" [, flag] )

 

[kaster]

по вопросу об активном окне

$hwnd = WinGetHandle('[ACTIVE]')

Но тут надо быть аккуратнее, т.к. это действительно хендл именно активного окна, и не всегда это то окно которое нужно ;D

Suppir [?]

однако вставка текста работает в 1 случае из 10

Send, так же как и ControlSend - это имитация нажатия клавиш. А уж когда нажимать, это как говорится лотерея. Нажмется как только интерпретатор начнет обрабатывать именно эту строку.
Поэтому, если так сильно хочется использовать именно Send, то лучше выставить

Opt("SendKeyDelay",...)

нужное время...
Но самое надежное, как уже прозвучало в теме, это

ControlSetText()

 

[vovsla]

а где можно посмотреть все параметры которые можно указывать в квадратных скобках, такие как [ACTIVE]?

 

[kaster]

Vovsla
Help - Window Titles and Text (Advanced)

 

[Suppir]

Ух, перед празниками такая запарка с работой - не остается времени на AutoIt :(

В общем, я пробую использовать ControlSend

Global $Topic = "23968526"
Global $TopicName = "О проведении краевой научно-практической конференции ""Организация медицинской помощи в Краснодарском крае при чрезвычайных ситуациях"
Global $Source = "департамента здравоохранения Краснодарского края"
Global $Type = "Приказ"
Global $Date = "15 декабря 2009 г."
Global $Code = "3241"
Global $Shapka = $Type & " " & $Source & " " & "от " & $Date & " N " & $Code & " """ & $TopicName & """"
ClipPut($Shapka)
sleep (100)
ControlSend("Новый документ", "", "", $Shapka)

При этом у меня вывелось:

Приказ департамента здравоохранения Краснодарского кра от 15 декабря 2009 гю Т 3241 ЭО проведении краевой научно-практической конференции ЭОрганизация медицинской помощи в Краснодарском крае при чрезвычайных ситуацияхЭ

Т.е. кавычки заменились на "Э", точка заменилась на "ю". Я так понимаю, что опять проблема в раскладке.


Добавлено:

Сообщение автоматически объединено: 22 Дек 2009

А если использовать ControlSetText, то символы интерпретируются нормально!

 

[asdf8]

У меня вопрос: как скрипту поменять раскладку своему окну?

#include <GUIConstantsEx.au3>

$Form1 = GUICreate("Form1", 633, 447, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 8, 12, 613, 357)
GUICtrlSetData(-1, "Edit1")
GUISetState(@SW_SHOW)

Sleep(400)
$WinID=WinGetHandle($Form1)
$ret=DllCall("user32.dll", "long", "LoadKeyboardLayout", "str", "00000409", "int", 0)
DllCall("user32.dll", "ptr", "SendMessage", "hwnd", $WinID, "int", "0x50", "int", 1, "int", $ret[0])
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

Если раскладка русская, то после запуска она так и остается русской.

 

[CreatoR]

asdf8 [?]

Если раскладка русская, то после запуска она так и остается русской.

Менять раскладку нужно у Edit-элемента:

#include <GUIConstantsEx.au3>

$Form1 = GUICreate("Form1", 633, 447, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 8, 12, 613, 357)
GUICtrlSetData(-1, "Edit1")
GUISetState(@SW_SHOW)

$aRet = DllCall("user32.dll", "long", "LoadKeyboardLayout", "str", "00000409", "int", 0)
DllCall("user32.dll", "ptr", "SendMessage", "hwnd", GUICtrlGetHandle($Edit1), "int", "0x50", "int", 1, "int", $aRet[0])

While 1
    $nMsg = GUIGetMsg()
	
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

 

[asdf8]

Помогло.
Спасибо.

 

[Yashied]

Друзья, забудьте уже про DllCall(), есть ведь WinAPIEx.au3. В большинстве случаев это намного проще и быстрее.

#include <GUIConstantsEx.au3>
#include <WinAPIEx.au3>

$Form1 = GUICreate("Form1", 633, 447, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 8, 12, 613, 357)
GUICtrlSetData(-1, "Edit1")
GUISetState(@SW_SHOW)

_WinAPI_SetKeyboardLayout(GUICtrlGetHandle($Edit1), 0x0409)

While 1
	$nMsg = GUIGetMsg()

	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

:whistle:

OffTopic:
Надеюсь когда-нибудь эту библиотеку объединят с WinAPI.au3, которая входит в состав AutoIt.

 

[CreatoR]

Yashied [?]

Надеюсь когда-нибудь эту библиотеку объединят с WinAPI.au3, которая входит в состав AutoIt.

Надеяться не вредно, но чтобы это произошло нужно её преподнисти разработчикам, и причём со всеми запчастями, включая доки к каждой функций (подробнее).

 

[Yashied]

OffTopic:
Я это уже делал - #1158.

 

[CreatoR]

Yashied [?]

Я это уже делал - #1158.

Пол года назад - Я немного “поднял” тикет.