Инструкция или концепция продажи своего ПО

#include <WinAPIDiag.au3>
#include <APIDiagConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <InetConstants.au3>

Global $sPRODUCT_NAME		= 'My Program'
Global $sPRODUCT_ID			= '12345' ;This is your product id from DigiSeller service
Global $sPRODUCT_URL		= 'https://www.oplata.info/asp2/pay_pp.asp?id_d=' & $sPRODUCT_ID
Global $sDBCMD_URL			= 'http://myserver.ru/db_cmd.php'
Global $sPRODUCT_INV		= _ProductKey_Read('inv')
Global $sPRODUCT_HWID		= _ProductKey_Read('hwid')
Global $fAPP_LICENSED 		= _ProductKey_Validate()

If $fAPP_LICENSED Then
	MsgBox(64, 'Title', 'Full version code')
	Exit
Else
	_RegisterGUI()
EndIf

;.....

If $fAPP_LICENSED Then
	MsgBox(64, 'Title', 'Full version code (after registration)')
EndIf

Func _RegisterGUI()
	Local $hGUI, $iRegister_Bttn, $iData_Input, $iCopy_Bttn, $iPK_Input, $iRestorePK_Bttn, $iOk_Bttn, $iCancel_Bttn
	Local $fHWID_Restored = False
	
	$hGUI = GUICreate('Registration...', 500, 300)
	
	GUICtrlCreateLabel('To use full version of this program, you must register', 20, 20)
	GUICtrlCreateLabel('Copy DATA bellow and press "Register..." button', 20, 40)
	$iRegister_Bttn = GUICtrlCreateButton('Register...', 20, 70, 80, 20)
	GUICtrlCreateLabel('After successful payment you will be asked to set DATA field', 120, 72)
	GUICtrlCreateLabel('DATA:', 20, 113)
	$iData_Input = GUICtrlCreateInput(_ProductKey_GetHardwareData(), 60, 110, 340, 20, BitOR($GUI_SS_DEFAULT_INPUT, $ES_READONLY))
	GUICtrlSetState(-1, $GUI_FOCUS)
	$iCopy_Bttn = GUICtrlCreateButton('Copy', 420, 110, 60, 20)
	
	GUICtrlCreateLabel('Product Key:', 20, 203)
	$iPK_Input = GUICtrlCreateInput('', 100, 200, 380, 20)
	$iRestorePK_Bttn = GUICtrlCreateButton('Restore product key...', 100, 220, 120, 20)
	
	$iOk_Bttn = GUICtrlCreateButton('OK', 20, 270, 60, 20)
	$iCancel_Bttn = GUICtrlCreateButton('Cancel', 100, 270, 60, 20)
	
	GUISetState(@SW_SHOW, $hGUI)
	
	While 1
		$nMsg = GUIGetMsg()
	
		Switch $nMsg
			Case $GUI_EVENT_CLOSE, $iCancel_Bttn
				If $fHWID_Restored Then
					Local $iAsk = MsgBox(52, 'Attention', _
						'Are you sure? you already have restored the product key...' & @CRLF & @CRLF & _
						'* If you cancel now, the restore point will be registered, many restore points in short time can cause license to be deactivated *', _
						0, $hGUI)
					
					If $iAsk <> 6 Then
						ContinueLoop
					EndIf
				EndIf
				
				$fAPP_LICENSED = False
				
				_ProductKey_Delete('hwid')
				_ProductKey_Delete('inv')
				
				ExitLoop
			Case $iRegister_Bttn
				ShellExecute($sPRODUCT_URL)
			Case $iCopy_Bttn
				ClipPut(GUICtrlRead($iData_Input))
			Case $iRestorePK_Bttn
				If $fHWID_Restored Then
					Local $iAsk = MsgBox(52, 'Attention', _
						'Are you sure? you already have restored the product key...' & @CRLF & @CRLF & _
						'* If you restore again, the restore point will be registered, many restore points in short time can cause license to be deactivated *', _
						0, $hGUI)
					
					If $iAsk <> 6 Then
						ContinueLoop
					EndIf
				EndIf
				
				$sInv = InputBox('Restore...', 'Please enter your payment receipt number (product_inv):', '', '', -1, -1, Default, Default, 0, $hGUI)
				
				If $sInv <> '' Then
					$sPRODUCT_INV = $sInv
					$sPRODUCT_HWID = 'OLD_HWID'
					
					$fAPP_LICENSED = _ProductKey_Validate()
					
					If $fAPP_LICENSED Then
						GUICtrlSetData($iPK_Input, $sPRODUCT_HWID)
						$fHWID_Restored = True
					Else
						MsgBox(48, 'Error', 'Sorry, unable to restore your Product key, wrong payment receipt number (product_inv), or it''s blocked.', 0, $hGUI)
						$fHWID_Restored = False
					EndIf
				EndIf
			Case $iOk_Bttn
				$sPRODUCT_HWID = GUICtrlRead($iPK_Input)
				$fAPP_LICENSED = _ProductKey_Validate()
				
				If $fAPP_LICENSED Then
					_ProductKey_Write('hwid', $sPRODUCT_HWID)
					_ProductKey_Write('inv', $sPRODUCT_INV)
					
					MsgBox(64, 'Successful!', 'Now your product is licensed!', 0, $hGUI)
					
					ExitLoop
				EndIf
				
				MsgBox(48, 'Error', 'Sorry, wrong Product Key', 0, $hGUI)
		EndSwitch
	WEnd
	
	GUIDelete($hGUI)
