↑  ←  Описание функции

_GDIPlus_LineBrushCreateFromRect

Создаёт объект кисть с линейным градиентом из прямоугольника и граничных цветов

#Include <GDIP.au3>
_GDIPlus_LineBrushCreateFromRect($tRectF, $iARGBClr1, $iARGBClr2[, $iGradientMode = 0[, $iWrapMode = 0]])

Параметры

$tRectF Структура $tagGDIPRECTF, определяющая прямоугольник для кисти линейного градиента
$iARGBClr1 Цвет начала градиента (альфа-канал, красный, зелёный, синий)
$iARGBClr2 Цвет конца градиента (альфа-канал, красный, зелёный, синий)
$iGradientMode Направление градиента:
0 - Горизонтальное направление слева-направо
1 - Вертикальное направление сверху-вниз
2 - Диагональ в прямом направлении от левого верхнего угла к правому нижнему
3 - Диагональ в обратном направлении от правого верхнего угла к левому нижнему
$iWrapMode Режим повтора, который определяет, как сопрягаются области.
0 - Плиткой, без зеркального отражения
1 - Плиткой с зеркальным отражением по горизонтали, как при перемещении от одной плитки к следующей в том же ряду
2 - Плиткой с зеркальным отражением по вертикали как при перемещении от одной плитки к следующей в том же столбце
3 - Плиткой с зеркальным отражением по горизонтали, как при перемещении в том же ряду и по вертикали как при перемещении в том же столбце
4 - Никакая плитка не помещается

Возвращаемое значение

Успех:Возвращает указатель на новый объект LinearGradientBrush
Ошибка:Возвращает 0, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

После завершения использования объекта вызовите _GDIPlus_BrushDispose, чтобы освободить ресурсы объекта

См. также

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hBrush, $tRectF

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("_GDIPlus_LineBrushCreateFromRect", 400, 200)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Создаёт структуру $tagGDIPRECTF, определяющую прямоугольник для кисти линейного градиента
    $tRectF = _GDIPlus_RectFCreate(0, 0, 50, 100)

    ; Создаёт кисть линейного градиента, который плавно изменяет цвет с красного на зеленый
    $hBrush = _GDIPlus_LineBrushCreateFromRect($tRectF, 0xFFFF0000, 0xFF009900, 3, 1) ; Диагональ в обратном направлении

    ; Заполняет прямоугольник кистью с линейным градиентом
    _GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 400, 200, $hBrush)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc