[Элементы GUI] Убрать рамку вокруг объекта IE

[ArgoNaft]

сейчас вот так

надо чтоб было так

Все перекопал не могу найти как решит данный вопрос. Помогите пожалуйста

код:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("eee", 651, 451, -1, -1)
GUISetBkColor(0xFFFFFF)
$Obj1 = ObjCreate("Shell.Explorer.2")
$Obj1_ctrl = GUICtrlCreateObj($Obj1, 0, 0, 650, 356)
$Button1 = GUICtrlCreateButton("oooo", 232, 376, 193, 57)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$Obj1.Navigate("http://google.com")

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd

Если объект делать IE на всю высотку ... то тогда поверх него кнопка не будет нажиматься

 

[snoitaleR]

ArgoNaft
Пока нашёл только две возможности:
Заблокировать объект MIE

GUICtrlSetState($Obj1_ctrl,$GUI_DISABLE)

и установить кнопке атрибут "поверх всех"

GUICtrlSetState($Button1,$GUI_ONTOP)

 

[WSWR]

ArgoNaft

Если объект делать IE на всю высотку ... то тогда поверх него кнопка не будет нажиматься

Можно так:

Спойлер

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#region ### START Koda GUI section ### Form=
$Form2 = GUICreate("eee", 651, 451, -1, -1)
GUIRegisterMsg($WM_MOVE, 'WM_MOVE')

GUISetBkColor(0xFFFFFF)
$Obj1 = ObjCreate("Shell.Explorer.2")
$Obj1_ctrl = GUICtrlCreateObj($Obj1, -10, -10, 680, 481)
GUISetState(@SW_SHOW)
Global $Child_X = 232
Global $Child_Y = 376

$Form3 = GUICreate("oooo", 193, 57, $Child_X, $Child_Y, $WS_POPUP, -1, $Form2)
WM_MOVE($Form2, $WM_MOVE, 0, 0)
$Button1 = GUICtrlCreateButton("oooo", 0, 0, 193, 57)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW, $Form3)
#endregion ### END Koda GUI section ###

$Obj1.Navigate("http://google.com")

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			MsgBox(0, 'Заголовок', 'Button1')
	EndSwitch
WEnd


Func WM_MOVE($hWnd, $iMsg, $wParam, $lParam)

	Switch $hWnd
		Case $Form2
			Local $Pos = WinGetPos($Form2)
			If IsArray($Pos) Then WinMove('[TITLE:oooo; CLASS:AutoIt v3 GUI]', '', $Pos[0] + $Child_X, $Pos[1] + $Child_Y)
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_MOVE

 

[ArgoNaft]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 623, 449, 192, 114)
$Obj1 = ObjCreate("Shell.Explorer.2")
$Obj1_ctrl = GUICtrlCreateObj($Obj1, 0, 0, 623, 449)
$Button1 = GUICtrlCreateButton("Button1", 192, 328, 225, 65)
GUICtrlSetState($Button1,$GUI_ONTOP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd

ВОт так вот работает, спасибо мужики :IL_AutoIt_1:
Правда кнопки появляются только после того как на нее мышку наведешь