↑  ←  Описание функции

_GDIPlus_PathCreate

Создаёт объект GraphicsPath и инициализирует режим заполнения

#Include <GDIP.au3>
_GDIPlus_PathCreate([$iFillMode = 0])

Параметры

$iFillMode Режим заполнения внутренней части фигуры объекта GraphicsPath:
0 - (по умолчанию) Области заполняются согласно правилу чётного-нечётного равенства
1 - Области заполняются согласно правилу ненулевого изгиба

Возвращаемое значение

Успех:Возвращает указатель на новый объект GraphicsPath
Ошибка:Возвращает 0, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

После завершения использования объекта вызовите _GDIPlus_PathDispose, чтобы освободить ресурсы объекта

См. также

_GDIPlus_PathDispose

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hPath

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("Рисует объект GraphicsPath", 400, 200)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Задействует сглаживание
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)

    ; Создаёт объект GraphicsPath и добавляет эллипс
    $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, 10, 10, 380, 180)

    ; Рисует путь
    _GDIPlus_GraphicsDrawPath($hGraphics, $hPath)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc