Что нового

Ввод данных с помощью календаря

AndreyK

Новичок
Сообщения
4
Репутация
0
Добрый день!

Никто не сталкивался с такой вот проблемой. С помощью Koda(FormDesigner) создаю календарь (DatePicker). Затем необходимо считать дату, на которую я "ткну" в этом календаре и присвоить ее какой-нибудь переменной. Формат даты (год, месяц, день, или наоборот) все равно какой. Сложность в том, что я никак не могу это сделать. Кто-нибудь может помочь?
 

madmasles

Модератор
Глобальный модератор
Сообщения
7,790
Репутация
2,322
AndreyK
Попробуйте так:
Код:
#include <GUIConstantsEx.au3>
#include <Date.au3>

Example()

Func Example()
	Local $Date, $msg
	GUICreate("Get date", 190, 230)
	$Date = GUICtrlCreateMonthCal(_NowDate(), 10, 10, 170, 170)
	$Input = GUICtrlCreateInput('', 60, 190, 70, 18)
	GUISetState()
	Do
		$msg = GUIGetMsg()
		If $msg = $Date Then
			$sDate = _DateTimeFormat(GUICtrlRead($Date), 2)
			GUICtrlSetData($Input, $sDate)
		EndIf
	Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example
 

Garrett

Модератор
Локальный модератор
Сообщения
3,999
Репутация
967
AndreyK
Ещё один вариант :smile:
Код:
#include <DateTimeConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 206, 236, 192, 114)
$MonthCal1 = GUICtrlCreateMonthCal("", 7, 7, 191, 184)
$Input1 = GUICtrlCreateInput("", 43, 204, 121, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $MonthCal1
		$aDate = StringSplit(GUICtrlRead($MonthCal1),"/",2)
		$sDate = StringFormat("%02d.%02d.%04d", $aDate[2], $aDate[1], $aDate[0])
		GUICtrlSetData($Input1, $sDate)

	EndSwitch
WEnd
 
Автор
A

AndreyK

Новичок
Сообщения
4
Репутация
0
Класс, заработало. Спасибо всем! Дальше хочу сам домучать прогу, без подсказок. Еще раз спасибо за оперативность.
 
Верх