EndFunc

Func _ProductKey_Validate()
	Local $sPK = _ProductKey_GenerateKey()
	
	;If hwid from registry match the current hardware id, then this soft is licensed
	If $sPRODUCT_HWID == $sPK Then
		;Set once the product_inv data
		If $sPRODUCT_INV = '' Then
			;Get product_inv data from our db_cmd.php wrapper
			Local $sInv = _ProductKey_DBRequest('get_inv', $sPRODUCT_ID, $sPRODUCT_INV, $sPK)
			
			;product_inv may be blocked
			If @error Then
				Return False
			EndIf
			
			_ProductKey_Write('inv', $sInv)
		EndIf
		
		Return True
	EndIf
	
	;If product_inv or product_hwid not found, then this soft is not licensed
	If $sPRODUCT_INV = '' Or $sPRODUCT_HWID = '' Then
		Return False
	EndIf
	
	Local $sValidate = _ProductKey_DBRequest('validate_inv', $sPRODUCT_ID, $sPRODUCT_INV, $sPK)
	
	;@error will indicate that there was an error to connect to the database (you can use it to inform the user to contact the author)
	If @error Then
		Return SetError(1, 0, False)
	EndIf
	
	If $sValidate = 'OK' Then
		$sPRODUCT_HWID = $sPK
		_ProductKey_Write('hwid', $sPK)
		Return True
	Else
		_ProductKey_Delete('hwid')
		Return False
	EndIf
EndFunc

Func _ProductKey_DBRequest($sFunc, $sID, $sINV, $sPK = '')
	If $sPK <> '' Then
		;Some sort of crypting method (decrypted later by db_cmd.php script)
		$sPK = _ProductKey_Crypt($sPK)
	EndIf
	
	Local $sRet = InetRead($sDBCMD_URL & '?fnc=' & $sFunc & '&id=' & $sID & '&inv=' & $sINV & '&pk=' & $sPK, $INET_FORCERELOAD)
	Local $iError = @error
	
	$sRet = BinaryToString($sRet)
	
	If $iError Or StringInStr($sRet, 'ERROR: ', 2) Then
		Return SetError(1, 0, $sRet)
	EndIf
	
	Return $sRet
EndFunc

Func _ProductKey_GenerateKey($sHWID = '')
	Local $sPK_Val = $sHWID
	
	If $sHWID = '' Then
		$sPK_Val = _ProductKey_GetHardwareData()
	EndIf
	
	Local $sRet_PK, $aSplit_PK = StringSplit(StringRegExpReplace(StringUpper($sPK_Val), "[^A-Z0-9]+", ""), "")
	
	For $i = $aSplit_PK[0] To 1 Step -2
		If Mod($i, 5) = 0 Then
			$sRet_PK &= $aSplit_PK[$i] & "-"
		Else
			$sRet_PK &= $aSplit_PK[$i]
		EndIf
	Next
	
	Return StringRegExpReplace($sRet_PK, "\A-+|-+$|\A.{1,4}-|-.{1,4}$", "")
EndFunc

Func _ProductKey_GetHardwareData()
	Local $sUniqueHwID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS))
	
	$sUniqueHwID = StringTrimLeft($sUniqueHwID, 1)
	$sUniqueHwID = StringTrimRight($sUniqueHwID, 1)
	$sUniqueHwID &= '-AERTFG' & StringLeft($sPRODUCT_ID, 3) & '-FGGHFGME' & StringTrimLeft($sPRODUCT_ID, 3)
	
	Return $sUniqueHwID
EndFunc

Func _ProductKey_Crypt($sPK)
	Local $s_PK = ''
	
	$s_PK &= StringRight($sPK, 4)
	$s_PK &= StringLeft($sPK, 4)
	$s_PK &= StringMid($sPK, 5, StringLen($sPK) - 8)
	
	Return StringReverse($s_PK)
EndFunc

