Функция FileOpen

FileOpen

Открывает файл для чтения или записи.

FileOpen ( "filename" [, mode = 0 ] )

Параметры

filename

Имя файла для открытия.

mode

[необязательный] Режим, в котором будет открыт файл. Может быть комбинацией следующих значений:
0 = (по умолчанию) Открыть только для чтения
1 = Открыть только для записи в конец файла
2 = Открыть только для записи в конец файла, удалив предыдущее содержание
8 = Создать структуру папок, если путь к файлу не существует (см. примечания).
16 = Принудительно использовать бинарный режим (см. примечания).
32 = Использовать кодировку Unicode UTF16 Little Endian для чтения и записи. Чтение не перезаписывает существующую BOM.
64 = Использовать кодировку Unicode UTF16 Big Endian для чтения и записи. Чтение не перезаписывает существующую BOM.
128 = Использовать кодировку Unicode UTF8 (с BOM) для чтения и записи. Чтение не перезаписывает существующую BOM.
256 = Использовать кодировку Unicode UTF8 (без BOM) для чтения и записи.
16384 = Если при открытии файла не найдена метка BOM, проверять файл полностью, чтобы определить, является ли он файлом в кодировке UTF8. Если это значение флага не используется, тогда при определении того, является ли файл файлом в кодировке UTF8, будет проверено только начало файла.
Каталог назначения должен существовать (если не используется значение флага '8').

Возвращаемое значение

Успех:	Возвращает дескриптор файла для использования в других файловых функциях.
Ошибка:	Возвращает -1, если произошла ошибка.

Примечания

По окончании работы необходимо освободить ресурсы, выделенные дескриптору с помощью функции FileClose().
Файл может не открыться в зависимости от прав доступа и/или его атрибутов HIDDEN или SYSTEM.
По умолчанию при записи текста используется режим ANSI, используйте флаг Unicode, чтобы изменить это. При записи файлов Unicode стандартный режим Windows (и самый быстрый в AutoIt из-за наименьшего преобразования) UTF16 Little Endian (флаг 32).
При открытии несуществующего файла для записи, он создаётся. Каталоги не создаются, если не используется соответствующий флаг.
При чтении и записи файла используя один и тот же дескриптор, необходимо использовать функцию FileSetPos(), чтобы обновлять текущую позицию в файле.
Файл может быть прочитан как бинарные данные (по байтам), используя FileOpen() с соответствующим флагом. В этом случае длина определяется байтами, а не символами. Если будет прочитано слишком много данных, это приведёт к остановке AutoIt с ошибкой выделения памяти.

См. также

FileClose, FileFlush, FileRead, FileReadLine, FileWrite, FileWriteLine, FileGetPos, FileSetPos

Пример

$hFile = FileOpen("test.txt", 0)

; Проверяет, является ли файл открытым, перед тем как использовать функции чтения/записи в файл
If $hFile = -1 Then
MsgBox(4096, "Ошибка", "Невозможно открыть файл.")
Exit
EndIf

FileClose($hFile)

; Другой пример, который автоматически создает структуру каталогов
$hFile = FileOpen("test.txt", 10) ; который аналогично 2 + 8 (очистить + создать путь к файлу)

If $hFile = -1 Then
MsgBox(4096, "Ошибка", "Невозможно открыть файл.")
Exit
EndIf

FileClose($hFile)