[Файловая система] Получение информации о файле

[Talany]

Доброго времени суток.
Вопрос как можно получить информацию о файле?
К примеру файл (C:\Windows\explorer.exe) мне нужна инфа из вкладки "подробно" то есть
Описание, Тип,Версия файла,Название продукта и т.д
Заранее благодарю!

P.S чтото типа этого наверно

$objWMIService = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
If IsObj($objWMIService) Then
$Get = $objWMIService.ExecQuery("Select * from Win32_Process WHERE Name='explorer.exe'", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
EndIf

 

[madmasles]

Talany,
Попробуйте примерно так.

#include <Array.au3>

$sExeFile = @AutoItExe
$aVersion = _FileGetVersionAll($sExeFile)
If @error Then Exit 13
_ArrayDisplay($aVersion, $sExeFile)

Func _FileGetVersionAll($s_FilePath)
	Local $a_String[14] = ['Comments', 'InternalName', 'ProductName', 'CompanyName', 'LegalCopyright', _
			'ProductVersion', 'FileDescription', 'LegalTrademarks', 'PrivateBuild', 'FileVersion', _
			'OriginalFilename', 'SpecialBuild', 'CompiledScript', 'DefaultLangCodepage'], $a_Ret[15][2], $s_Res

	If Not FileExists($s_FilePath) Then Return SetError(1)
	For $s_Tmp In $a_String
		$s_Res = FileGetVersion($s_FilePath, $s_Tmp)
		If @error Then ContinueLoop
		$a_Ret[0][0] += 1
		$a_Ret[$a_Ret[0][0]][0] = $s_Tmp
		$a_Ret[$a_Ret[0][0]][1] = $s_Res
	Next
	If Not $a_Ret[0][0] Then Return SetError(2)
	ReDim $a_Ret[$a_Ret[0][0] + 1][2]
	Return $a_Ret
EndFunc   ;==>_FileGetVersionAll

 

[Talany]

Благодарю madmasles, выриант!

 

[AZJIO]

http://www.autoitscript.com/forum/topic/148232-filegetproperty-retrieves-the-properties-of-a-file/?hl=%2Bproperties