[Время, дата] Вывод текущего времени компьютера в строке

[vanekzver]

Как сделать строку в скрипте, чтобы она выводила в Input дату и время компьютера, такого вида : Дата : DD/MM/YYYY ; Время : ЧЧ/ММ/СС

 

[Zaramot]

#include <WindowsConstants.au3>

GUICreate("Form1", 400, 199, 192, 124, -1, $WS_EX_COMPOSITED)
$Input1 = GUICtrlCreateInput("", 64, 80, 250, 21)
$Input2 = GUICtrlCreateInput("", 64, 110, 250, 21)
$Input3 = GUICtrlCreateInput("", 64, 50, 250, 21)
GUISetState()

While 1
	GUICtrlSetData($Input1, 'Дата: ' & @MDAY & '/' & @MON & '/' & @YEAR)
	GUICtrlSetData($Input2, 'Время: ' & @HOUR & ':' & @MIN & ':' & @SEC)
	GUICtrlSetData($Input3, 'Дата: ' & @MDAY & '/' & @MON & '/' & @YEAR & '         Время: ' & @HOUR & ':' & @MIN & ':' & @SEC)
	Switch GUIGetMsg()
		Case -3
			Exit
	EndSwitch
WEnd

 

[vanekzver]

Она мигает ((

 

[Zaramot]

vanekzver,

Она мигает ((

#include <GUIConstantsEx.au3>
#include "GUIFFLabel.au3"

$hGUI = GUICreate("Test", 400, 220)
$Input1 = _GUICtrlFFLabel_Create($hGUI, "", 80, 40, 140, 17)
$Input2 = _GUICtrlFFLabel_Create($hGUI, "", 80, 60, 140, 17)
$Input3 = _GUICtrlFFLabel_Create($hGUI, "", 80, 80, 250, 17)
GUISetState(@SW_SHOW)

While 1
	_GUICtrlFFLabel_SetData($Input1, 'Дата: ' & @MDAY & '/' & @MON & '/' & @YEAR, 0x00FFFF)
	_GUICtrlFFLabel_SetData($Input2, 'Время: ' & @HOUR & ':' & @MIN & ':' & @SEC, 0xFF0000)
	_GUICtrlFFLabel_SetData($Input3, 'Дата: ' & @MDAY & '/' & @MON & '/' & @YEAR & '     Время: ' & @HOUR & ':' & @MIN & ':' & @SEC, 0x00FF00)
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

http://autoit-script.ru/index.php?topic=5632.0

 

[Medic84]

Zaramot
Можно сделать через AdlibRegister с обновлением в секунду, тогда мигать не будет (если коенчно человеку милисекунда не нужна.

 

[CreatoR]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUICreate("Set Time", 240, 60)

$Input = GUICtrlCreateInput("", 20, 20, 200, 20)

GUISetState()

_SetTimeProc()
AdlibRegister("_SetTimeProc", 1000)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _SetTimeProc()
	GUICtrlSetData($Input, 'Дата : ' & @MDAY & '/' & @MON & '/' & @YEAR & ' ; Время : ' & @HOUR & ':' & @MIN & ':' & @SEC)
EndFunc

Добавлено:

Сообщение автоматически объединено: 2 Мар 2012

Ну или так если нужны миллисекунды:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUICreate("Set Time", 240, 60)
$Input = GUICtrlCreateInput("", 10, 20, 220, 20)
GUISetState()

AdlibRegister("_SetTimeProc", 200)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _SetTimeProc()
	Local $sTime = 'Дата : ' & @MDAY & '/' & @MON & '/' & @YEAR & ' ; Время : ' & @HOUR & ':' & @MIN & ':' & @SEC & ':' & @MSEC
	
	If GUICtrlRead($Input) <> $sTime Then
		GUICtrlSetData($Input, $sTime)
	EndIf
EndFunc