Обработка текста (удаление строк по условиям)

Local $s_FileRead = @ScriptDir & '\txt.txt', $a_Read, $s_Txt, $i_Tmp, $s_FileWrite, $h_File

$s_Txt = FileRead($s_FileRead);читаем обрабатываемый файл
$a_Read = StringRegExp($s_Txt, '(?<=[\n\r]|^)(.{5})[^\n\r]+(\(<(?:печать|ПЕЧАТЬ).+?)(?=[\n\r]|$)', 3)
;~ 1	(?<=[\n\r]|^)				- проверка совпадения слева символов переноса строки "[\n\r]" или "|" начала текста "^"
;~ 2	(.{5})						- забираем пять любых символов, если совпадают все условия
;~ 3	[^\n\r]+					- проверяем наличие любых символов, кроме символов переноса строки "[^\n\r]" в количестве больше одного "+"
;~ 4	(\(<(?:печать|ПЕЧАТЬ).+?)	- забираем текст, начинающийся с (< "\(<", проверяя наличие в нем печать или "|" ПЕЧАТЬ "(?:печать|ПЕЧАТЬ)" и все
;~ 									  следующие символы в количестве больше одного ".+?" до совпадения с условием на следующей строке
;~ 5	(?=[\n\r]|$)				- проверка совпадения справа символов переноса строки "[\n\r]" или "|" конца текста "$"
;~ В итоге получаем массив, в котором в индексах 0, 2, 4 и т.д. находятся символы из условия 2, например "VG587", "VV951" и т.д., а в индексах 1, 3, 5 и т.д.
;~ находятся символы из условия 4, например "(<ПЕЧАТЬ>)SLKFHY897E 	-LKJS09F	-FKLEJNER(<'end'>)", "(<ПЕЧАТЬ>)FE89FIJ39F	-FNM92OI	-EFWEFFYT(<'end'>)" и т.д.
$i_Tmp = UBound($a_Read); получаем размер массива
If (Not $i_Tmp) Or (Mod($i_Tmp, 2)) Then Exit 13;если размер 0 или не кратен 2, выход, так как это ошибка
$s_Txt = 'Файл ' & $s_FileRead & @CRLF & @CRLF; задаем новый текст
For $i = 0 To $i_Tmp - 1 Step 2; в цикле с шагом два от 0 до последнего индекса массива
    $s_Txt &= $a_Read[$i] & StringStripWS($a_Read[$i + 1], 8) & @CRLF
;~ добавляем к тексту символы из условия 2 " $s_Txt &= $a_Read[$i]",
;~ символы из условия 4, предварительно удалив из них все пробельные символы " & StringStripWS($a_Read[$i + 1], 8)",
;~ символы переноса строки " & @CRLF"
Next
$s_Txt = StringTrimRight($s_Txt, 2);удаляем два последних символа переноса строки "@CRLF"
$i_Tmp = StringInStr($s_FileRead, '\', 0, -1);получаем номер вхождения последнего обратного слеша в пути к обрабатываемому файлу
$s_FileWrite = StringLeft($s_FileRead, $i_Tmp) & 'Print_' & StringTrimLeft($s_FileRead, $i_Tmp)
;~ задаем имя файла-результата, добавляя к имени обрабатываемого файла 'Print_'
$h_File = FileOpen($s_FileWrite, 2);открываем файл-результат и получаем его дескриптор
FileWrite($h_File, $s_Txt);пишем в него новый текст
FileClose($h_File);закрывем дескриптор файла-результата

Local $s_FileRead = @ScriptDir & '\txt.txt', $v_Read, $s_Txt, $i_Tmp

$s_Txt = FileRead($s_FileRead)
$v_Read = StringRegExp($s_Txt, '(?<=[\n\r]|^)(.{5})[^\n\r]+(\(<(?:печать|ПЕЧАТЬ).+?)\(', 3)
$i_Tmp = UBound($v_Read)
If (Not $i_Tmp) Or (Mod($i_Tmp, 2)) Then Exit 13
$s_Txt = 'Файл ' & $s_FileRead & @CRLF & @CRLF
For $i = 0 To $i_Tmp - 1 Step 2
	$s_Txt &= $v_Read[$i] & StringStripWS($v_Read[$i + 1], 8) & @CRLF
Next
$s_Txt = StringTrimRight($s_Txt, 2)
$i_Tmp = StringInStr($s_FileRead, '\', 0, -1)
$v_Read = FileOpen(StringLeft($s_FileRead, $i_Tmp) & 'Print_' & StringTrimLeft($s_FileRead, $i_Tmp), 2)
FileWrite($v_Read, $s_Txt)
FileClose($v_Read)

$s_FileRead = FileOpenDialog("Открыть...", @DesktopDir, "Text Files (*.txt)", 1 ) ; выбрать файл
If @error Then Exit


;~ Поиск нужных строк и форматирование с помощью регулярных выражений
;~ копирования результата в буфер обмена для вставки в новый файл и сохранения нового файла без изименения открытого


SAVE()

Func SAVE()

;~ $save = FileSaveDialog ( "Сохранить", @DesktopDir, "Txt files (*.txt)",2) ; Самомоу выбрать название
;~ If @error Then Exit

$save = @ScriptDir & '\Выгрузка' & ' (' & @MDAY & '.' & @MON & '  ' & ' ' & @HOUR & '_' & @MIN & '_' & @SEC & ' )' ; Сюда ввести название файла
$File = FileOpen($save & ".txt",2)
$bufer = ClipGet() ; Вставить из буфера обмена
FileWrite($File, $bufer)
FileClose($File)
EndFunc