Func _ProductKey_Delete($sKey)
	Local $iDel = IniDelete(@ScriptDir & '\Product.key', 'Data', $sKey)
	
	If @error Or $iDel == 0 Then
		RegDelete('HKLM\SOFTWARE\' & $sPRODUCT_NAME, $sKey)
	EndIf
	
	Return Number(@error = 0)
EndFunc

Func _ProductKey_Read($sKey)
	Local $sRead = IniRead(@ScriptDir & '\Product.key', 'Data', $sKey, '@ERROR@')
	
	If $sRead == '@ERROR@' Then
		$sRead = RegRead('HKLM\SOFTWARE\' & $sPRODUCT_NAME, $sKey)
	EndIf
	
	Return $sRead
EndFunc

Func _ProductKey_Write($sKey, $sVal)
	Local $iWrite = IniWrite(@ScriptDir & '\Product.key', 'Data', $sKey, $sVal)
	
	If @error Or $iWrite == 0 Then
		RegWrite('HKLM\SOFTWARE\' & $sPRODUCT_NAME, $sKey, 'REG_SZ', $sVal)
	EndIf
	
	Return Number(@error = 0)
EndFunc

#include <WinAPIDiag.au3>
#include <APIDiagConstants.au3>

Global $sAPP_NAME			= 'My Program'
Global $sAPP_PRICE			= '10'
Global $sAPP_IMAGEURL		= 'http://myserver.ru/images/MyApp.jpg'
Global $sAPP_EMAIL			= '[email protected]'
Global $sPAYMENT_PAGE		= 'http://myserver.ru/payment-page.html'
Global $sREGISTER_URL		= 'http://myserver.ru/product_register.php'
Global $sPRODUCT_HWID		= _ProductKey_Read('hwid')
Global $fAPP_LICENSED 		= _ProductKey_Validate()

If $fAPP_LICENSED Then
	MsgBox(64, 'Title', 'Full version code')
	Exit
Else
	$sPage = StringFormat('?app=%s&img=%s&lang=%s&price=%s&ppage=%s&email=%s&uid=%s', _
		$sAPP_NAME, $sAPP_IMAGEURL, 'English', $sAPP_PRICE, $sPAYMENT_PAGE, $sAPP_EMAIL, _ProductKey_GetHardwareData())
	ShellExecute($sREGISTER_URL & $sPage)
	
	$sPK = InputBox('Product key', 'Please enter your Product Key:', '')
	
	If $sPK <> '' Then
		$sPRODUCT_HWID = $sPK
		$fAPP_LICENSED = _ProductKey_Validate()
	EndIf
EndIf

;.....

If $fAPP_LICENSED Then
	MsgBox(64, 'Title', 'Full version code (after registration)')
EndIf

Func _ProductKey_Validate()
	Local $sPK = _ProductKey_GenerateKey()
	
	If $sPRODUCT_HWID == $sPK Then
		_ProductKey_Write('hwid', $sPK)
		Return True
	EndIf
	
	Return False
EndFunc

Func _ProductKey_GenerateKey($sHWID = '')
	Local $sPK_Val = $sHWID
	
	If $sHWID = '' Then
		$sPK_Val = _ProductKey_GetHardwareData()
	EndIf
	
	Local $sRet_PK, $aSplit_PK = StringSplit(StringRegExpReplace(StringUpper($sPK_Val), "[^A-Z0-9]+", ""), "")
	
	For $i = $aSplit_PK[0] To 1 Step -2
		If Mod($i, 5) = 0 Then
			$sRet_PK &= $aSplit_PK[$i] & "-"
		Else
			$sRet_PK &= $aSplit_PK[$i]
		EndIf
	Next
	
	Return StringRegExpReplace($sRet_PK, "\A-+|-+$|\A.{1,4}-|-.{1,4}$", "")
EndFunc

Func _ProductKey_GetHardwareData()
	Local $sUniqueHwID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS))
	Local $sName = StringStripWS($sAPP_NAME, 8)
	
	$sUniqueHwID = StringTrimLeft($sUniqueHwID, 1)
	$sUniqueHwID = StringTrimRight($sUniqueHwID, 1)
	$sUniqueHwID &= '-AERTFG' & StringLeft($sName, 3) & '-FGGHFGME' & StringTrimLeft($sName, 3)
	
	Return $sUniqueHwID
EndFunc

Func _ProductKey_Read($sKey)
	Local $sRead = IniRead(@ScriptDir & '\Product.key', 'Data', $sKey, '@ERROR@')
	
	If $sRead == '@ERROR@' Then
		$sRead = RegRead('HKLM\SOFTWARE\' & $sAPP_NAME, $sKey)
	EndIf
	
	Return $sRead
EndFunc

Func _ProductKey_Write($sKey, $sVal)
	Local $iWrite = IniWrite(@ScriptDir & '\Product.key', 'Data', $sKey, $sVal)
	
	If @error Or $iWrite == 0 Then
		RegWrite('HKLM\SOFTWARE\' & $sAPP_NAME, $sKey, 'REG_SZ', $sVal)
	EndIf
	
	Return Number(@error = 0)
EndFunc