_GDIPlus_GraphicsDrawCurve3
Рисует кривую
#Include <GDIP.au3>
_GDIPlus_GraphicsDrawCurve3($hGraphics, $aPoints, $iOffset, $iNumOfSegments, $nTension[, $hPen = 0])
Параметры
| $hGraphics | Указатель на объект Graphics |
| $aPoints |
Массив, содержащий координаты точек кривой: [0][0] - Количество точек [1][0] - X-координата точки 1 [1][1] - Y-координата точки 1 [2][0] - X-координата точки 2 [2][1] - Y-координата точки 2 ... [n][0] - X-координата точки n [n][1] - Y-координата точки n |
| $iOffset |
Индекс точки массива, используемый в качестве первой точки кривой, отсчёт от 0 |
| $iNumOfSegments |
Количество сегментов, используемых для рисования кривой. Это значение должно быть не менее 1 |
| $nTension |
Число, указывающее, насколько ярко выражены изгибы кривой (амплитуда) |
| $hPen |
[необязательный] Дескриптор объекта карандаша, который используется для рисования замкнутой кривой. Если 0, то сплошная чёрная линия шириной 1 пиксель. |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False, либо: |
| Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall() | |
| $GDIP_STATUS содержит не нулевое значение кода ошибки. |
См. также
Пример
#include <GDIP.au3>
#include <GUIConstantsEx.au3>
_Example()
Func _Example()
Local $hGUI, $hGraphics, $hPen, $aPoints[11][2], $iI, $iJ
; Инициализирует библиотеку GDI+
_GDIPlus_Startup()
$hGUI = GUICreate("Рисует часть кривой", 400, 350)
GUISetState()
; Создаёт графический объект из дескриптора окна
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
; Задействует сглаживание
_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)
; Создаёт несколько точек
$aPoints[0][0] = 10
For $iI = 0 To 1
For $iJ = 1 To 5
$aPoints[$iI*5+$iJ][0] = 300*$iI+50
$aPoints[$iI*5+$iJ][1] = $iJ*50
Next
Next
; Создаёт объект карандаша
$hPen = _GDIPlus_PenCreate($GDIP_ORCHID, 8)
; Рисует кривую с указанием количества точек, чтобы использовать, смещение первой точки и амплитуды
; Начинает со 2-ой точки и использует только 3 точки для рисования кривой
_GDIPlus_GraphicsDrawCurve3($hGraphics, $aPoints, 1, 3, 0.8, $hPen)
; Начинает с 6-ой точки и использует только 3 точки для рисования кривой
_GDIPlus_GraphicsDrawCurve3($hGraphics, $aPoints, 5, 3, 0.8, $hPen)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Освобождает ресурсы
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphics)
; Закрывает библиотеку GDI+
_GDIPlus_Shutdown()
EndFunc