Как перемасштабировать картинку без потери качества?

; Изменить рисунок. ByRef вернёт путь по умолчанию
Func _ShangePic(ByRef $sPathCur, $sPic, $iW, $iH)
	Local $sPathOpen, $sPathSave, $DefExt
	$sPathOpen = FileOpenDialog('Открыть', @WorkingDir , 'Рисунок (*.bmp;*.jpg;*.gif;*.png)', 3, '', $Gui)
	If @error Then Return
	; Если текущая папка pic, то применяем сразу
	If StringLeft($sPathOpen, StringLen(@ScriptDir&'\pic'))=@ScriptDir&'\pic' And StringRight($sPathSave, 4)<>'.png' Then
		$sPathCur = 'pic\'&StringRegExpReplace($sPathOpen, '^.*\\(.*)$', '\1')
	Else ; иначе делаем сохранение с конвертированием формата и изменением размеров
		$DefExt='.jpg' ; jpg компактен, база 200 элементов = 1Мб рисунков. При BMP - 60Мб. Но BMP поддерживает прозрачность чёрного в элементе.
		$sPathSave = FileSaveDialog('Сохранить как ...', @ScriptDir&'\pic' , 'Рисунок (*.bmp;*.jpg;*.gif)', 16+8, StringRegExpReplace($sPathOpen, '^.*\\(.*)\..*$', '\1')&$DefExt, $Gui)
		If @error Then Return
		If Not StringInStr(';.bmp;.jpg;.gif;', ';'&StringRight($sPathSave, 4)&';') Then ; если указано иное расширение (не bmp, jpg, gif), то выставляем JPG ($DefExt)
			$sPathSave=StringTrimRight($sPathSave, 4)
			$sPathSave &= $DefExt
		EndIf
		If _ImageResize($sPathOpen, $sPathSave, $iW, $iH) Then ; если конвертирование удачно, то делаем текущим
			$sPathCur = 'pic\'&StringRegExpReplace($sPathSave, '^.*\\(.*)$', '\1')
		Else
			MsgBox(0, 'Сообщение', 'Ошибка при сохранении в указанном формате')
			Return
		EndIf
	EndIf
	GUICtrlSetImage($sPic, @ScriptDir&'\'&$sPathCur)
EndFunc

Func _ImageResize($sImagePath, $sOutImage, $iW, $iH)
    Local $hWnd, $hDC, $hBMP, $hImage1, $hImage2, $hGraphic, $CLSID, $i = 0, $Ext, $TrOut
	
    ;Старт GDIPlus
    _GDIPlus_Startup()

    $hImage2 = _GDIPlus_ImageLoadFromFile ($sImagePath) ; загружаем файл рисунка
	$iWidth = _GDIPlus_ImageGetWidth($hImage2) ; получаем его размеры
	$iHeight = _GDIPlus_ImageGetHeight($hImage2)
	$aWH=_Coor($iW, $iH, $iWidth, $iHeight) ; возвращает пропорциональные координаты по наименьшему

    ; WinAPI для создания пустого bitmap с шириной и высотой, для вставки изменёного рисунка.
    $hWnd = _WinAPI_GetDesktopWindow()
    $hDC = _WinAPI_GetDC($hWnd)
    $hBMP = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
    _WinAPI_ReleaseDC($hWnd, $hDC)

    ;Возвращает дескриптор пустого bitmap созданного ранее в виде изображения
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP ($hBMP)

    ; Создаём графический контекст пустого bitmap
    $hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage1)

    ; Рисует загруженное изображение в пустом bitmap нужного размера
    _GDIPLus_GraphicsDrawImageRect($hGraphic, $hImage2, 0, 0, $aWH[0], $aWH[1])


    ; Расширение файла, чтобы получить CLSID декодера.
    $Ext = StringUpper(StringMid($sOutImage, StringInStr($sOutImage, ".", 0, -1) + 1))
    ; Возвращает декодер, чтобы сохранить изменённое изображение в нужном формате.
    $CLSID = _GDIPlus_EncodersGetCLSID($Ext)

    ; Сохраняет изменённый рисунок.
	$TrOut=_GDIPlus_ImageSaveToFileEx($hImage1, $sOutImage, $CLSID)

    ; Очищает и закрывает GDIPlus.
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_ImageDispose($hImage2)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _WinAPI_DeleteObject($hBMP)
    _GDIPlus_Shutdown()
	Return $TrOut
EndFunc

; Вычисление размера рисунка для пропорционального преобразования
Func _Coor($x1, $y1, $x2, $y2)
	Local $aXY[2] = [0,0], $kX=$x1/$x2, $kY=$y1/$y2
	If Abs($x1-$x2)<3 And Abs($y1-$y2)<3 Then ; если размер почти совпадает, то возврат родных координат, отказ от преобразования
		$aXY[0]=$x2
		$aXY[1]=$y2
		Return SetError(0, 1, $aXY)
	EndIf
	If $kX>$kY Then
		$aXY[0]=Round($x2*$kY)
		$aXY[1]=$y1
	Else
		$aXY[0]=$x1
		$aXY[1]=Round($y2*$kX)
	EndIf
	Return SetError(0, 0, $aXY)
EndFunc