Не могу разобраться с GUICtrlCreateLabel

edyapd · 17 Фев 2010

Кусок из программы:

Код:

#include <GUIConstants.au3>
Opt("GUIOnEventMode", 1)

$gui = GUICreate("Моя программа", @DesktopWidth-100, 210, 50, 50)
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
GUISetState(@SW_SHOW)
Data1()

While 1
	Sleep(1000)
WEnd

Func Data1()
	$lvl =	 GUICtrlCreateLabel("", 82, 57)
 	GUICtrlSetData($lvl, "Level")	
EndFunc

Func Close()
	Exit
EndFunc

Вместо "Level" выводиться часть буквы. Если сделать:

Код:

$lvl =	 GUICtrlCreateLabel("00", 82, 57)

То выводиться чуть больше символов. Но я заранее не знаю сколько символов придется выводить.
Или я вообще что-то не правильно делаю.
Хотел создать несколько указателей и потом забивать через них данные, которые могут со временем меняться.
Подскажите как это можно решить.

kaster · 17 Фев 2010

edyapd [?]

Или я вообще что-то не правильно делаю.

Да. не задаешь размеры Label'a. Задай хотябы 50 в длину и 20 по высоте

Код:

$lvl  =   GUICtrlCreateLabel("00", 82, 57, 50, 20)

Yashied · 17 Фев 2010

Лучше задать фиксированную ширину (длину) элемента, но можно написать так:

Код:

#Include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
#Include <WindowsConstants.au3>

GUICreate('MyGUI', 400, 100)
$Label = GUICtrlCreateLabel('', 20, 20)
GUISetState()

_SetData($Label, 'This')
Sleep(400)
_SetData($Label, 'This is')
Sleep(400)
_SetData($Label, 'This is simple')
Sleep(400)
_SetData($Label, 'This is simple text')

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _SetData($CtrlID, $sText)

	Local $hWnd, $Pos, $Size

	$hWnd = GUICtrlGetHandle($CtrlID)
	$Pos = ControlGetPos($hWnd, '', '')
	$Size = _StringSize($hWnd, $sText)
	GUICtrlSetPos($CtrlID, $Pos[0], $Pos[1], $Size[0], $Size[1])
	GUICtrlSetData($CtrlID, $sText)
EndFunc   ;==>_SetData

Func _StringSize($hWnd, $sText)

	Local $hDC, $hFont, $hSv, $tSize, $Result[2]

	$hDC = _WinAPI_GetDC($hWnd)
	$hFont = _SendMessage($hWnd, $WM_GETFONT)
	$hSv = _WinAPI_SelectObject($hDC, $hFont)
	$tSize = _WinAPI_GetTextExtentPoint32($hDC, $sText)
	_WinAPI_SelectObject($hDC, $hSv)
	_WinAPI_ReleaseDC($hWnd, $hDC)
	$Result[0] = DllStructGetData($tSize, 1)
	$Result[1] = DllStructGetData($tSize, 2)
	Return $Result
EndFunc   ;==>_StringSize

edyapd · 17 Фев 2010

Спасибо. Пока буду использовать фиксированую длину. Когда разберусь с примером Yashied то может вставлю его.

Автор темы	Похожие темы	Форум	Ответы	Дата
D	FileCopy - утилита копирования с GUI .... не могу скачать	Общие вопросы по AutoIt	2	12 Авг 2022
S	Не могу разобраться в функции	Общие вопросы по AutoIt	1	31 Окт 2015
S	[Элементы GUI] Не могу разобраться с FileInstall	Общие вопросы по AutoIt	1	30 Июл 2014
M	никак не могу разобраться как запустить скрипт как службу	Общие вопросы по AutoIt	18	1 Июн 2013
W	немогу разобраться с id	Общение	5	5 Июн 2012

Поиск

Поиск

Не могу разобраться с GUICtrlCreateLabel

edyapd

Осваивающий

kaster

Мой Аватар, он лучший самый

Yashied

Модератор

edyapd

Осваивающий