Как получить текущий шрифт в GUI/окне?

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test Script", 300, 200)

GUISetFont(14, 800, 0, "Tahoma")
GUICtrlCreateLabel("Label", 20, 40)

GUISetState(@SW_SHOW, $hGUI)

$aFont = _GUIGetFont($hGUI)
;Возвращает:
;$aFont[1] -> size
;$aFont[2] -> weight
;$aFont[3] -> attribute
;$aFont[4] -> name
;$aFont[5] -> quality

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

Func _GUIGetFont($hWnd)
	Local $aFont[6] = [0]
	;Тут нужно получить шрифт GUI
	Return $aFont
EndFunc

#Include <Array.au3>
#Include <FontConstants.au3>
#Include <WinAPI.au3>
#Include <WindowsConstants.au3>

$hForm = GUICreate('MyGUI', 300, 200)

GUISetFont(12, 700, 2 + 4, 'Tahoma')
GUICtrlCreateLabel('Simple Text', 20, 40)

$aFont = _GUIGetFont($hForm)

GUISetFont($aFont[1], $aFont[2], $aFont[3], $aFont[4], $hForm, $aFont[5])
GUICtrlCreateLabel('Simple Text', 20, 80)

GUISetState(@SW_SHOW)

_ArrayDisplay($aFont)

Do
Until GUIGetMsg() = -3

Func _GUIGetFont($hWnd)

; [0] - 0
; [1] - Size
; [2] - Weight
; [3] - Attribute
; [4] - Name
; [5] - Quality

	Local $Ret, $Label, $hLabel, $hPrev, $hDC, $hFont, $tFont
	Local $aFont = 0

	$hPrev = GUISwitch($hWnd)
	If Not $hPrev Then
		Return 0
	EndIf
	$Label = GUICtrlCreateLabel('', 0, 0, 0, 0)
	If Not $Label Then
		Return 0
	EndIf
	$hLabel = GUICtrlGetHandle($Label)
	$hDC = _WinAPI_GetDC($hLabel)
	$hFont = _SendMessage($hLabel, $WM_GETFONT)
	$tFont = DllStructCreate($tagLOGFONT)
	$Ret = DllCall('gdi32.dll', 'int', 'GetObjectW', 'ptr', $hFont, 'int', DllStructGetSize($tFont), 'ptr', DllStructGetPtr($tFont))
	If (Not @error) And ($Ret[0]) Then
		Dim $aFont[6] = [0]
		$aFont[1] = -Round(DllStructGetData($tFont, 'Height') / _WinAPI_GetDeviceCaps($hDC, $LOGPIXELSY) * 72, 1)
		$aFont[2] = DllStructGetData($tFont, 'Weight')
		$aFont[3] = BitOR(2 * (DllStructGetData($tFont, 'Italic') <> 0), 4 * (DllStructGetData($tFont, 'Underline') <> 0), 8 * (DllStructGetData($tFont, 'Strikeout') <> 0))
		$aFont[4] = DllStructGetData($tFont, 'FaceName')
		$aFont[5] = DllStructGetData($tFont, 'Quality')
	EndIf
	_WinAPI_ReleaseDC($hLabel, $hDC)
	GUICtrlDelete($Label)
	GUISwitch($hPrev)
	Return $aFont
EndFunc   ;==>_GUIGetFont