Блокировка подключаемых устройств

joiner · 1 Окт 2009

нашел на oszone функцию по блокировке папок и файлов.
хочу использовать его для блокировки подключаемых устройств usb
блокирует одно устройство, которое подключено, а если подключаю другое, то не блокирует. хочется добиться, чтобы при запуске кода любое подключаемое usb в любом количестве блокировалось.

Код:

$var = DriveGetDrive( "REMOVABLE" )

While 1
If NOT @error Then

    For $i = 1 to $var[0]
 $hFile = _CreateFile($var[$i])
Next
EndIf

WEnd
If $hFile = -1 Then Exit MsgBox(16, "Error", "Unable to open file")
Func _CreateFile($var)
    Local Const $GENERIC_READ  = 0x80000000
    Local Const $GENERIC_WRITE = 0x40000000

    Local Const $FILE_FLAG_BACKUP_SEMANTICS = 0x02000000
    Local Const $OPEN_EXISTING = 3

    $var = "\\.\" & $var

    Local $aRet = DllCall("kernel32.dll", "hwnd", "CreateFile", _
                                          "str", $var, _
                                          "int", BitOR($GENERIC_READ, $GENERIC_WRITE), _
                                          "int", 0, _
                                          "ptr", 0, _
                                          "int", $OPEN_EXISTING, _
                                          "int", $FILE_FLAG_BACKUP_SEMANTICS, _
                                          "int", 0)
    Return $aRet[0]
EndFunc

блокирует если на момент запуска была подключена флешка. и все..что нужно изменить?

ZanMax · 2 Окт 2009

Самого интересует даный вопрос.
Но у меня еще один вопрос :
Как можно запретить все устройства кроме 1,2,3
Я знаю что флешки можно както идентифицировать.
Спасибо.

Yashied · 2 Окт 2009

Александр сказал(а):
...хочется добиться, чтобы при запуске кода любое подключаемое usb в любом количестве блокировалось.

Вот первая часть скрипта, вторую напишу потом (если будет время). :smile:

Код:

#Include <WinAPIEx.au3>

Global Const $WM_DEVICECHANGE = 0x0219

Global Const $DBT_DEVICEARRIVAL = 0x00008000
Global Const $DBT_DEVICEREMOVECOMPLETE = 0x00008004
Global Const $DBT_DEVTYP_VOLUME = 0x00000002

Global $DevList = _GetDevList()

GUICreate('')
GUIRegisterMsg($WM_DEVICECHANGE, '_WM_DEVICECHANGE')
;GUISetState()

Do
Until GUIGetMsg() = -3

Func _WM_DEVICECHANGE($hWnd, $iMsg, $wParam, $lParam)
    Switch $wParam
        Case $DBT_DEVICEARRIVAL, $DBT_DEVICEREMOVECOMPLETE

            Local $NewList = _GetDevList()

            Switch $wParam
                Case $DBT_DEVICEARRIVAL

                    Local $tDEV_BROADCAST_VOLUME = DllStructCreate('int Size;int DeviceType;int Reserved;int UnitMask;ushort Flags', $lParam)

                    If DllStructGetData($tDEV_BROADCAST_VOLUME, 'DeviceType') = $DBT_DEVTYP_VOLUME Then
                        $Drive = _ArrayDiff($DevList, $NewList) & ':'
                        Switch _WinAPI_GetDriveBusType($Drive)
                            Case $DRIVE_BUS_TYPE_USB
                                ConsoleWrite('USB drive (' & StringUpper($Drive) & ') detected.' & @CR)

                                ; Здесь блокируем USB устройство

                        EndSwitch
                    EndIf
            EndSwitch
            $DevList = $NewList
    EndSwitch
    Return 0
EndFunc   ;==>_WM_DEVICECHANGE

Func _ArrayDiff(ByRef $ArrayMin, ByRef $ArrayMax)

    Local $Dup

    For $i = $ArrayMax[0] To 1 Step -1
        $Dup = 1
        For $j = $ArrayMin[0] To 1 Step -1
            If $ArrayMax[$i] = $ArrayMin[$j] Then
                $Dup = 0
                ExitLoop
            EndIf
        Next
        If $Dup Then
            Return $ArrayMax[$i]
        EndIf
    Next
    Return 0
EndFunc   ;==>_ArrayDiff

Func _GetDevList()

    Local $Drv = DriveGetDrive('REMOVABLE')

    If Not IsArray($Drv) Then
        Dim $Drv[1] = [0]
    EndIf
    For $i = 1 To $Drv[0]
        $Drv[$i] = StringLeft($Drv[$i], 1)
    Next
    Return $Drv
EndFunc   ;==>_GetDevList

WinAPIEx.au3

Yashied · 2 Окт 2009

Можно так.

Код:

#Include <WinAPIEx.au3>

Global Const $WM_DEVICECHANGE = 0x0219

