_GDIPlus_PathBrushSetCenterColor
Устанавливает цвет центра кисти градиента
#Include <GDIP.au3>
_GDIPlus_PathBrushSetCenterColor($hPathGradientBrush, $iARGB)
Параметры
| $hPathGradientBrush | Указатель на объект PathGradientBrush |
| $iARGB |
Цвет в шестнадцатеричном формате: прозрачность, красный, зелёный и синий. |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False, либо: |
| Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall() | |
| $GDIP_STATUS содержит не нулевое значение кода ошибки. |
См. также
_GDIPlus_PathBrushGetCenterColorСм. также
Искать GdipSetPathGradientCenterColor в библиотеке MSDNПример
#include <GDIP.au3>
#include <GUIConstantsEx.au3>
_Example()
Func _Example()
Local $hGUI, $hGraphics, $hBrush
Local $aColors[11] = [10, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFFFFFF, 0xFFFF0000, 0xFF0000FF]
Local $aPoints[11][2] = [[10], [303, 114], [215, 178], [248, 281], [160, 218], [72, 281], [105, 178], [17, 114], [126, 113], [160, 10], [194, 113]]
; Инициализирует библиотеку GDI+
_GDIPlus_Startup()
$hGUI = GUICreate("Устанавливает цвет центра кисти градиента", 400, 300)
GUISetState()
; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
; Создаёт путь кисти градиента из точек
$hBrush = _GDIPlus_PathBrushCreate($aPoints)
; Устанавливает цвет центра кисти градиента
_GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF00FF00)
; Устанавливает цвета окружения кисти градиента
_GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)
; Заполняет многоугольник используя кисть градиента
_GDIPlus_GraphicsFillPolygon($hGraphics, $aPoints, $hBrush)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Освобождает ресурсы
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphics)
; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc