[Окна, Диалоги] Данные из диалога в скрипт или текстовый файл?

InputBox()

GUICtrlCreateEdit

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

Global $aInput[5] = ['1-ые данные', '2-ые данные', '3-ий вопрос', '4-ый вопрос', '5-ый вопрос'], _ ;массив с текстом вопросов
		$iW = 210, _		;ширина окна
		$iCount = 5, _		;кол-во элементов
		$iW_LI = 200, _		;ширина Label и Input
		$iH_Label = 16, _	;высота Label
		$iH_Input = 20, _	;высота Input
		$iTop = 10, _		;отступ от верхнего края окна
		$iW_Btn = 100, _	;ширина Button
		$iH_Btn = 30 ;высота Button

$hGui = GUICreate('Test', $iW, $iTop * 3 + $iCount * ($iH_Label + $iH_Input) + $iH_Btn);создаем окно
;В цикле создаем нужные нам элементы:
For $i = 0 To $iCount - 1
	GUICtrlCreateLabel($aInput[$i], ($iW - $iW_LI) / 2, $iTop + $i * ($iH_Label + $iH_Input), $iW_LI, $iH_Label, BitOR($GUI_SS_DEFAULT_LABEL, $SS_CENTER, $SS_CENTERIMAGE))
	$aInput[$i] = GUICtrlCreateInput('', ($iW - $iW_LI) / 2, $iTop + $iH_Label + $i * ($iH_Label + $iH_Input), $iW_LI, $iH_Input)
Next
$nBtn = GUICtrlCreateButton('Прочитать ответы', ($iW - $iW_Btn) / 2, $iTop * 2 + $iCount * ($iH_Label + $iH_Input), $iW_Btn, $iH_Btn)
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $nBtn
			$sText = ''
			For $i = 0 To $iCount - 1
				$sTmp = GUICtrlRead($aInput[$i])
				If Not $sTmp Then $sTmp = 'Нет ответа'
				MsgBox(64, 'Ответ № ' & $i + 1, 'Вопрос :' & GUICtrlRead($aInput[$i] - 1) & @LF & 'Ответ: ' & $sTmp, 0, $hGui)
				$sText &= $sTmp & @CRLF
			Next
			MsgBox(64, 'Все ответы', $sText, 0, $hGui)
			$sTmp = ''
			$sText = ''
	EndSwitch
WEnd