[Элементы GUI] помогите разобраться с Checkbox'ами

[hunter-300399]

Как сделать так что бы test.exe запустился если активирован checkbox а затем нажата кнопка!Вот пример:

if $checkbox = x and $button = x then run("test.exe")

p.s делаю нечто похожее на wpi сборник.

 

[Zaramot]

Пример:

GUICreate("Form1", 192, 118, 192, 124)
$Checkbox1 = GUICtrlCreateCheckbox("", 48, 48, 20, 17)
$Button1 = GUICtrlCreateButton("Button1", 72, 45, 75, 25)
GUISetState()

While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $Button1
			if GUICtrlRead($Checkbox1) = 1 Then Run('notepad.exe')
	EndSwitch
WEnd

 

[madmasles]

hunter-300399,
Или так.

#include <GUIConstantsEx.au3>

Global $aChB[6][2] = [[5],['Prog1\prog1.exe'],['Prog2\prog2.exe'],['Prog3\prog3.exe'],['Prog4\prog4.exe'], _
		['Prog5\prog5.exe']], $sDir = @ScriptDir & '\MyProg\'

$hGui = GUICreate('Test', 200, $aChB[0][0] * 30 + 10 + 30 + 10)
For $i = 1 To $aChB[0][0]
	$aChB[$i][1] = GUICtrlCreateCheckbox(StringRegExpReplace($aChB[$i][0], '\\.*$', ''), 50, 10 + ($i - 1) * 30, 100, 20)
	If Random(0, 1, 1) Then;del
		GUICtrlSetState(-1, $GUI_CHECKED)
	EndIf;del
Next
$nButton = GUICtrlCreateButton('Go', 50, $aChB[0][0] * 30 + 10, 100, 30)
GUISetState()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $nButton
			For $i = 1 To $aChB[0][0]
				If BitAND(GUICtrlRead($aChB[$i][1]), $GUI_CHECKED) Then
					;Run($sDir & $aChB[$i][0])
					ConsoleWrite($sDir & $aChB[$i][0] & @LF)
				EndIf
			Next
	EndSwitch
WEnd

 

[hunter-300399]

Zaramot, madmasles всё заработало большое спасибо за помощь!