Что нового

Вывод информаций в Edit

Yoshiyuki

Новичок
Сообщения
40
Репутация
0
Здравствуйте, у меня скрипт скачивает с фтп файл, добавляет в него информацию и отправляет обратно, но как сделать, чтобы скачать и вывести его в edit? Скачать я смогу, но как вывести его содержимое в edit не знаю, подскажите, пожалуйста
Код:
#include <FTPEx.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("IP Control", 360, 120, 192, 124)
$Ip_ = GUICtrlCreateLabel("Айпи", 8, 3, 29, 17)
$Ip = GUICtrlCreateInput("", 8, 20, 155, 21)
$Name_ = GUICtrlCreateLabel("Подпись", 8, 47, 113, 17)
$Name = GUICtrlCreateInput("", 8, 64, 155, 21)
$Ok = GUICtrlCreateButton("Добавить", 8, 90, 75, 25, $WS_GROUP)
$Cancel = GUICtrlCreateButton("Отмена", 88, 90, 75, 25, $WS_GROUP)
$IPList = GUICtrlCreateEdit("", 170, 8, 185, 80)
$but1 = GUICtrlCreateButton("Ок", 170, 90, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Ok
			Ip()
		Case $Cancel
			Exit

	EndSwitch
WEnd

Func Ip()
$2 = GUICtrlRead($Ip)
$3 = " "
$4 = "("
$5 = GUICTrlRead($Name)
$6 = ")"
$ftp_server_ip = '***'
$user_name = '***'
$user_pass = '***'
$mode = '1'
$file_local = @TempDir & 'IP.txt'
$file_remote = 'IP.txt'
$ftp_session = _FTP_Open("Ip Control")
$ftp_session_connect = _FTP_Connect($ftp_session, $ftp_server_ip, $user_name, $user_pass, $mode)
_FTP_ProgressDownload($ftp_session_connect, $file_local, $file_remote)
FileWriteLine($file_local, $2&$3&$4&$5&$6)
_FTP_ProgressUpload($ftp_session_connect, $file_local, $file_remote)
_FTP_Close($ftp_session)
EndFunc
 

madmasles

Модератор
Глобальный модератор
Сообщения
7 790
Репутация
2 319
Yoshiyuki
В окно, надеюсь, сами сможете вставить:
Код:
#include <FTPEx.au3>

$sServer = 'ftp.my_server.ru'
$sUser = 'Login'
$sPass = 'Password'
$sRemote = '/Dir/File.txt'

$hOpen = _FTP_Open('MyFTP')
$hConn = _FTP_Connect($hOpen, $sServer, $sUser, $sPass, 1); в зависимости от сервера, может быть 0, а не 1, см. справку.
$iSize = _FTP_FileGetSize($hConn, $sRemote)
$hFile = _FTP_FileOpen($hConn, $sRemote)
$sText = _FTP_FileRead($hFile, $iSize)
_FTP_FileClose($hFile)
_FTP_Close($hOpen)
$sText = BinaryToString($sText)

MsgBox(64, $iSize & ' b', $sText)


С выводом:
Код:
#include <FTPEx.au3>
#include <GuiConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WinAPIEx.au3>

$sServer = 'ftp.my_server.ru'
$sUser = 'Login'
$sPass = 'Password'
$sRemote = '/Dir/File.txt'

$hOpen = _FTP_Open('MyFTP')
$hConn = _FTP_Connect($hOpen, $sServer, $sUser, $sPass, 1); в зависимости от сервера, может быть 0, а не 1, см. справку.
$iSize = _FTP_FileGetSize($hConn, $sRemote)
$hFile = _FTP_FileOpen($hConn, $sRemote)
$sText = _FTP_FileRead($hFile, $iSize)
_FTP_FileClose($hFile)
_FTP_Close($hOpen)
$sText = BinaryToString($sText)

;MsgBox(64, $iSize & ' b', $sText)

$hGui = GUICreate('MyFTP', 300, 300, -1, -1, -1, $WS_EX_TOPMOST)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, '', 5, 5, 290, 290, _
		BitOR($ES_MULTILINE, $WS_HSCROLL, $ES_AUTOHSCROLL, $WS_VSCROLL, _
		$ES_AUTOVSCROLL, $ES_NOHIDESEL, $ES_READONLY))
_GUICtrlRichEdit_SetRECT($hRichEdit, 10, 10, 280)
_GUICtrlRichEdit_SetBkColor($hRichEdit, _WinAPI_SwitchColor(0xF0F0F0))
_GUICtrlRichEdit_SetFont($hRichEdit, 10, Default)
_GUICtrlRichEdit_AppendText($hRichEdit, $sText)
_GUICtrlRichEdit_SetSel($hRichEdit, 0, -1)
_GUICtrlRichEdit_SetCharBkColor($hRichEdit, _WinAPI_SwitchColor(0xE6E6E6))
_GUICtrlRichEdit_SetCharColor($hRichEdit, _WinAPI_SwitchColor(0xFF0000))
_GUICtrlRichEdit_GotoCharPos($hRichEdit, 0)
GUISetState()

_WinAPI_EmptyWorkingSet()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			_GUICtrlRichEdit_Destroy($hRichEdit)
			GUIDelete($hGui)
			Exit
	EndSwitch
WEnd
WinAPIEx.au3
 
Верх