Что нового

[Элементы GUI] Убрать фон надписи чекбокса поверх картинки

erlik

Продвинутый
Сообщения
317
Репутация
84
Есть форма с чекбоксами - и картинка, которая служит фоновым рисунком самой формы.
Как сделать, чтобы чекбоксы отображались поверх картинки без своего фона ( имею ввиду ввиду фон текста чекбокса - чтобы отображались только квадратик чекбокса и текст)?

Код:
#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Global $count=45
Global $Array[50]

CreateWPI()

Func CreateWPI()
	Local $msg
    Local $left =10
    Local $top  =10
	
    GUICreate("My GUI Checkbox",600,400)
    local $Picture=GUICtrlCreatePic ("PIC\image.jpg",-1,-1, 600,400)
    GuiCtrlSetState($Picture,$GUI_DISABLE)
    
	For $i = 1 To $count
    If $i=16 Then
	$left=200
	$top=10
    ElseIf $i=31 Then
	$left=400
	$top=10
	EndIf	 
    $Array[$i]= GUICtrlCreateCheckbox("CHECKBOX 1", $left, $top, 120, 20)
	GUICtrlSetBkColor( $Array[$i], $GUI_BKCOLOR_TRANSPARENT) ; вот это не дает нужного эффекта
    $top+=20
    Next
   
     
	GUISetState() 


    While 1
        $msg = GUIGetMsg()
        
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
erlik,
Попробуйте так.
Код:
#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Global $count = 45
Global $Array[50]

CreateWPI()

Func CreateWPI()
	Local $msg, $left = 10, $top = 10, $Picture

	GUICreate('My GUI Checkbox', 600, 400)
	$Picture = GUICtrlCreatePic(@ScriptDir & 'PIC\image.jpg', 0, 0, 600, 400)
	GUICtrlSetState($Picture, $GUI_DISABLE)

	For $i = 1 To $count
		If $i = 16 Then
			$left = 200
			$top = 10
		ElseIf $i = 31 Then
			$left = 400
			$top = 10
		EndIf
		$Array[$i] = GUICtrlCreateCheckbox('', $left, $top, 14, 14)
		GUICtrlCreateLabel('Checkbox ' & $i, $left + 16, $top + 1, 114, 14)
		GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
		$top += 20
	Next
	GUISetState()
	While 1
		$msg = GUIGetMsg()
		If $msg = $GUI_EVENT_CLOSE Then ExitLoop
	WEnd
	GUIDelete()
EndFunc   ;==>CreateWPI
 
Верх