[Время, дата] Высвечивание сообщения в определенное время

[_Lexa98_]

Нужно реализовать появление MsgBox в определенное время, то есть в 12:45 , 13:45 , 14:45 и т.д. высвечивается MsgBox.

 

[Arei]

if (@HOUR = 12) and  (@MIN= 45) Then
	MsgBox("","","Привет")
	Endif

Вот, следующие по аналогии.

 

[madmasles]

_Lexa98_,
Можно так попробовать.

HotKeySet('{Esc}', '_Exit')

Global $sDay = @MDAY, $aHourMin[6][3] = [[5],[12, 45],[13, 25],[14, 30],[15, 15],[16, 00]]
AdlibRegister('Show', 1000)
While 1
	Sleep(500)
WEnd

Func Show()
	If $sDay <> @MDAY Then
		$sDay = @MDAY
		For $i = 1 To $aHourMin[0][0]
			$aHourMin[$i][2] = 0
		Next
	EndIf
	For $i = 1 To $aHourMin[0][0]
		If $aHourMin[$i][0] = @HOUR And $aHourMin[$i][1] = @MIN And Not $aHourMin[$i][2] Then
			$aHourMin[$i][2] = 1
			AdlibUnRegister('Show')
			MsgBox(64, 'Info', $aHourMin[$i][0] & ':' & $aHourMin[$i][1])
			AdlibRegister('Show', 1000)
		EndIf
	Next
EndFunc   ;==>Show

Func _Exit()
	Exit
EndFunc   ;==>_Exit

 

[_Lexa98_]

Спасибо всем! :laugh:

 

[Zaramot]

Более лёгкий способ:

While 1
    $Time = @HOUR & ':' & @MIN & ':' & @SEC
    Switch $Time
        Case '12:45:00', '13:45:00', '14:45:00' ;.....и.т.д
            MsgBox(0, '', '')
    EndSwitch
WEnd