Global Const $DBT_DEVICEARRIVAL = 0x00008000
Global Const $DBT_DEVICEREMOVECOMPLETE = 0x00008004
Global Const $DBT_DEVTYP_VOLUME = 0x00000002

Global $DevList = _GetDevList()

GUICreate('')
GUIRegisterMsg($WM_DEVICECHANGE, '_WM_DEVICECHANGE')
;GUISetState()

Do
Until GUIGetMsg() = -3

Func _WM_DEVICECHANGE($hWnd, $iMsg, $wParam, $lParam)
    Switch $wParam
        Case $DBT_DEVICEARRIVAL, $DBT_DEVICEREMOVECOMPLETE

            Local $NewList = _GetDevList()

            Switch $wParam
                Case $DBT_DEVICEARRIVAL

                    Local $tDEV_BROADCAST_VOLUME = DllStructCreate('int Size;int DeviceType;int Reserved;int UnitMask;ushort Flags', $lParam)

                    If DllStructGetData($tDEV_BROADCAST_VOLUME, 'DeviceType') = $DBT_DEVTYP_VOLUME Then
                        $Drive = _ArrayDiff($DevList, $NewList)
                        Switch _WinAPI_GetDriveBusType($Drive & ':')
                            Case $DRIVE_BUS_TYPE_USB
;                                ConsoleWrite('USB drive (' & StringUpper($Drive) & ':) detected.' & @CR)
                                DllCall(@ScriptDir & '\SRD.dll', 'str', 'SafeRemoveDrive', 'str', $Drive)
                        EndSwitch
                    EndIf
            EndSwitch
            $DevList = $NewList
    EndSwitch
    Return 0
EndFunc   ;==>_WM_DEVICECHANGE

Func _ArrayDiff(ByRef $ArrayMin, ByRef $ArrayMax)

    Local $Dup

    For $i = $ArrayMax[0] To 1 Step -1
        $Dup = 1
        For $j = $ArrayMin[0] To 1 Step -1
            If $ArrayMax[$i] = $ArrayMin[$j] Then
                $Dup = 0
                ExitLoop
            EndIf
        Next
        If $Dup Then
            Return $ArrayMax[$i]
        EndIf
    Next
    Return 0
EndFunc   ;==>_ArrayDiff

Func _GetDevList()

    Local $Drv = DriveGetDrive('REMOVABLE')

    If Not IsArray($Drv) Then
        Dim $Drv[1] = [0]
    EndIf
    For $i = 1 To $Drv[0]
        $Drv[$i] = StringLeft($Drv[$i], 1)
    Next
    Return $Drv
EndFunc   ;==>_GetDevList

SRD.dll - где нашел уже не помню.
WinAPIEx.au3

ZanMax · 2 Окт 2009

Нашел вот что в Диспетчере устройств :

Я так думаю для каждой флешки по другому будет ? или я не прав ?
Если да. То как взять даное значение ?

CreatoR · 2 Окт 2009

Yashied [?]

SRD.dll - где нашел уже не помню.

Кстати она есть в виде встроенного модуля (au3 файл), см. тему Отсоединение УСБ устройства.

Yashied · 2 Окт 2009

Кажется я его взял где-то на Ru-Board. :smile:

Но возможно (?) его писал не Rasim.

CreatoR · 2 Окт 2009

Yashied [?]

Но возможно (?) его писал не Rasim.

Я почти уверен что Dll'ку не он писал, там авторство относится к самому проекту ;)

madmasles · 14 Сен 2011

scenarist [?]

Вы б хоть проверяли сценарии,перед тем, как публиковать.

А Вы бы внимательнее читали описание перед использованием. :smile:

Расширение стандартной AutoIt библиотеки WinAPI.au3 (под спойлером) [?]

WinAPIEx.au3 теперь не включает в себя APIConstants.au3. Вы должны самостоятельно включить APIConstants.au3 в ваши скрипты с помощью "#Include", если хотите использовать объявленные в нем константы.

Автор темы	Похожие темы	Форум	Ответы	Дата
Z	Перехват и блокировка перемещений окна	Общие вопросы по AutoIt	0	25 Фев 2023
	Процессы Временная блокировка повторного использования идентификатора процесса	Общие вопросы по AutoIt	8	11 Ноя 2022
	Мышь, клавиатура Блокировка мышки по оси Y	Стол заказов	3	19 Июн 2022
S	Блокировка клавиатуры через Devcon.exe	Общие вопросы по AutoIt	6	15 Янв 2020
S	блокировка Ctrl+Alt+Del	Общие вопросы по AutoIt	4	9 Янв 2020

Поиск

Поиск

Блокировка подключаемых устройств

joiner

Модератор

ZanMax

Тестер

Yashied

Модератор

Yashied

Модератор

ZanMax

Тестер

CreatoR

Must AutoIt!

Yashied

Модератор

CreatoR

Must AutoIt!

madmasles

Модератор