[Мышь, клавиатура] Переназначение функций клавиш F1-F12 на ноутбуке

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <Misc.au3>

Global $Media = False
OnAutoItExitRegister("Cleanup")

$hStub_KeyProc = DllCallbackRegister("_KeyProc", "long", "int;wparam;lparam")
$hmod = _WinAPI_GetModuleHandle(0)
$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)

While 1
  Sleep(1000)
WEnd

Func _KeyProc($nCode, $wParam, $lParam)
  Local $tKEYHOOKS
  $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
  If $nCode < 0 Then
    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
  EndIf
  If $wParam = $WM_KEYDOWN Then
    ; ConsoleWrite("vkCode - " & DllStructGetData($tKEYHOOKS, "vkCode") & @CRLF)
    If DllStructGetData($tKEYHOOKS, "vkCode") = 145 Then $Media = Not $Media
    If Not $Media Then
      Switch DllStructGetData($tKEYHOOKS, "vkCode")
        Case 173        ; <= клавиша Mute
          _Send("{F1}") ; <= вместо Mute отправляем F1
          Return -1
        Case 174        ; <= Vol-
          _Send("{F2}") ; <= F2
          Return -1
        Case 175        ; <= Vol+
          _Send("{F3}") ; <= F3
          Return -1
      EndSwitch
    EndIf
  EndIf
  Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc

Func Cleanup()
  _WinAPI_UnhookWindowsHookEx($hHook)
  DllCallbackFree($hStub_KeyProc)
EndFunc   ;==>Cleanup

Func _Send($key)
  Local $mod = ""
  If _IsPressed("10") Then $mod &= "+"
  If _IsPressed("11") Then $mod &= "^"
  If _IsPressed("12") Then $mod &= "!"
  Send($mod & $key)
EndFunc   ;==>_Send